souris et coordonnées

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

Bonjour à tous,

Je programme malheureusement rarement, ma femme à acheter un stylo qui simule la souris, hors je charge l'exemple :

Code:: picture 1
rem imprime les positions en X et Y de la souris quand on enfonce le bouton gauche sur picture 1
if mouse_left_down(1)=1
print mouse_x_left_down(1)
print mouse_y_left_down(1)
end_if

Rien ne s'affiche.

Mon but est qu'elle puisse écrire avec son stylo, j'ai donc commençais le plus facile, l’interface. Il y a un petit logiciel livré avec, mais c'est une demie page A4 qui est utilisable, hors son stylo peut allé plus loin.

Voici le stylo : le stylo

Mon interface est minimaliste :

Code:: rem dessin v1.0

rem Déclaration des variables

dim w
dim h
dim rou
dim noi
dim ver
dim ble
dim y$
dim r
dim v
dim b

rem déclaration labels

label new, rou, ver, ble, noi, boucle, fin, gros, moyen

rem creation de la forme

w = SCREEN_X
h = SCREEN_Y
height 0,h : Width 0,w
Caption 0,"A ma petite irène"

rem creation des boutons

button 100 : font_color 100,100,200,0 : left 100,(w-100) : top 100,(10) : font_bold 100 : caption 100,"New"
button 101 : left 101,(w-100) : top 101,(80) : font_bold 101 : caption 101,"Fin"
button 102 : left 102,(w-100) : top 102,(110) : font_bold 102 : caption 102,"Moyen"
button 103 : left 103,(w-100) : top 103,(140) : font_bold 103 : caption 103,"Epais"

button 104 : left 104,(w-100) : top 104,(200) : font_bold 104 : caption 104,"Noir"
button 105 : left 105,(w-100) : top 105,(230) : font_bold 105 : caption 105,"Rouge"
button 106 : left 106,(w-100) : top 106,(260) : font_bold 106 : caption 106,"Bleu"
button 107 : left 107,(w-100) : top 107,(290) : font_bold 107 : caption 107,"Vert"

button 108 : left 108,(w-100) : top 108,(450) : font_bold 108 : caption 108,"Gomme"
button 109 : left 109,(w-100) : top 109,(480) : font_bold 109 : caption 109,"Cercle"
button 110 : left 110,(w-100) : top 110,(510) : font_bold 110 : caption 110,"Ligne"

2d_line (w-115),0,(w-115),h
2d_line (w-116),0,(w-116),h

2d_fill_color 0,0,0
2d_rectangle (W-75),320,(W-45),350

Alpha 1 : left 1,(w-82) : top 1,170 : font_bold 1

boucle:

on_click 100 ,new

on_click 104 ,noi
on_click 105 ,rou
on_click 106 ,ble
on_click 107 ,ver
on_click 101 ,fin
on_click 102 ,moyen
on_click 103 ,gros

end : rem le programme principal est fini

rou:

r=255
v=0
b=0
2d_fill_color r,v,b
2d_rectangle (w-75),320,(w-45),350
return

noi:
r=0
v=0
b=0
2d_fill_color r,v,b
2d_rectangle (w-75),320,(w-45),350
return

ble:
r=0
v=0
b=255
2d_fill_color r,v,b
2d_rectangle (w-75),320,(w-45),350
return

ver:
r=0
v=255
b=0
2d_fill_color r,v,b
2d_rectangle (w-75),320,(w-45),350
return

new:
terminate
return

fin:
caption 1,"Fin"

return

moyen:
caption 1,"Moyen"
return

gros:
caption 1,"Gros"

return

end

Le stylo fonctionne comme la souris, on installe le récepteur devant la feuille, et le bouton de la souris est simulé lorsque on écrit en appuyant sur la pointe du stylo.

Mon soucis est de récupérer les coordonnées de la souris, pour en afficher des pixels.

Merci à touss

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

