J'ai copié sur Bignono

Sujet: Re: J'ai copié sur Bignono Lun 3 Sep 2012 - 21:11

En fait quand je chargeais des objets 3D avec ton programme (les voitures par exemple), ça faisait des traits n'importe comment avec des trous, etc ... alors que quand je les chargeais avec un petit programme, ça marchait très bien. J'ai cherché pourquoi ça faisait ça et comme tu avais un scale très faible, je suis parti sur cette piste. J'ai vu au premier essai que ça réglait ce problème J'ai donc laissé cette valeur par défaut.
De toute façon, je pense qu'il faut limiter la taille du scale. Après il faut jouer avec la position de la caméra que tu implémentera bientôt, je pense.

Pour le if O3D_object_exists(1) = 1 then 3d_scale 1,V,V,V
la modif c'est pour éviter de une erreur quand on bouge le scale alors que l'on n'a pas encore chargé de fichier

Sujet: re Lun 3 Sep 2012 - 22:20

Je vais tester ton ajout sur une voiture qui me fait la même cochonnerie Laughing

Je comprends maintenant.

j'en suis à la caméra mais je me bats avec mes boutons que je voudrais dynamique.
il faut que je demande à klaus une variante de sa dll sur la souris.
juste savoir si elle est sur un objet ou pas... mais il l'a peut-être déjà fait
sans que j'ai tilté .
Il est tellement actif sur KGF... Laughing

Sujet: Re: J'ai copié sur Bignono Lun 3 Sep 2012 - 22:25

Un objet ? tu ne pense pas à un objet 3D ? Non par ce que pour un objet 3D, ce n'est pas évident vu qu'il y a une dimension que l'on n'a pas... mais tu parlais sans doute d'un autre type d'objets.

Sujet: re Lun 3 Sep 2012 - 22:29

Il l'a fait sans que je tilte sur la fonction... Laughing

ce n'était que pour un picture...
res% = dll_call2("ClickSetLink",hnd_button%,typ%)

edit : rater ! pas de handle pour picture !

Sujet: re Mar 4 Sep 2012 - 1:10

Vous pourrez trouver les avancées du source sur mon webdav:

http://www.mydrive.ch/
panoramic@ygeronimi
panoramic123

Sujet: Re: J'ai copié sur Bignono Mar 4 Sep 2012 - 3:11

Hello ygeronimi

J’ai visité ton Web-Dav pour télécharger 3DS VIEWER.ZIP

J’ai adapté TOP 0 et LEFT 0 à mon écran.
En cliquant sur Liste, lorsque celle-ci est vide, on a un message d’erreur.
Et même lorsque la liste n’est pas vide, mais on clique sur un objet quelconque des différents CONTAINER avant de sélectionner un fichier, on a également un message d’erreur.
Pour remédier à ceci, j’ai apporté quelques modifications au programme :
J’ai d’abord mis tous les CONTAINER (de 12 à 17) HIDE.
J’ai ajouté une condition d’existence de fichiers avant le chargement de la liste.
Et, après sélection d’un fichier, j’ai mis les CONTAINER à SHOW.

Je te remets le code modifié.
Pour repérer facilement les lignes modifiées ou ajoutées, j’ai mis, à la fin de chaque ligne une REM ‘papydall

Code:: ' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
' ¤ 3DS Viewer version 1.0 ¤
' ¤ créé par ygeronimi ¤
' ¤ le 02/09/2012 ¤
' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤

dim x%,y%
dim D$,D3D$,DL$
dim Menu%,F$
dim File$,V,Dir%,x,y,z,PC%,Cx,Cy,Cz
' ------------------------------------------------------------------------------
label Init_prog,Init_Doss,Init_Langue,Init_Image
label Create_File_Image
label Menu,Selection,Valid_Selection,Init_Scene,Langue,APp,AIde
label Zoom,Rotation_X,Rotation_Y,Rotation_Z,Direction
label Position_Cam
label Quitter
' ******************************************************************************
width 0,1400:height 0,820
top 0,(screen_y-780)/2:left 0,(screen_x-1040)/2: ' papydall
caption 0,"3DS Viewer"
font_name 0,"Times new roman":font_size 0,10

main_menu 1
for x%=2 to 5:sub_menu x% :parent x%,1:on_click x%,Menu:next x%
caption 2,"Liste":caption 3,"langue":caption 4,"A Propos...":caption 5,"Aide"

scene3d 11:top 11,0:left 11,0:width 11,1184:height 11,762:color 11,0,0,0
3d_target_is 11

container 12:top 12,0 :left 12,1194:height 12,70 :caption 12,chr$(32)+"Zoom"+chr$(32)
font_color 12,120,20,10 : hide 12 : ' papydall
scroll_bar 121:parent 121,12:top 121,25:left 121,13:width 121,160:min 121,1:max 121,2000
position 121,0.001:on_change 121,Zoom
alpha 122:parent 122,12:top 122,45:left 122,80:font_color 122,0,0,255

container 13:top 13,75:left 13,1194:height 13,120:caption 13,chr$(32)+"Rotation de l'objet"+chr$(32)
font_color 13,120,20,10 : hide 13 : ' papydall
alpha 131:parent 131,13:top 131,15 :left 131,13:caption 131,"Axe X":font_color 131,0,0,255
scroll_bar 132:parent 132,13:top 132,30:left 132,13:width 132,160:min 132,0:max 132,359
position 132,0:on_change 132,Rotation_X
alpha 133:parent 133,13:top 133,50 :left 133,13:caption 133,"Axe Y":font_color 133,0,0,255
scroll_bar 134:parent 134,13:top 134,65:left 134,13:width 134,160:min 134,0:max 134,359
position 134,0:on_change 134,Rotation_Y
alpha 135:parent 135,13:top 135,85 :left 135,13:caption 135,"Axe Z":font_color 135,0,0,255
scroll_bar 136:parent 136,13:top 136,100:left 136,13:width 136,160:min 136,0:max 136,359
position 136,0:on_change 136,Rotation_Z

