Un programme d'aide de rappel d'instruction

' mise à jour du fichier initiale.fic
  file_open_write 1,dir_current$ +"\"+"initiale.fic"
      file_writeln 1,"Courier New"
      file_writeln 1,1
      file_writeln 1,10
      file_writeln 1,"10:' retrait horizontal par rapport à la fenêtre droite de l'écran"
      file_writeln 1,"10:' position de l'icône verticalement par rapport au haut de l'écran"
      file_writeln 1,"les couleurs de l'icône en mode réduit du programme"
      file_writeln 1,255
      file_writeln 1,0
      file_writeln 1,0
      file_writeln 1,"1 :' dernière fiche lue" :rem "ligne rajoutée"
  file_close 1
  terminate

' mémoire de Panoramique pour programmer
width 0,860:height 0,980:left 0,400:color 0,255,235,123:caption 0," aide sur le codage Panoramique (cliquer sur le cadre jaune pour réduire  /  ou rouge pour normal)"
hint 0, "en appuyant sur la forme principale, on rétrécie celle_ci"+chr$(13)+"elle est réduite en rouge en haut à droite"+chr$(13)+"si on reclique sur le carré rouge, elle revient"
dim choix,fichier$,dossier$,question%,f$,a%,b$,lire%,gras%,a$,fonte$,droite%,haut%,rouge%,vert%,bleu%,op%

label sauve,lire,choix,new,veille,reveille,ajout,fonte,gras,save,size,textcombo
dossier$=dir_current$ +"\":droite%=40:haut%=0:rouge%=255:vert%=0:bleu%=0

combo    1  :left 1,10:top 1,10:height 1,500:text 1,"      Aide Panoramic":on_click 1,choix:hint 1,"choisir l'instruction"
memo      2  :left 2,10:top 2,40:width 2,830:height 2,870:font_size 2,12:font_bold 2:font_name 2,"Bitstream Vera Sans Mono"
              bar_both 2
button    3  :left 3,230:top 3,10:width 3,50:caption 3,"sauve"
' button    4  :left 4,170:top 4,10:width 4,50:caption 4,"lire" :on_click 4,lire
alpha    5  :left 5,410:top 5,0:caption 5,"nom du fichier et du texte du Combo"
edit      6  :left 6,420:top 6,15:width 6,150:color 6,231,224,224
button    7  :left 7,290:top 7,10:width 7,50:caption 7,"ajouter":on_click 7,ajout
button    8  :left 8,350:top 8,10:width 8,50:caption 8,"new":on_click 8,new:hint 8,"efface les données visibles pour une nouvelle fiche"+chr$(13)+"si vous avez modifier le texte, sauvegardez avant"
alpha    9  :left 9,1:top 9,1:caption 9,"  Aide"+chr$(13)+"  BASIC":hide 9:on_click 9,reveille
combo    10  :left 10,600:top 10,5:width 10,150:font_names_load 10:text 10,"Font"
check    11  :left 11,750:top 11,5:caption 11,"Gras"
spin    12  :left 12,800:top 12,5:width 12,50:position 12,12:max 12,18:min 12,8

gosub lire
gosub textcombo

on_click 0,veille:inactive 8:on_change 12,size
end
' ______________________________________________________________________________
sauve:
  fichier$=item_read$(1,choix)
  if text$(6)<>""
      color 2,226, 200, 0  :wait 50
      file_save 2,dossier$+text$(6)+".txt"
      gosub save
  end_if
  color 2,255,247,206
return
' ______________________________________________________________________________
lire:
if file_exists(dossier$+"liste_des_fiches.txt")=1
  file_load 1,dossier$+"liste_des_fiches.txt"
  sort 1
  color 2,255,247,206
  color 1,204,233,180
  inactive 6 :active 3:active 8:lire%=1
end_if
if file_exists(dossier$+"initiale.fic")=1
  file_open_read 1,dossier$+"initiale.fic" :op%=1
  file_readln 1,fonte$:font_name 2,fonte$ :text 10,fonte$
  file_readln 1,a%
  if a%=0
      mark_off 11:font_bold_off 2
  else
      mark_on 11:font_bold 2
  end_if
  file_readln 1,a%:position 12,a%
  file_readln 1,a$:droite%=val(left$(a$,instr(a$,":")-1))
  file_readln 1,a$:haut%=val(left$(a$,instr(a$,":")-1))
  file_readln 1,a$
  file_readln 1,rouge%
  file_readln 1,vert%
  file_readln 1,bleu%
  file_readln 1,a$:choix=val(left$(a$,instr(a$,":")-1))
  file_close 1
end_if
on_click 3,sauve:on_click 10,fonte:on_click 11,gras
return
' ______________________________________________________________________________
choix:
  choix=item_index(1)
textcombo:
  f$=item_read$(1,choix)
  fichier$=f$+".txt"
  file_load 2,dossier$+fichier$
  text 6,f$ :text 1,f$
  inactive 6:active 3:inactive 7:hint_hide 0
