Calculs sur les équations des droites

rem ============================================================================
rem         Détermination des équations réduites des droites
rem                     Par Papydall
rem ============================================================================


 Equation_Droite_Passant_Par_2Points(2,-2,4,-1)
 Equation_Droite_Passant_Par_2Points(1,-1,1,5)
 Equation_Droite_Passant_Par_2Points(3,-2,1,-2)

 Equation_Droite_Parallele_a_D_Passant_Par_A(3,-4,1,2)

 Equation_Droite_Parallele_a_AB_passant_Par_C(1,-1,0,2,3,8)

 Equation_Mediane_ABC(-3,1,1,3,-1,-5)

 Equation_Droite_Perpendiculaire_a_Droite_Et_passant_par_A(2.5,-3,-3,-2)
 
 
end
rem ============================================================================
' Equation réduite d'une droite de la forme y = mx + p connaissant les coordonnées
' de deux points de cette droite A(xa,ya) et B(xb,yb).
' si A et B ont la même abscisse alors D est parallèle à l’axe des ordonnées et
' admet x = xa comme équation.
' si A et B ont la même ordonnée alors D est parallèle à l’axe des abscisses et
'  admet y = ya comme équation.
' Dans le cas contraire, on calcule le coefficient directeur m avec la formule :
' m = (différence des ordonnées) / (différences des abscisses)
' et l'ordonnée à l'origine p avec la formule :
' p = ya - m * xa

SUB Equation_Droite_Passant_Par_2Points(xa,ya,xb,yb)
    dim_local m,p,sig$
    if xb-xa = 0
      message "La droite est parallèle à l'axe des ordonnées" + chr$(13) + "Elle admet x = " + str$(xa) + " comme équation"
    else
       if yb-ya = 0
          message "La droite est parallèle à l'axe des abscisses" + chr$(13) + "Elle admet y = " + str$(ya) + " comme équation"
       else
          m = (yb-ya)/(xb-xa) : ' Coefficient directeur de la droite
          p = ya - m * xa     : ' Ordonnée à l'origine de la droite
          if p >= 0 then sig$ = "+" : else : sig$ = ""
          message "y = " + str$(m) + " * x " + sig$ + str$(p)
       end_if
    end_if
END_SUB

rem ============================================================================
' Equation d'une droite D' parallèle à une droite D connue (y = mx+p) et passant
' par un point A(xa,ya)
' D' est de la forme y = m'x + p' avec m' = m et p' = ya - m'xa

SUB Equation_Droite_Parallele_a_D_Passant_Par_A(m,p,xa,ya)
    dim_local mprime,pprime,sig$
    mprime = m : pprime = ya - m * xa
    if pprime >= 0 then sig$ = "+" : else : sig$ = ""
    message "y = " + str$(mprime) + " * x " + sig$ + str$(pprime)
END_SUB
rem ============================================================================
' Equation d'une droite D' parallèle à la droite (BC) et passant par A
' Avec A(xa,ya) ; B(xb,yb) ; C(xc,yc)
' Le coefficient directeur de D' est le même que celui de (BC).Donc
' m' = (yc-yb)/(xc-xb)
' p' = ya - m'xa
SUB Equation_Droite_Parallele_a_AB_passant_Par_C(xa,ya,xb,yb,xc,yc)
    dim_local mprime,pprime,sig$
    mprime = (yc-yb)/(xc-xb) : pprime = ya - mprime * xa
    if pprime >= 0 then sig$ = "+" : else : sig$ = ""
    message "y = " + str$(mprime) + " * x " + sig$ + str$(pprime)
END_SUB
rem ============================================================================
' Equation de la médiane issue de A dans un triangle ABC
' Avec A(xa,ya) ; B(xb,yb) ; C(xc,yc)
' Cette droite passe par A et par I milieu de [BC] avec I(xi,yi)
' On a  : xi = (xb + xc)/2 et yi = (yb + yc)/2
' Le coefficient directeur de la médiane est m = (yi-ya)/((xi-xa)
' et p = ya - m * xa
SUB Equation_Mediane_ABC(xa,ya,xb,yb,xc,yc)
    dim_local m,p,sig$,xi,yi
    xi = (xb + xc)/2 : yi = (yb + yc)/2 : ' coordonnées du milieu I de [BC]
    m = (yi-ya)/(xi-xa) : p = ya - m * xa
    if p >= 0 then sig$ = "+" : else : sig$ = ""
    message "y = " + str$(m) + " * x " + sig$ + str$(p)
END_SUB
rem ============================================================================
' Equation de la droite perpendiculaire à la droite d'équation y = mx+p et
' passant par le point A(xa,ya)
SUB Equation_Droite_Perpendiculaire_a_Droite_Et_passant_par_A(m,p,xa,ya)
    dim_local m1,p1,sig$
    if m = 0 then m1 = 0 : else : m1 = -1/m  : ' Coefficient directeur de la droite
    p1 = ya - m1 * xa  : ' Ordonnée à l'origine de la droite
    if p1 >= 0 then sig$ = "+" : else : sig$ = ""
    message "y = " + str$(m1) + " * x " + sig$ + str$(p1)
END_SUB
rem ============================================================================