container 14:top 14,200:left 14,1194:height 14,120:caption 14,chr$(32)+"Déplacement de l' objet"+chr$(32)
font_color 14,120,20,10 : hide 14 : ' papydall
for x%=141 to 150:button x% :parent x%,14:font_name x%,"webdings":font_size x%,12 :on_click x%,Direction:next x%
for x%=141 to 148:width x%,30:height x%,30:next x%
for x%=149 to 150:width x%,30:height x%,15:next x%
top 141,20:left 141,80
top 142,20:left 142,110 :caption 142,"5"
top 143,20:left 143,140
top 144,50:left 144,80 :caption 144,"3"
top 145,50:left 145,140:caption 145,"4"
top 146,80:left 146,80
top 147,80:left 147,110 :caption 147,"6"
top 148,80:left 148,140
top 149,50:left 149,110 :caption 149,"5"
top 150,65:left 150,110 :caption 150,"6"

container 15:top 15,325:left 15,1194:height 15,250:caption 15,chr$(32)+"Caméra"+chr$(32)
font_color 15,120,20,10 : hide 15 : ' papydall
alpha 151 :parent 151,15:top 151,20 :left 151,13:caption 151,"Axe X":font_color 151,0,0,255
scroll_bar 152:parent 152,15:top 152,35 :left 152,13:min 152,0:max 152,100:on_change 152,Position_Cam
alpha 153 :parent 153,15:top 153,55 :left 153,13:caption 153,"Axe Y":font_color 153,0,0,255
scroll_bar 154:parent 154,15:top 154,70 :left 154,13:min 154,0:max 154,100:on_change 154,Position_Cam
alpha 155 :parent 155,15:top 155,90 :left 155,13:caption 155,"Axe Z":font_color 155,0,0,255
scroll_bar 156:parent 156,15:top 156,105:left 156,13:min 156,0:max 156,100:on_change 156,Position_Cam
y%=-15
for x%=157 to 159:y%=y%+35:alpha x%:parent x%,15:top x%,y%:left x%,50:font_name x%,"arial":font_size x%,8:font_color x%,255,0,0:next x%

container 16:top 16,580:left 16,1194:height 16,70 :caption 16,chr$(32)+"Couleur de l' objet"+chr$(32)
font_color 16,120,20,10 : hide 16 : ' papydall

container 17:top 17,655:left 17,1194:height 17,70 :caption 17,chr$(32)+"Texture de l' objet"+chr$(32)
font_color 17,120,20,10 : hide 17 : ' papydall

dlist 99

gosub Init_prog
on_close 0,Quitter
end
' ******************************************************************************
Init_Prog:
gosub Init_Doss
gosub Init_Langue
gosub Init_Image
return
' ------------------------------------------------------------------------------
Init_Doss:
D$=dir_current$
if dir_exists(D$+"\3D")=0 then dir_make D$+"\3D"
D3D$=D$+"\3D"
if dir_exists(D$+"\Langues")=0 then dir_make D$+"\Langues"
DL$=D$+"\Langues"
gosub Create_File_Image
return
' ------------------------------------------------------------------------------
Init_Langue:
return
' ------------------------------------------------------------------------------
Init_Image:
return
' ------------------------------------------------------------------------------
Menu:
for x%=2 to 5
if clicked(x%)=1 then Menu%=x%
next x%
select Menu%
case 2
gosub Selection
case 3
gosub Langue
case 4
gosub APp
case 5
gosub Aide
end_select
return
' ------------------------------------------------------------------------------
Selection:
form 100:width 100,200:height 100,300:caption 100,"Sélection"
font_name 100,"Times new roman":font_size 100,10
command_target_is 100
list 101:width 101,184:height 101,240:on_double_click 101,Valid_Selection
alpha 102:top 102,240:left 102,5:caption 102,"Double cliquez pour sélectionner"
font_color 102,0,0,255
' Placement de l'appli dans le dossier où sont les fichiers 3d
dir_change D3D$
' Récupération des adresses des fichiers 3DS et 3ds
F$=file_find_first$
if file_extract_extension$(F$)=".3DS" or file_extract_extension$(F$)=".3ds" then item_add 99,F$
F$=file_find_next$
while F$<>"_"
if file_extract_extension$(F$)=".3DS" or file_extract_extension$(F$)=".3ds" then item_add 99,F$
F$=file_find_next$
end_while
file_find_close
' Affichage des fichiers récupérés dans le list 101
if count(99) > 0 : ' papydall
for x%=1 to count(99)
F$=item_read$(99,x%)
item_add 101,left$(file_extract_name$(F$),len(file_extract_name$(F$))-4)
next x%
for x% = 12 to 17 : show x% : next x% : ' papydall
else : ' papydall
message "liste vide" : ' papydall
end_if : ' papydall
command_target_is 0
return
' ------------------------------------------------------------------------------
Valid_Selection:
if o3d_object_exists(1)=1 then 3d_delete 1
File$=D3D$+"\"+item_read$(99,item_index(101))
3d_mesh 1
3d_load_object 1,File$
gosub Init_Scene
clear 99
delete 100
return
' ------------------------------------------------------------------------------
Init_Scene:
position 121,1:position 132,0:position 134,0:position 136,0
gosub Zoom
position 152,0:position 154,0:position 156,5
gosub Position_Cam
return
' ------------------------------------------------------------------------------
Langue:
message "En cours d'écriture"
return
' ------------------------------------------------------------------------------
APp:
message "En cours d'écriture"
return
' ------------------------------------------------------------------------------
Aide:
message "Sera créé si nécessaire"
return
' ------------------------------------------------------------------------------
Zoom:
V=position(121)/1000
if O3D_object_exists(1) = 1 then 3d_scale 1,V,V,V
caption 122,str$(V)
return
' ------------------------------------------------------------------------------
Rotation_X:
3d_x_rotate 1,position(132)
return
' ------------------------------------------------------------------------------
Rotation_Y:
3d_y_rotate 1,position(134)
return
' ------------------------------------------------------------------------------
Rotation_Z:
3d_z_rotate 1,position(136)
return
' ------------------------------------------------------------------------------
Direction:
for x%=141 to 150
if clicked(x%)=1 then Dir%=x%
next x%
select Dir%
case 141
' decale vers haut gauche
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y+0.1:x=x-0.1:3d_position 1,x,y,z
case 142
' decale vers haut
y=o3d_y_position(1):y=y+0.1:3d_y_position 1,y
case 143
' decale vers haut droit
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y+0.1:x=x+0.1:3d_position 1,x,y,z
case 144
' decale vers gauche
x=o3d_x_position(1):x=x-0.1:3d_x_position 1,x
case 145
' decale vers droite
x=o3d_x_position(1):x=x+0.1:3d_x_position 1,x
case 146
' decale vers bas gauche
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y-0.1:x=x-0.1:3d_position 1,x,y,z
case 147
' decale vers bas
y=o3d_y_position(1):y=y-0.1:3d_y_position 1,y
case 148
' decale vers bas droite
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y-0.1:x=x+0.1:3d_position 1,x,y,z
case 149
' decale vers fond
z=o3d_z_position(1):z=z+0.1:3d_z_position 1,z
case 150
' decale vers avant
z=o3d_z_position(1):z=z-0.1:3d_z_position 1,z
end_select
return
' ------------------------------------------------------------------------------
Position_Cam:
if O3D_object_exists(1) = 1
Cx=Position(152):Cy=Position(154):Cz=Position(156)
caption 157,"("+str$(Cx)+")":caption 158,"("+str$(Cy)+")":caption 159,"("+str$(Cz)+")"
cam_position Cx,Cy,Cz
end_if
return
' ------------------------------------------------------------------------------
' Place des #include
#include "Include_Image.bas"
' ------------------------------------------------------------------------------
Quitter:
terminate

