WebBrowser sur une form Panoramic !

dim w%,h%,t%,l%,k%,hnd%,url$,hurl%
dim Page$,Repert$

label fichier,Preced,Suiv,Index,Choix,Quitter

rem 'Localisation du repertoire source et placement de l'adresse dans une variable
repert$=dir_current$
caption 0,Panora_Aide
width 0,550:height 0,400
list 1:top 1,10:left 1,10:width 1,150:height 1,345:font_name 1,"Arial":on_click 1,Choix
cursor_point 1
hnd%=handle(0)
w%=350
h%=315
t%=10
l%=170
dll_on "WebBrowser.dll"
k% = dll_call1("WBCreate",hnd%)
k% = dll_call4("WBLocate",l%,t%,w%,h%)
rem 'Page précédente
button 2:top 2,330:left 2,170:width 2,20:height 2,20:caption 2,"t":font_name 2,"Wingdings 3"
hint 2,"Page précédente":cursor_point 2:on_click 2,Preced
rem 'Index
button 3:top 3,330:left 3,195:width 3,20:height 3,20:caption 3,"I":font_name 3,"Times new roman":font_bold 3
hint 3,"Index":cursor_point 3:on_click 3,Index
rem 'Page suivante
button 4:top 4,330:left 4,220:width 4,20:height 4,20:caption 4,"u":font_name 4,"Wingdings 3"
hint 4,"Page suivante":cursor_point 4 :on_click 4,Suiv
rem 'Fermeture du module
button 5:top 5,330:left 5,450:width 5,20:height 5,20:caption 5,"X":font_name 5,"Arial":font_bold 5
hint 5,"Fermer l'aide":cursor_point 5:on_click 5,Quitter
gosub fichier
end

fichier:
rem 'verif de l'existence du dossier Help sinon création du dossier et des pages de test
rem 'Tout le bloc if...end_if peut être supprimer ou remplacer
if dir_exists(Repert$+"\Help")<>1
  dir_make Repert$+"\Help"
  dlist 100
  item_add 100,"Index de l'aide"
  file_save 100,Repert$+"\Help\Index.html"
  clear 100
  item_add 100,"Page test n°1"
  file_save 100,Repert$+"\Help\Page_1.html"
  clear 100
  item_add 100,"Page test n°2"
  file_save 100,Repert$+"\Help\Page_2.html"
  delete 100
end_if
dir_change Repert$+"\Help"
if file_find_first$<>"_"
  Page$=file_find_first$
  item_add 1,left$(Page$,len(Page$)-5)
  Page$=file_find_next$
  while Page$<>"_"
    item_add 1,left$(Page$,len(Page$)-5)
    Page$=file_find_next$
  end_while
  file_find_close
end_if
url$ = "File:///"+Repert$+"\Help\index.html"
hurl% = adr(url$)
k% = dll_call1("WBUrl",hurl%)
return

Choix:
url$ = "File:///"+Repert$+"\Help"+item_index$(1)+".html"
hurl% = adr(url$)
k% = dll_call1("WBUrl",hurl%)
return

Preced:
k% = dll_call1("WBFunction",1)
return

Suiv:
k% = dll_call1("WBFunction",2)
return

Index:
url$ = "File:///"+Repert$+"\Help\index.html"
hurl% = adr(url$)
k% = dll_call1("WBUrl",hurl%)
return

Quitter:
k% = dll_call0("WBDelete")
dll_off
terminate