return
' ______________________________________________________________________________
ajout:
  active 6
  if text$(6)<>""
    ' ici il faut vérifier dans la liste 1, si le nom existe
    if count(1)>0
        for a%=1 to count(1)
          if upper$(item_read$(1,a%))=upper$(text$(6)) then message "le nom du fichier existe déjà":exit_for
        next a%
        if a%<=count(1) then return
    end_if

    question%=message_confirmation_YES_NO("ON AJOUTE le nom du fichier:"+ text$(6))
    if question%=1
        color 2,226, 200, 0  :wait 50
        file_save 2,dossier$+text$(6)+".txt"
        item_add 1,text$(6)
        file_save 1,dossier$+"liste_des_fiches.txt"
        inactive 6
        color 2,255,247,206
    end_if
    text 1,"  instruction Panoramique"
    hint 6,"nom du fichier" : active 3:inactive 7
  else
    message "il n'y a pas de nom de fichier, sauvegarde impossible"
  end_if
return
' ______________________________________________________________________________
new:
  question%=message_confirmation_YES_NO("ON SAUVEGARDE le texte en cours?"+ text$(6))
  if question%=1 then gosub sauve
  inactive 3
  clear 2:text 6,"":text 1,"NOUVEAU"
  hint 6,"mettre ici le nom du fichier"
  active 6 :active 7
return
' ______________________________________________________________________________
veille:
for a%=1 to 8
  if a%<>4 then hide a%
next a%:a%=screen_x
border_hide 0 :left 0,a%-droite%-40 :top 0,haut%:width 0,40:height 0,40
color 0,rouge%,vert%,bleu%
show 9:on_click 9,reveille
on_click 0,reveille
return
' ______________________________________________________________________________
reveille:
width 0,860:height 0,980:left 0,400:color 0,255,235,123
for a%=1 to 8
  if a%<>4 then show a%
next a%
border_normal 0
hide 9
on_click 0,veille
return
' ______________________________________________________________________________
fonte:
  fonte$=item_read$(10,item_index(10))
  font_name 2,fonte$
  if op%=0 then gosub save
return
' ______________________________________________________________________________
gras:
  if checked(11)=1
    font_bold 2:gras%=1
  else
    font_bold_off 2:gras%=0
  end_if
  if op%=0 then gosub save
return
' ______________________________________________________________________________
save:
  color 2,222,186,115:wait 10
  file_open_write 1,dossier$+"initiale.fic"
      file_writeln 1,fonte$
      file_writeln 1,gras%
      file_writeln 1,position(12)
      file_writeln 1,str$(droite%)+":' retrait horizontal par rapport à la fenêtre droite de l'écran"
      file_writeln 1,str$(haut%)  +":' position de l'icône verticalement par rapport au haut de l'écran"
      file_writeln 1,"les couleurs de l'icône en mode réduit du programme"
      file_writeln 1,rouge%
      file_writeln 1,vert%
      file_writeln 1,bleu%
      file_writeln 1,str$(choix)+":' dernière fiche lue "
      color 2,255,247,206
  file_close 1  :op%=0
return
' ______________________________________________________________________________
size:
  font_size 2,position(12)
  if op%=0 then gosub save
return

' FOR
For a%=1 To 10 Step2
  Print a%
Next a%

' Aide.bas lecture des fichiers .txt d'aide Panoramic
DIM fd$, rep$, fl$, f$, m$, nmc, a$, i%
DIM h0, w0, l1, l2, ncl
LABEL Fin, Mc

fd$ = "Z:\dir.txt"
rep$ = "C:\LANGAGES\PANORAMI\MANUEL\TEXTE\": ' contient les fichiers .txt
fl$ = rep$ + "Motcle.lst"

EXECUTE_WAIT "Cmd.exe /c DIR " + rep$ + "*.txt /O:N /B >" + fd$
FILE_OPEN_READ 1, fd$: nmc = 0
FILE_OPEN_WRITE 2, fl$: ' Création du fichier liste des mots-clés
WHILE FILE_EOF(1) = 0
    FILE_READLN 1, m$: m$ = LEFT$(m$, LEN(m$)-4)
    FILE_WRITELN 2, m$
END_WHILE
FILE_CLOSE 1: FILE_CLOSE 2: FILE_DELETE fd$

h0 = SCREEN_Y - 100: w0 = 800
HEIGHT 0, h0: WIDTH 0, w0
l1 = 200
LIST 1: HEIGHT 1, h0-20: WIDTH 1, l1: COLOR 1, 240, 255, 255
ON_CLICK 1, Mc
FILE_LOAD 1, fl$: ' fichier des mots-clés
l2 = w0 - l1 - 35: ncl = INT(l2/8) - 1: ' caractères par ligne
LIST 2: LEFT 2, 200: HEIGHT 2, h0-20: WIDTH 2, l2
COLOR 2, 255, 255, 220
FONT_SIZE 2, 10: FONT_BOLD 2

Fin:
END

Mc:
f$ = rep$ + ITEM_INDEX$(1) + ".txt"
FILE_OPEN_READ 1, f$: FILE_OPEN_WRITE 2, fd$
WHILE FILE_EOF(1) = 0
    FILE_READLN 1, a$
    IF LEN(a$) > ncl
        FOR i% = ncl+1 TO 1 STEP -1
            IF MID$(a$, i%, 1) = " " THEN EXIT_FOR
        NEXT i%
        FILE_WRITELN 2, LEFT$(a$, i%-1)
        a$ = MID$(a$, i%+1, LEN(a$) - i%)
    END_IF
    FILE_WRITELN 2, a$
END_WHILE
FILE_CLOSE 1: FILE_CLOSE 2
FILE_LOAD 2, fd$
RETURN