Après la sélection d’un fichier de la liste, j’ai un message d’erreur ‘Privileged instruction’.
En cliquant sur OK le programme continue normalement.

Sujet: re Mar 4 Sep 2012 - 4:02

Je fais une cafetière et je regarde çà... Laughing

Sujet: re Mar 4 Sep 2012 - 5:45

Quelques modifs :

J'ai modifié la fonction "Selection" et je crois que j'ai évité ton message "Privileged Instruction"
J'ai créé et "hider" les "container" dès le départ et mis "show" en condition de sélection d'un fichier
dans le "list 101".

... et des évolutions mais...faudra télécharger sur le webdav... SURPRISES !!!! Laughing

bon ...maintenant... Sleep

Sujet: Re: J'ai copié sur Bignono Mar 4 Sep 2012 - 17:49

Salut ygeronimi

Ton 3DS Viewer commence à devenir intéressant, BRAVO.
Une suggestion : si après avoir choisis un objet de la liste, tu affiches, sur la fenêtre active ou ailleurs, le nom de l’objet.
Idem pour le nom de la texture.
Comme ça, en voulant charger une texture, on ne se trompe pas sur le nom, bien que dans ce cas (si on choisit une texture qui n’est pas la bonne) on obtient une forme assez étrange !

Comme cadeau pour toi, je t’offre des objets 3DS avec leurs textures que tu peux télécharger sur mon Web-Dav.
Essaye-les avec 3DS Viewer : ce sont des beaux poissons.

http://www.mydrive.ch/
identifiant: panoramic@papydall
mot de passe: panoramic123

Dossier : Pour Ygeronimi (qui contient 2 fichiers) :
3D.zip contenant les objets
Textures.zip contenant les textures.

Voici ce que tu peux obtenir!

Sujet: re Mar 4 Sep 2012 - 18:14

Merci du cadeau papydall !

ils sont géniaux ces poissons !

J' des objets avec des textures mais elles ne sont pas faites pour Panoramic
et en plusieurs images jpg.

Comment fais tu tes textures, il y a un ordre, un placement précis ?

Sujet: re Mar 4 Sep 2012 - 18:23

@ papydall,

Concernant le viewer, il va évoluer, ce n'était qu'un premier jet
pour prendre en main les commandes 3d.
C' est pour cela que certain menus sont vides.

@ Jack,

Je ne sais si cela est possible mais si elle faisait parti des commandes déjà codées
une petite commande pour effacer une texture de façon à pouvoir en revenir
à l'application d'une couleur.

Sujet: Re: J'ai copié sur Bignono Mar 4 Sep 2012 - 18:43

ygeronimi a écrit:: Merci du cadeau papydall !
ils sont géniaux ces poissons !
J' des objets avec des textures mais elles ne sont pas faites pour Panoramic
et en plusieurs images jpg.
Comment fais tu tes textures, il y a un ordre, un placement précis ?

Les textures, ce n’est pas moi qui les ai faites. Je les ai téléchargées sur internet.

Panoramic supporte le 2 formats de textures : les .BMP et le .JPG

Ma science s’arrête là.

Sujet: Re: J'ai copié sur Bignono Mar 4 Sep 2012 - 19:57

ygeronimi a écrit:: @ Jack,

Je ne sais si cela est possible mais si elle faisait parti des commandes déjà codées
une petite commande pour effacer une texture de façon à pouvoir en revenir
à l'application d'une couleur.

Une commande par exemple ‘ 3d_delete_texture N’ serait la bienvenue.

A défaut, voici une alternative :
Tu charges ton objet par ‘ 3d_load_object n, …’
Tu charges ensuite ta texture par ‘3d_load_texture n ,….’