J'ai inséré le code pour la souris dans la boucle, j'ai rajouté terminate (Si je clique sue le bouton gauche le prog se termine, mais rien n'y fait)

Code:: rem dessin v1.0

rem Déclaration des variables

dim w
dim h
dim rou
dim noi
dim ver
dim ble
dim x
dim y

rem déclaration labels

label new, rou, ver, ble, noi, boucle

rem creation de la forme

w = SCREEN_X
h = SCREEN_Y
height 0,h : Width 0,w
Caption 0,"A ma petite irène"
rem creation des boutons

button 100 : left 100,(w-100) : top 100,(10) : font_bold 100 : caption 100,"New"
button 101 : left 101,(w-100) : top 101,(80) : font_bold 101 : caption 101,"Fin"
button 102 : left 102,(w-100) : top 102,(110) : font_bold 102 : caption 102,"Moyen"
button 103 : left 103,(w-100) : top 103,(140) : font_bold 103 : caption 103,"Epais"

button 104 : left 104,(w-100) : top 104,(200) : font_bold 104 : caption 104,"Noir"
button 105 : left 105,(w-100) : top 105,(230) : font_bold 105 : caption 105,"Rouge"
button 106 : left 106,(w-100) : top 106,(260) : font_bold 106 : caption 106,"Bleu"
button 107 : left 107,(w-100) : top 107,(290) : font_bold 107 : caption 107,"Vert"

button 108 : left 108,(w-100) : top 108,(450) : font_bold 108 : caption 108,"Gomme"
button 109 : left 109,(w-100) : top 109,(480) : font_bold 109 : caption 109,"Cercle"
button 110 : left 110,(w-100) : top 110,(510) : font_bold 110 : caption 110,"Ligne"

2d_line (w-115),0,(w-115),h
2d_line (w-116),0,(w-116),h

2d_fill_color 0,0,0
2d_rectangle (W-75),320,(W-45),350

boucle:

on_click 100 ,new
on_click 104 ,noi
on_click 105 ,rou
on_click 106 ,ble
on_click 107 ,ver

if mouse_left_down(0)=1
x = MOUSE_X_POSITION(0)
y = MOUSE_Y_POSITION(0)
terminate
end_if
end

rou:
2d_fill_color 255,0,0
2d_rectangle (w-75),320,(w-45),350
return

noi:
2d_fill_color 0,0,0
2d_rectangle (w-75),320,(w-45),350
return

ble:
2d_fill_color 0,0,255
2d_rectangle (w-75),320,(w-45),350
return

ver:
2d_fill_color 0,255,0
2d_rectangle (w-75),320,(w-45),350
return

new:
terminate
return

end

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

Code:: rem dessin v1.0

rem Déclaration des variables

dim w
dim h
dim rou
dim noi
dim ver
dim ble
dim x
dim y

rem déclaration labels

label new, rou, ver, ble, noi, boucle, quit

rem creation de la forme

w = SCREEN_X
h = SCREEN_Y
height 0,h : Width 0,w
Caption 0,"A ma petite irène"
rem creation des boutons

button 100 : left 100,(w-100) : top 100,(10) : font_bold 100 : caption 100,"New"
button 101 : left 101,(w-100) : top 101,(80) : font_bold 101 : caption 101,"Fin"
button 102 : left 102,(w-100) : top 102,(110) : font_bold 102 : caption 102,"Moyen"
button 103 : left 103,(w-100) : top 103,(140) : font_bold 103 : caption 103,"Epais"

button 104 : left 104,(w-100) : top 104,(200) : font_bold 104 : caption 104,"Noir"
button 105 : left 105,(w-100) : top 105,(230) : font_bold 105 : caption 105,"Rouge"
button 106 : left 106,(w-100) : top 106,(260) : font_bold 106 : caption 106,"Bleu"
button 107 : left 107,(w-100) : top 107,(290) : font_bold 107 : caption 107,"Vert"

button 108 : left 108,(w-100) : top 108,(450) : font_bold 108 : caption 108,"Gomme"
button 109 : left 109,(w-100) : top 109,(480) : font_bold 109 : caption 109,"Cercle"
button 110 : left 110,(w-100) : top 110,(510) : font_bold 110 : caption 110,"Ligne"
button 111 : left 111,(w-100) : top 111,(640) : font_bold 111 : caption 111,"Quitter"

2d_line (w-115),0,(w-115),h
2d_line (w-116),0,(w-116),h

2d_fill_color 0,0,0
2d_rectangle (W-75),320,(W-45),350

boucle:

on_click 100 ,new
on_click 104 ,noi
on_click 105 ,rou
on_click 106 ,ble
on_click 107 ,ver

on_click 111 ,quit

if mouse_left_down(0)=1
x = MOUSE_X_POSITION(0)
y = MOUSE_Y_POSITION(0)
2d_point x,y
terminate
end_if
end

goto boucle

rou:
2d_fill_color 255,0,0
2d_rectangle (w-75),320,(w-45),350
return

noi:
2d_fill_color 0,0,0
2d_rectangle (w-75),320,(w-45),350
return

ble:
2d_fill_color 0,0,255
2d_rectangle (w-75),320,(w-45),350
return

ver:
2d_fill_color 0,255,0
2d_rectangle (w-75),320,(w-45),350
return

new:
terminate
return

quit:
terminate
return

end

Voici comment récupérer les coordonnées de la souris.
Click-gauche pour voir.

Code:: label dessin
dim x,y
picture 10 : full_space 10 : 2d_target_is 10: on_click 10,dessin
2d_fill_on
end
Dessin:
   2d_fill_color rnd(255),rnd(255),rnd(255)
   x = mouse_x_position(10) : y = mouse_y_position(10)
caption 0, str$(x) + " / " + str$(y)
   2d_circle x,y,rnd(50)
return

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

Bonjour,

Si j'ai bien compris, je dois créer une nouvelle picture dans le programme, c'est le Target que j'avais oublier.

Merci papy, je me mets au travail. Je vous montre ça.

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

Papydall, ton exemple foctionne, mais lorsque je reste appuyer les cercles crées se stoppent. J'ai changé cà :

Code:: label dessin
picture 10
dessin:
dim x,y
full_space 10 : 2d_target_is 10
2d_fill_on

if mouse_left_down(10)=1
2d_fill_color rnd(255),rnd(255),rnd(255)
x = mouse_x_position(10) : y = mouse_y_position(10)
caption 0, str$(x) + " / " + str$(y)
2d_circle x,y,5
end_if
end

J'essaye d'être logique.

Si (If) ma souris à le bouton gauche appuyé, alors j’exécute j'affiche mes petits cercles en continu, un gros trait.
Je finis bien par un End_if. Cela ne fonctionne pas

Dans mon programme :

j'ai même inséré un 2d_point, le point s'affiche. J'ai même supprimé le GOTO en respectant les labels. J'ai donc une boucle principale.

Code:: rem dessin v1.0

rem Déclaration des variables
dim w : rem variables fenêtre
dim h : rem variables fenêtre
dim roug : rem changement de couleur rouge
dim noir : rem changement de couleur noir
dim vert : rem changement de couleur vert
dim bleu : rem changement de couleur bleu
dim x : rem coordonées x souris
dim y : rem coordonées y souris

rem déclaration labels
label roug, vert, bleu, noir, boucle, quit, new

rem creation de la forme
w = SCREEN_X
h = SCREEN_Y
height 0,h : Width 0,w
Caption 0,"A ma petite irène"

rem creation des boutons
button 100 : left 100,(w-100) : top 100,(10) : font_bold 100 : caption 100,"New"
button 101 : left 101,(w-100) : top 101,(80) : font_bold 101 : caption 101,"Fin"
button 102 : left 102,(w-100) : top 102,(110) : font_bold 102 : caption 102,"Moyen"
button 103 : left 103,(w-100) : top 103,(140) : font_bold 103 : caption 103,"Epais"
button 104 : left 104,(w-100) : top 104,(200) : font_bold 104 : caption 104,"Noir"
button 105 : left 105,(w-100) : top 105,(230) : font_bold 105 : caption 105,"Rouge"
button 106 : left 106,(w-100) : top 106,(260) : font_bold 106 : caption 106,"Bleu"
button 107 : left 107,(w-100) : top 107,(290) : font_bold 107 : caption 107,"Vert"
button 108 : left 108,(w-100) : top 108,(450) : font_bold 108 : caption 108,"Gomme"
button 109 : left 109,(w-100) : top 109,(480) : font_bold 109 : caption 109,"Cercle"
button 110 : left 110,(w-100) : top 110,(510) : font_bold 110 : caption 110,"Ligne"
button 111 : left 111,(w-100) : top 111,(640) : font_bold 111 : caption 111,"Quitter"

rem création du séparation et un rectangle pour le choix de la couleur
2d_line (w-115),0,(w-115),h
2d_line (w-116),0,(w-116),h
2d_fill_color 0,0,0
2d_rectangle (W-75),320,(W-45),350

rem boucle principale
boucle:
on_click 100 ,new
on_click 104 ,noir
on_click 105 ,roug
on_click 106 ,bleu
on_click 107 ,vert
on_click 111 ,quit

if mouse_left_down(0)=1
xx = MOUSE_X_POSITION(0)
yy = MOUSE_Y_POSITION(0)
2d_point xx,yy
end_if
2d_point 100,100

end
rem fin de boucle principale

rem option du clique de souris sur les boutons
roug:
2d_fill_color 255,0,0
2d_rectangle (w-75),320,(w-45),350
return
noir:
2d_fill_color 0,0,0
2d_rectangle (w-75),320,(w-45),350
return
bleu:
2d_fill_color 0,0,255
2d_rectangle (w-75),320,(w-45),350
return
vert:
2d_fill_color 0,255,0
2d_rectangle (w-75),320,(w-45),350
return

rem effacement de la page
new:
rem à remplir après
return

rem sortie du programme
quit:
terminate
return

Merci

Panoramic intercepte ton click mais pas le fait que tu reste appuyé.
il te faut lancé une procédure sur le premier clic et l' arrêter sur un second.

if clic gauche
if etat_clic% = 0
etat_clic% = 1
detection_position souris
colorer le pixel detecté en ......
else
etat_clic% = 0
stop detection
stop coloration
end_if
end_if

enfin il me semble...

bonjour gigi75 !

J'ai repris ton programme et voila ce que cela donne.

Le premier clic de la souris te permet d'écrire.
Si tu clic de nouveau il n'y a plus d'écriture. etc...

Les options couleurs et taille fonctionnent. Wink

Code:: ' ********** dessin v1.0 ***********

' ------ Déclaration des variables ------
DIM w , h : ' Dimensions du FORM
DIM x , y : ' coordonnées de la souris
DIM ap : ' Flag d'appui du bouton gauche de la souris
DIM t : t=1 : ' Taille du trait et assignation de sa valeur
DIM n, t$ : ' variables nécessaires a l'affichage des objets
DIM cl : ' Numéro de l'objet cliqué par la souris

' ------ Déclaration des labels ------
LABEL menu , appel_timer

' ------ Déclaration des datas ------
DATA 10,"New",80,"Fin",110,"Moyen",140,"Epais",200,"Noir",230,"Rouge",260,"Bleu",290,"Vert",450,"Gomme",480,"Cercle",510,"Ligne",640,"Quitter"

' ------ Création des objets ------
w=SCREEN_X : h=SCREEN_Y : HEIGHT 0,h : WIDTH 0,w : CAPTION 0,"A ma petite irène" : COLOR 0,220,220,220 : ON_CLICK 0,menu
FOR n=100 TO 111 : BUTTON n : LEFT n,(w-100) : FONT_BOLD n : READ t$ : TOP n,VAL(t$) : READ t$ : CAPTION n,t$ : ON_CLICK n,menu : NEXT n
TIMER 120 : TIMER_INTERVAL 120,20 : ON_TIMER 120,appel_timer

' ------ Création de la séparation et du rectangle pour choix de la couleur ------
2D_PEN_COLOR 0,0,0 : 2D_LINE (w-115),0,(w-115),h : 2D_LINE (w-116),0,(w-116),h : 2D_FILL_COLOR 0,0,0 : 2D_RECTANGLE (W-75),320,(W-45),350

END

' ------ Boucle principale ------
menu:
cl=NUMBER_CLICK
IF cl=0 THEN IF ap=1 : ap=0 : TIMER_OFF 120 : ELSE : ap=1 : TIMER_ON 120 : END_IF
IF cl=100 THEN CLS : 2D_PEN_COLOR 0,0,0 : 2D_LINE (w-115),0,(w-115),h : 2D_LINE (w-116),0,(w-116),h : 2D_FILL_COLOR 0,0,0 : 2D_RECTANGLE (W-75),320,(W-45),350
IF cl=101 THEN t=1
IF cl=102 THEN t=5
IF cl=103 THEN t=10
IF cl=104 THEN 2D_FILL_COLOR 0,0,0 : 2D_PEN_COLOR 0,0,0 : 2D_RECTANGLE (w-75),320,(w-45),350
IF cl=105 THEN 2D_FILL_COLOR 255,0,0 : 2D_PEN_COLOR 255,0,0 : 2D_RECTANGLE (w-75),320,(w-45),350
IF cl=106 THEN 2D_FILL_COLOR 0,0,255 : 2D_PEN_COLOR 0,0,255 : 2D_RECTANGLE (w-75),320,(w-45),350
IF cl=107 THEN 2D_FILL_COLOR 0,255,0 : 2D_PEN_COLOR 0,255,0 : 2D_RECTANGLE (w-75),320,(w-45),350
IF cl=108 THEN 2D_FILL_COLOR 220,220,220 : 2D_PEN_COLOR 220,220,220 : 2D_RECTANGLE (w-75),320,(w-45),350
IF cl=111 THEN TERMINATE
RETURN

' ------ Boucle principale ------
appel_timer:
x=MOUSE_X_POSITION(0) : y=MOUSE_Y_POSITION(0) : 2D_CIRCLE x,y,t
RETURN

je viens de ré-éditer le code ci_dessus pour le rendre plus simple et plus court.

Il tient maintenant en 50 lignes. Wink

Je viens de faire une nouvelle mise a jour.

J'ai amélioré les couleurs du stylo (plus de bordure noir) et la gomme est fonctionnelle.

gigi75 a écrit:

Papydall, ton exemple foctionne, mais lorsque je reste appuyer les cercles crées se stoppent. J'ai changé cà :

Code:: label dessin
picture 10
dessin:
dim x,y
full_space 10 : 2d_target_is 10
2d_fill_on

   if mouse_left_down(10)=1
   2d_fill_color rnd(255),rnd(255),rnd(255)
   x = mouse_x_position(10) : y = mouse_y_position(10)
   caption 0, str$(x) + " / " + str$(y)
   2d_circle x,y,5
   end_if
end

J'essaye d'être logique.

Si (If) ma souris à le bouton gauche appuyé, alors j’exécute j'affiche mes petits cercles en continu, un gros trait.
Je finis bien par un End_if. Cela ne fonctionne pas

Cela ne fonctionne pas.
Voici pourquoi ça ne fonctionne pas :
C’est un code séquentiel, c’est-à-dire qu’il se déroule de la 1ère instruction jusqu’à la dernière séquentiellement et sans débranchement
vers un autre point du programme et ceci malgré le LABEL dessin qui n’a pas de raison d’être dans ce cas.
Analysons maintenant le code :
Les instructions des lignes 1 à 6 s’exécutent sans problème.
Vient ensuite le test de la ligne 7 if mouse_left_down(10)=1 ;
le bouton gauche de la souris N’EST PAS ENCORE appuyé,
donc les instructions entre IF et END_IF ne sont pas exécutées.
Le programme passe alors à l’instruction suivante qui est END qui marque la fin du déroulement du programme et il ne se passe rien.
Le programme s'est déroulé infiniment plus vite que l'utilisateur et l'événement de
l'appui sur le bouton de la souris est venu trop tard alors que le programme a déjà atteint la ligne END.

Comment faire alors ?
L’idée est que le test et les instructions de la séquence conditionnelle doivent être à l’intérieur d’une boucle REPEAT … UNTIL par exemple.
Ce code doit marcher.

Code:: ' label dessin : ' non utilisé donc à supprimer dans ce cas
picture 10
' dessin:
dim x,y
full_space 10 : 2d_target_is 10
2d_fill_on
repeat
  if mouse_left_down(10)=1
  2d_fill_color rnd(255),rnd(255),rnd(255)
  x = mouse_x_position(10) : y = mouse_y_position(10)
  caption 0, str$(x) + " / " + str$(y)
  2d_circle x,y,5
  end_if
until scancode = 27
end

Pour sortir, il faut appuyer sur <ESC>

Nombre de messages : 101 Age : 52 Date d'inscription : 13/04/2013

La boucle, les labels, je comprends mieux maintenant. Je comprends aussi le programme. Donc je vais insérer.

Je vous remercie tousssss.

Merci,merci, pour votre gentillesse.

Gilles

Nombre de messages : 7112 Localisation : 77 Date d'inscription : 29/11/2007

Bonsoir Gilles,
ne te fais pas d'illusions, ils étaient tous gentils avec toi parce qu'il croyaient que tu t'appelais Ginette Very Happy

Même si c’était Jeanne-Laure 35, Jeanne-Louise 35 ou Jeanne-Lise 35, je serais tout aussi gentil avec. Wink

Je suis gentil avec les Jeanne, les Julie et autres Juliette, tout aussi qu'avec les Gilles.

Il y a des gens qui utilisent leur temps libre pour vous parler et il y a des gens qui libèrent leur temps pour vous parler.
J’en fait partie des ces derniers.
Mais je ne suis pas le dernier ! tongue