Tu veux revenir à ton objet sans la texture :
Tu effaces l’objet par ‘3d_delete n’ : l’objet ainsi que la texture sont effacés.
Tu recharges l’objet (sans recharger la texture) par ‘3d_load_object n,….’

Ça y est : tu as obtenu ce que tu voulais.

Voici un exemple de code

Code:: dim rep$
rep$ = dir_current$ +"\"
full_space 0 : scene3d 1 : full_space 1 : color 1,100,150,50
cam_position 0,0,5 : point_position 0,0,0
' on charge l'objet et la texture
3d_mesh 1 : 3d_load_object 1,rep$+"flower1.3ds" : 3d_load_texture 1,rep$+"flower1.bmp"
3d_position 1,-2,4,-10 : 3d_scale 1,.25,.25,.25 : 3d_x_rotate 1,90 : 3d_z_rotate 1,180

wait 2000
' on efface l'objet et la texture
3d_delete 1
' on recharge l'objet sans la texture
3d_mesh 1 : 3d_load_object 1,rep$+"flower1.3ds"
3d_position 1,-2,4,-10 : 3d_scale 1,.25,.25,.25 : 3d_x_rotate 1,90 : 3d_z_rotate 1,180

end

Sujet: re Mar 4 Sep 2012 - 20:17

@ papydall,

Je vais me concentrer sur la version 2 de 3DS Viewer et après j'étudierai les textures,
Chaque chose en son temps... Laughing

Sujet: re Mer 5 Sep 2012 - 1:11

La version 2 de "3DS Viewer" est sur mon webdav

Edit : il y a encore des menus à finir mais çà s'approche...

Sujet: Re: J'ai copié sur Bignono Mer 5 Sep 2012 - 1:13

Salut ygeronimi

SPIN 172, SPIN 173 et SPIN 174 : si on saisit, dans l’un de ces SPIN (dans le CONTAINER 17 : couleur de l’objet), une valeur supérieure à 255, on a un message d’erreur et c’est normal !
Pour l’éviter :
Dans le sous-programme ‘Coloration’, ajoute les tests nécessaires sur les variables R1%, G1%, B1%

Code:: Coloration:
R1%=val(text$(172)):G1%=val(text$(173)):B1%=val(text$(174))
if r1% > 255 then r1% = 255
if g1% > 255 then g1% = 255
if b1% > 255 then b1% = 255
color 171,R1%,G1%,B1%
return

PS : j'ai envoyé ce message avant de voir le tien.

Sujet: Re: J'ai copié sur Bignono Mer 5 Sep 2012 - 1:31

Ca prends forme, tu avance bien Wink

2 petites améliorations minimes pour éviter les vilains messages:

Code:: Coloration:
if numeric(text$(172))=1 then R1%=val(text$(172))
if numeric(text$(173))=1 then G1%=val(text$(173))
if numeric(text$(174))=1 then B1%=val(text$(174))
color 171,R1%,G1%,B1%
return

et

Code:: Couleur_Fond:
if numeric(text$(402))=1 then R2%=val(text$(402))
if numeric(text$(403))=1 then G2%=val(text$(403))
if numeric(text$(404))=1 then B2%=val(text$(404))
Color 401,R2%,G2%,B2%
return

Je me suis fais un dossier capture et avec la DLL de Klaus, je fais des captures des objets 3D pour voir ce qu'ils donnent dans Panoramic

Je te mets le source pour s'y tu veux ajouter l'outil

Code:: dim i,rep$, dirKGF$,num_objet%,num_objet1%,nom$
num_objet%=200 : num_objet1%=100 : rep$ = dir_current$ + "\"
dirKGF$ = "C:\Panoramic-Init\sources\"
image 2 : dll_on dirKGF$+"KGF.dll"

nom$="hummer2"

full_space 0:scene3d 1:full_space 1:color 1,100,100,0
light_position 50,300,0: cam_position 0,4,4:point_position 0,0,0

3d_mesh 1:3d_load_object 1,rep$+ "3D\"+nom$+".3ds"
3d_position 1,0,0,0 :3d_scale 1,2,2,2 : 3d_x_rotate 1,90: 3d_y_rotate 1,0 : 3d_z_rotate 1,60
caption 0,rep$
if file_exists(rep$+ "Textures\"+nom$+".bmp") = 1 then 3d_load_texture 1,rep$+ "Textures\"+nom$+".bmp"

pause num_objet% : ' num_objet%>=200 sinon la transparence apparaîtra et l'image commence à se déformer

i = dll_call1("ScreenCopy",2)
pause num_objet1% : ' num_objet1%>=100 sinon la Form 0 ne s'est pas encore complètement affichée.

clipboard_paste 2
file_save 2,rep$+"Captures\C_"+nom$+".bmp"

wait 1000

dll_off
terminate

Sujet: Re: J'ai copié sur Bignono Mer 5 Sep 2012 - 1:35

Et ajouter le test de Papydall après, bien sûr Wink

Bonn aller, bonne nuit

Sujet: re Mer 5 Sep 2012 - 1:37

Le spin est fait pour être utilisé avec ses flèches "haut", "bas"
et fonctionne avec "min" et "max" pour pouvoir cibler une fourchette de valeur
à ne pas dépasser ou à ne pas être inferieur.
pour les "spin" couleur "min" est à 0 et "max" à 255 ce qui correspond aux couleurs RGB

en plus, la fonction associé est "on_change", si tu entres au clavier une valeur, tu seras forcemment
soit à "" et la fonction renvoie une erreur .

la seule chose possible par une entrée au clavier, pour que ce soit plus rapide, c'est que le spin soit >0
et là tu peux voir le curseur dans la partie "edit" du "spin" qui clignote et à ce moment tu peus inserer un chiffre

Sujet: re Mer 5 Sep 2012 - 1:47

@ Jicehel et Papydall,

Un spin est forcement numérique cf :

J'ai copié sur Bignono - Page 4 Captur36

bon c'est pas "on_click" mais "on_change" petite erreur de doc.

Il n'est pas fait pour que l'utilisateur entre une données et même avec vos testes si vous entrez un valeur au clavier
il y aura une erreur. ( sauf si spin>0 et les chiffres entrés ne passent pas le "spin" au dessus de 255)

@ Jicehel,

Merci pour l'outils, je vais voir comment l'intégrer...

Sujet: re Mer 5 Sep 2012 - 2:06

@ Jicehel,

à quoi correspondent Num_objet% et Num_objet1% ? scratch

Sujet: Re: J'ai copié sur Bignono Mer 5 Sep 2012 - 3:34

ygeronimi a écrit:: @ Jicehel,

à quoi correspondent Num_objet% et Num_objet1% ?

Ça servent comme valeurs de temporisation pour que le système puisse avoir le temps nécessaire pour l’affichage !
C’est expliqué dans le code.

Pour le SPIN, je ne suis pas d’accord. Laughing

Fais des beaux rêves avec 3D Viewer! Laughing

Quant à moi, je fais faire Sleep

Buonna notte

Sujet: re Mer 5 Sep 2012 - 4:37

les dernières avancés !!!

Lumière + Capture de la fenêtre !!!

Y a mieux mais c'est plus cher !!! Laughing

Code:: dim x%,y%,lang$,def$(200),a$
dim D$,D3D$,DL$,DT$,F$,DC$
dim Menu_P% ,Menu_O%
dim File$,V,Dir%,x,y,z,PC%,Cx,Cy,Cz,PVx,PVy,PVz
dim Teint%,R1%,G1%,B1%,Texture$,R2%,G2%,B2%
dim left_f%, top_f%
dim Lx,Ly,Lz,res%,nom$
left_f%=(screen_x-816)/2: top_f% =(screen_y-658)/2

' ------------------------------------------------------------------------------
Label Init_Prog,Init_Path,Init_Langue,Init_Caption,Init_Scene
label Create_File_Image,Create_File_Langue
label Menu_Principal,Ouvrir,Valid_Selection,Quitter,Outils,Fond,Couleur_Fond,Appli_Fond,Langue,APp,Aide
label Menu_Outils
label Zoom,Rotation_X,Rotation_Y,Rotation_Z,Direction
label Position_Cam,Position_PV,Coloration,Appli_Color,Appli_Texture
label Lumiere,Capture
' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
height 0,658:width 0,816:top 0,top_f% :left 0,left_f%
font_name 0,"Times new roman":font_size 0,10:Caption 0,"3DS Viewer"

main_menu 1
for x%=2 to 6 :sub_menu x% :parent x%,1:on_click x%,Menu_Principal:next x%
for x%=7 to 8 :sub_menu x% :parent x%,2:on_click x%,Menu_Principal:next x%
for x%=9 to 10:sub_menu x% :parent x%,4:on_click x%,Menu_Principal:next x%
inactive 3
scene3d 11:height 11,600:width 11,800:color 11,0,0,0
3d_target_is 11

dlist 14 :' Liste des langues
dlist 13 :' Liste des captions
dlist 99 :' Liste des fichiers 3DS

Image 98

gosub Init_Prog
end
' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
Init_Prog:
gosub Init_Path
gosub Outils
gosub Init_Langue
return
' ------------------------------------------------------------------------------
Init_Path:
D$=dir_current$
if dir_exists(D$+"\Capture")=0 then dir_make D$+"\Capture"
DC$=D$+"\Capture"
if dir_exists(D$+"\3D")=0 then dir_make D$+"\3D"
D3D$=D$+"\3D"
if dir_exists(D$+"\Langues")=0 then dir_make D$+"\Langues"
DL$=D$+"\Langues"
if dir_exists(D$+"\Textures")=0 then dir_make D$+"\Textures"
DT$=D$+"\Textures"
gosub Create_File_Image
if file_exists(D$+"\Param.inf")=0
file_open_write 1000,D$+"\Param.inf"
lang$="French"
file_writeln 1000,lang$
file_close 1000
gosub Create_File_Langue
else
file_open_read 1000,D$+"\Param.inf"
file_readln 1000,lang$
file_close 1000
end_if
return
' ------------------------------------------------------------------------------
Init_Langue:
clear 13
file_load 13,DL$+"\"+Lang$+".txt"
for x%=1 to count(13):def$(x%)=item_read$(13,x%):next x%
gosub Init_Caption
return
' ------------------------------------------------------------------------------
Init_Caption:
for x%=2 to 10 :caption x%,def$(x%):next x%
if object_exists(100)=1
caption 100,def$(3)
for x%=22 to 25:caption x%,chr$(32)+def$(x%-11)+chr$(32):next x%
caption 123,def$(15)
caption 160,def$(17)
caption 170,def$(16)
caption 175,def$(20)
caption 179,def$(18)
caption 180,def$(19)
caption 181,def$(21)
caption 106,def$(22)
caption 26,chr$(32)+def$(22)+chr$(32)
caption 107,def$(23)
caption 200,def$(22)
end_if
for x%=102 to 105:caption x%,def$(x%-91):next x%
return
' ------------------------------------------------------------------------------
Init_Scene:
position 121,1:position 132,0:position 134,0:position 136,0
gosub Zoom
position 152,0:position 154,0:position 156,5
gosub Position_Cam
position 202,0:position 204,0:position 206,5
gosub Lumiere
return
' ------------------------------------------------------------------------------
Menu_Principal:
for x%=2 to 10
if clicked(x%)=1 Then Menu_P%=x%
next x%
select Menu_P%
case 2
case 3
if object_exists(100)=1 then show 100
case 4
case 5
gosub APp
case 6
gosub Aide
case 7
gosub Ouvrir
case 8
gosub Quitter
case 9
gosub Fond
case 10
gosub Langue
end_select
return
' ------------------------------------------------------------------------------
Ouvrir:
' Placement de l'appli dans le dossier où sont les fichiers 3d
dir_change D3D$
' Récupération des adresses des fichiers 3DS et 3ds
F$=file_find_first$
if file_extract_extension$(F$)=".3DS" or file_extract_extension$(F$)=".3ds" then item_add 99,F$
F$=file_find_next$
while F$<>"_"
if file_extract_extension$(F$)=".3DS" or file_extract_extension$(F$)=".3ds" then item_add 99,F$
F$=file_find_next$
end_while
file_find_close
if count(99)>0
form 500:top 500,top_f%+54:left 500,left_f%+8:width 500,200:height 500,300:caption 500,"Sélection"
font_name 500,"Times new roman":font_size 500,10
command_target_is 500
list 501:width 501,184:height 501,240:cursor_point 501:on_double_click 501,Valid_Selection
alpha 502:top 502,240:left 502,5:caption 502,"Double cliquez pour sélectionner"
font_color 502,0,0,255
' Affichage des fichiers récupérés dans le list 101
for x%=1 to count(99)
F$=item_read$(99,x%)
item_add 501,left$(file_extract_name$(F$),len(file_extract_name$(F$))-4)
next x%
command_target_is 0
else
Message "Le dossier 3D est vide !"
end_if
return
' ------------------------------------------------------------------------------
Valid_Selection:
if o3d_object_exists(1)=1 then 3d_delete 1
File$=D3D$+"\"+item_read$(99,item_index(501))
caption 0,"3DS Viewer"+chr$(32)+"("+chr$(32)+file_extract_name$(File$)+chr$(32)+")"
nom$=file_extract_name$(file$)
nom$=left$(nom$,len(nom$)-4)
3d_mesh 1
3d_load_object 1,File$
gosub Init_Scene
clear 99
delete 500
if file$<>"_" then active 3
return
' ------------------------------------------------------------------------------
Fond:
form 400:width 400,250:height 400,150:top 400,(screen_y-150)/2:left 400,(screen_x-250)/2
font_name 400,"Times new roman":font_size 400,10:caption 400,"Couleur de fond"
command_target_is 400
picture 401:height 401,70:width 401,70:top 401,5:left 401,5:color 401,0,0,0
spin 402:top 402,5 :left 402,80:width 402,45:font_color 402,255,0,0:cursor_point 402:min 402,0:max 402,255
spin 403:top 403,30:left 403,80:width 403,45:font_color 403,0,255,0:cursor_point 403:min 403,0:max 403,255
spin 404:top 404,55:left 404,80:width 404,45:font_color 404,0,0,255:cursor_point 404:min 404,0:max 404,255
button 405:top 405,85:left 405,155:cursor_point 405:caption 405,"Appliquer"
for x%=402 to 404:on_change x%,Couleur_Fond:next x%
on_click 405,Appli_Fond
command_target_is 0
return
' ------------------------------------------------------------------------------
Couleur_Fond:
R2%=val(text$(402)):G2%=val(text$(403)):B2%=val(text$(404))
Color 401,R2%,G2%,B2%
return
' ------------------------------------------------------------------------------
Appli_Fond:
Color 11,R2%,G2%,B2%
delete 400
return
' ------------------------------------------------------------------------------
Langue:
message "En cours"
return
' ------------------------------------------------------------------------------
APp:
message "En cours"
return
' ------------------------------------------------------------------------------
Aide:
message "En cours"
return
' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
Outils:
Form 100:hide 100:height 100,300:width 100,410
font_name 100,"Times new roman":font_size 100,10
command_target_is 100

main_menu 101
for x%=102 to 107:sub_menu x% :parent x%,101:on_click x%,Menu_Outils :next x%
for x%=22 to 26:container x%:hide x% :next x%

' Contenu du container 22 Zoom / Déplacement
top 22,5:left 22,10:height 22,205:width 22,375
font_color 22,120,20,10

scroll_bar 121:parent 121,22:top 121,40:left 121,13:width 121,160:min 121,1:max 121,2000
position 121,0.001:on_change 121,Zoom
alpha 122:parent 122,22:top 122,60:left 122,80:font_color 122,0,0,255
for x%=141 to 150:button x% :parent x%,22:font_name x%,"webdings":font_size x%,12 :on_click x%,Direction:next x%
for x%=141 to 148:width x%,30:height x%,30:next x%
for x%=149 to 150:width x%,30:height x%,15:next x%
top 141,90:left 141,230
top 142,90:left 142,260 :caption 142,"5"
top 143,90:left 143,290
top 144,120:left 144,230 :caption 144,"3"
top 145,120:left 145,290:caption 145,"4"
top 146,150:left 146,230
top 147,150:left 147,260 :caption 147,"6"
top 148,150:left 148,290
top 149,120:left 149,260 :caption 149,"5"
top 150,135:left 150,260 :caption 150,"6"
alpha 123:parent 123,22:top 123,185:left 123,230

' Contenu du container 23 Rotation
top 23,5:left 23,10:height 23,205:width 23,375
font_color 23,120,20,10

alpha 131:parent 131,23:top 131,35 :left 131,13:caption 131,"Axe X":font_color 131,0,0,255
scroll_bar 132:parent 132,23:top 132,50:left 132,13:width 132,160:min 132,0:max 132,359
position 132,0:on_change 132,Rotation_X
alpha 133:parent 133,23:top 133,70 :left 133,13:caption 133,"Axe Y":font_color 133,0,0,255
scroll_bar 134:parent 134,23:top 134,85:left 134,13:width 134,160:min 134,0:max 134,359
position 134,0:on_change 134,Rotation_Y
alpha 135:parent 135,23:top 135,105 :left 135,13:caption 135,"Axe Z":font_color 135,0,0,255
scroll_bar 136:parent 136,23:top 136,120:left 136,13:width 136,160:min 136,0:max 136,359
position 136,0:on_change 136,Rotation_Z

' Contenu du container 24 Caméra
top 24,5:left 24,10:height 24,205:width 24,375
font_color 24,120,20,10

alpha 151 :parent 151,24:top 151,45 :left 151,13:caption 151,"Axe X":font_color 151,0,0,255
scroll_bar 152:parent 152,24:top 152,60 :left 152,13:min 152,0:max 152,100:on_change 152,Position_Cam
alpha 153 :parent 153,24:top 153,80 :left 153,13:caption 153,"Axe Y":font_color 153,0,0,255
scroll_bar 154:parent 154,24:top 154,95 :left 154,13:min 154,0:max 154,100:on_change 154,Position_Cam
alpha 155 :parent 155,24:top 155,115:left 155,13:caption 155,"Axe Z":font_color 155,0,0,255
scroll_bar 156:parent 156,24:top 156,130:left 156,13:min 156,0:max 156,100:on_change 156,Position_Cam
y%=10
for x%=157 to 159:y%=y%+35:alpha x%:parent x%,24:top x%,y%:left x%,50:font_name x%,"arial":font_size x%,8:font_color x%,255,0,0:next x%
alpha 160:parent 160,24:top 160,30:left 160,250

alpha 161 :parent 161,24:top 161,45 :left 161,213:caption 161,"Axe X":font_color 161,0,0,255
scroll_bar 162:parent 162,24:top 162,60 :left 162,213:min 162,-100:max 162,100:on_change 162,Position_PV
alpha 163 :parent 163,24:top 163,80 :left 163,213:caption 163,"Axe Y":font_color 163,0,0,255
scroll_bar 164:parent 164,24:top 164,95 :left 164,213:min 164,-100:max 164,100:on_change 164,Position_PV
alpha 165 :parent 165,24:top 165,115:left 165,213:caption 165,"Axe Z":font_color 165,0,0,255
scroll_bar 166:parent 166,24:top 166,130:left 166,213:min 166,-100:max 166,100:on_change 166,Position_PV
y%=10
for x%=167 to 169:y%=y%+35:alpha x%:parent x%,24:top x%,y%:left x%,250:font_name x%,"arial":font_size x%,8:font_color x%,255,0,0:next x%
alpha 170:parent 170,24:top 170,30:left 170,50

' Contenu du container 25 Habillage
top 25,5:left 25,10:height 25,205:width 25,375
font_color 25,120,20,10

picture 171 :parent 171,25:width 171,40:height 171,40:top 171,60:left 171,25:color 171,0,0,0
spin 172 :parent 172,25:height 172,15:width 172,45:top 172,50:left 172,70:min 172,0:max 172,255
font_size 172,8:font_name 172,"arial":font_color 172,255,0,0:on_change 172,Coloration
spin 173 :parent 173,25:height 173,15:width 173,45:top 173,70:left 173,70:min 173,0:max 173,255
font_size 173,8:font_name 173,"arial":font_color 173,0,255,0:on_change 173,Coloration
spin 174 :parent 174,25:height 174,15:width 174,45:top 174,90:left 174,70:min 174,0:max 174,255
font_size 174,8:font_name 174,"arial":font_color 174,0,0,255:on_change 174,Coloration
button 175 :parent 175,25:width 175,70:top 175,120:left 175,40
cursor_point 175:on_click 175,Appli_Color
alpha 179 :parent 179,25:top 179,30 :Left 179,25
alpha 180 :parent 180,25:top 180,110:Left 180,220
button 181 :parent 181,25:top 181,130:left 181,220:width 181,140
cursor_point 181:on_click 181,Appli_Texture

' Contenu du container 26 Lumière
top 26,5:left 26,10:height 26,205:width 26,375
font_color 26,120,20,10

alpha 201 :parent 201,26:top 201,45 :left 201,213:caption 201,"Axe X":font_color 201,0,0,255
scroll_bar 202:parent 202,26:top 202,60 :left 202,213:min 202,0:max 202,359:on_change 202,Lumiere
alpha 203 :parent 203,26:top 203,80 :left 203,213:caption 203,"Axe Y":font_color 203,0,0,255
scroll_bar 204:parent 204,26:top 204,95 :left 204,213:min 204,0:max 204,359:on_change 204,Lumiere
alpha 205 :parent 205,26:top 205,115:left 205,213:caption 205,"Axe Z":font_color 205,0,0,255
scroll_bar 206:parent 206,26:top 206,130:left 206,213:min 206,0:max 206,359:on_change 206,Lumiere
y%=10
for x%=207 to 209:y%=y%+35:alpha x%:parent x%,26:top x%,y%:left x%,250:font_name x%,"arial":font_size x%,8:font_color x%,255,0,0:next x%
alpha 200:parent 200,26:top 200,30:left 200,250
command_target_is 0
return
' ¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤
Menu_Outils:
for x%=102 to 107
if clicked(x%)=1 then Menu_O% =x%
next x%
select Menu_O%
case 102
show 22
hide 23:hide 24:hide 25:hide 26
case 103
show 23
hide 22:hide 24:hide 25:hide 26
case 104
show 24
hide 25:hide 23:hide 22:hide 26
case 105
show 25
hide 22:hide 23:hide 24:hide 26
case 106
show 26
hide 22:hide 23:hide 24:hide 25
case 107
gosub Capture
end_select
return
' ------------------------------------------------------------------------------
Zoom:
V=position(121)/1000
if O3D_object_exists(1) = 1 then 3d_scale 1,V,V,V
caption 122,str$(V)
return
' ------------------------------------------------------------------------------
Rotation_X:
3d_x_rotate 1,position(132)
return
' ------------------------------------------------------------------------------
Rotation_Y:
3d_y_rotate 1,position(134)
return
' ------------------------------------------------------------------------------
Rotation_Z:
3d_z_rotate 1,position(136)
return
' ------------------------------------------------------------------------------
Direction:
for x%=141 to 150
if clicked(x%)=1 then Dir%=x%
next x%
select Dir%
case 141
' decale vers haut gauche
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y+0.1:x=x-0.1:3d_position 1,x,y,z
case 142
' decale vers haut
y=o3d_y_position(1):y=y+0.1:3d_y_position 1,y
case 143
' decale vers haut droit
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y+0.1:x=x+0.1:3d_position 1,x,y,z
case 144
' decale vers gauche
x=o3d_x_position(1):x=x-0.1:3d_x_position 1,x
case 145
' decale vers droite
x=o3d_x_position(1):x=x+0.1:3d_x_position 1,x
case 146
' decale vers bas gauche
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y-0.1:x=x-0.1:3d_position 1,x,y,z
case 147
' decale vers bas
y=o3d_y_position(1):y=y-0.1:3d_y_position 1,y
case 148
' decale vers bas droite
y=o3d_y_position(1):x=o3d_x_position(1):z=o3d_z_position(1)
y=y-0.1:x=x+0.1:3d_position 1,x,y,z
case 149
' decale vers fond
z=o3d_z_position(1):z=z+0.1:3d_z_position 1,z
case 150
' decale vers avant
z=o3d_z_position(1):z=z-0.1:3d_z_position 1,z
end_select
return
' ------------------------------------------------------------------------------
Position_Cam:
if O3D_object_exists(1) = 1
Cx=Position(152):Cy=Position(154):Cz=Position(156)
caption 157,"("+str$(Cx)+")":caption 158,"("+str$(Cy)+")":caption 159,"("+str$(Cz)+")"
cam_position Cx,Cy,Cz
end_if
return
' ------------------------------------------------------------------------------
Position_PV:
if O3D_object_exists(1) = 1
PVx=Position(162)/10:PVy=Position(164)/10:PVz=Position(166)/10
caption 167,"("+str$(PVx)+")":caption 168,"("+str$(PVy)+")":caption 169,"("+str$(PVz)+")"
point_position PVx,PVy,PVz
end_if
return
' ------------------------------------------------------------------------------
Coloration:
R1%=val(text$(172)):G1%=val(text$(173)):B1%=val(text$(174))
color 171,R1%,G1%,B1%
return
' ------------------------------------------------------------------------------
Appli_Color:
if O3D_object_exists(1) = 1 then 3d_color 1,R1%,G1%,B1%
return
' ------------------------------------------------------------------------------
Appli_Texture:
texture$=""
dir_change DT$
a$=file_find_first$
if a$=nom$+".bmp"
texture$=a$
else
a$=file_find_next$
if a$=nom$+".bmp"
texture$=a$
else
while a$<>"_"
a$=file_find_next$
if a$=nom$+".bmp"
texture$=a$
exit_while
end_if
end_while
end_if
end_if
if texture$=""
open_dialog 1000
dir_dialog 1000,DT$
Texture$=file_name$(1000)
delete 1000
end_if
if Texture$<>"_"
if O3D_object_exists(1) = 1 then 3d_load_texture 1,Texture$
end_if
return
' ------------------------------------------------------------------------------
Lumiere:
if O3D_object_exists(1) = 1
Lx=Position(202):Ly=Position(204):Lz=Position(206)
caption 207,"("+str$(Lx)+")":caption 208,"("+str$(Ly)+")":caption 209,"("+str$(Lz)+")"
light_position Lx,Ly,Lz
end_if
return
' ------------------------------------------------------------------------------
Capture:
dll_on D$+"\KGF.dll"
to_foreground 0
res%=dll_call1("ScreenCopy",2)
pause 100
clipboard_paste 98
file_save 98,D$+"\Capture\"+nom$+".bmp"
wait 1000
return
' ------------------------------------------------------------------------------

' Place des #Include
#include "Include_Image.bas"
#include "Include_Texte.bas"
' ------------------------------------------------------------------------------
Quitter:
terminate

Pour la lumière scratch

j'ai du mal à voir la différence mais bon...
Faudrait peut-être une commande pour le nbre de watts ...non ? Laughing

Je verrai bien "Hallogene N" , bon, c'est bon, je sors ... Laughing

je vais faire un Sleep

comme çà je dirai moins de bêtises... Laughing

Sujet: Re: J'ai copié sur Bignono Mer 5 Sep 2012 - 7:16

Si tu cliques sur ton spin, tu peux entrer la valeur.
En mettant le test avec numeric (ou en testant si la chaine est vide), tu empêche d'avoir le message d'erreur et tu peux saisir la valeur que tu veux après, tu as juste à vérifier que la valeur est bien inférieure à 256
Il faut que l'on ajoute quelque chose aussi pour faire apparaitre le menu Capture (dans include_Texte, sans doute)

Sujet: re Mer 5 Sep 2012 - 9:20

@ Jicehel,

J' ai mis le webdav à jours, il y a deux p'tit truc en plus... Laughing

Essayes, avec des fichiers dans les dossiers "3D" et "texture" puis avec ces deux fichiers vides.
Le premier sur "Ouvrir", l'autre sur "charger une texture".

Si le dossier 3D est vide c'est un open_dialog qui peut s'ouvrir pour faire une recherche sur disque dur...
...et pour l'autre, si une texture nommé comme le "*.3DS" mais avec "*.bmp" est dans le dossier texture,
elle s'applique automatiquement.

J'avais mis le source sans réfléchir mais avec les includes, il n' y a pas
que lui qui change. Comme je le dis souvent, j'avais plus les yeux en face des trous... Laughing

Je verrai pour les spins en rentrant, là, je dois m'absenter une heure ou deux...
...mon frigo à faim.... Laughing

» Bonjour Bignono
» chasseur d’astéroïdes V4 sonorisé par Bignono
» copie multiple clip_board
» copie d'image ?
» Fonction copie de fichiers