Un déplacement FPS en 3D

' ======= Déclaration des label =======
' Positionnnement de la souris
label position_souris


' ======= Déclaration des variables   =======

' Comportement de la souris
dim souris_x_init
dim souris_x_comp
dim souris_y_init
dim souris_y_comp

' Repère sphérique et cartésiens pour le pointage caméra
dim sph_point_teta
dim sph_point_phi
dim sph_point_R

dim cart_point_x
dim cart_point_y
dim cart_point_z

' Repère cartesien pour la position de la caméra
dim cam_pos_x
dim cam_pos_y

' Sensibilité de la souris
dim sensi

' Vitesse de déplacement
dim vit_depl

' ======= Initialisation des variables  =======
sph_point_R = 0.5
sph_point_teta=0
sph_point_phi=0
sensi=-0.05
cam_pos_x = 0
cam_pos_y = 0
vit_depl = 0.1

' ======= Initialisation de l'affichage  =======


' Création de la fenetre
caption 0,"Test de caméra 3D"
full_space 0


' === Création de l'environnement 3D de déplacement de la caméra ===
' Légende des couleur
' x: Rouge
' y: vert
' z: Bleu

scene3d 1
full_space 1
axes_show
color 1,0,0,0
cursor_hide 1

3d_plane 2
3d_position 2,0,0,0
3d_load_texture 2,"terrain.bmp"
3d_x_rotate 2,90
3d_u_tile 2,5
3d_v_tile 2,5

3d_sphere 3,0.005
3d_color 3,255,0,0

' === FIN de la création de la map ===

' affichage de la fenetre de test commande
form 10
caption 10,"test"
height 10,90
width 10,60


' ======= PROGRAMME PRINCIPAL Création du timer de surveillance de la souris =======
timer 30
timer_interval 30,5
on_timer 30,position_souris

end

' ======= Ecriture des sous-programmes =======


' === Programme principal ===

position_souris:

' Surveillance du pointeur + position pointage
print_target_is 10
print_locate 0,0
print sph_point_teta

' Test sur le comportement du pointeur
' Comportement horizontal
  if souris_x_init <> mouse_x_position(1)
     sph_point_phi = sph_point_phi-(mouse_x_position(1)-souris_x_init)*sensi
  end_if

' Comportement vertical
 if souris_y_init <> mouse_y_position(1)
     sph_point_teta=sph_point_teta+(mouse_y_position(1)-souris_y_init)*sensi
     if sph_point_teta > 24.8
      sph_point_teta=24.8
     end_if
     if sph_point_teta < 14.85
      sph_point_teta=14.85
     end_if
 end_if

 ' Test sur le comportement des touches du clavier
 if scancode=90
     cam_pos_x = cam_pos_x + vit_depl*(cart_point_x-cam_pos_x)
     cam_pos_y = cam_pos_y + vit_depl*(cart_point_y-cam_pos_y)
 end_if

 if scancode=83
     cam_pos_x = cam_pos_x - vit_depl*(cart_point_x-cam_pos_x)
     cam_pos_y = cam_pos_y - vit_depl*(cart_point_y-cam_pos_y)
 end_if
 
 if scancode=27
  timer_off_all
  terminate
 end_if
 
 
 ' Calcul des coordonnées du pointeur 3D
 cart_point_x = cam_pos_x + sph_point_R*cos(sph_point_teta/3.141592654)*cos(sph_point_phi/3.141592654)
 cart_point_y = cam_pos_y + sph_point_R*cos(sph_point_teta/3.141592654)*sin(sph_point_phi/3.141592654)
 cart_point_z = 1+sph_point_R*sin(sph_point_teta/3.141592654)
 
 ' Calcul des coordonnées de la caméra
 
 ' Actualisation affichage
 3d_position 3,cart_point_x,cart_point_z,cart_point_y
 point_position cart_point_x,cart_point_z,cart_point_y
 cam_position cam_pos_x,1,cam_pos_y

light_x_position cam_pos_x
light_z_position cam_pos_y

souris_x_init=mouse_x_position(1)
souris_y_init=mouse_y_position(1)

return

EXECUTE_WAIT "osk.exe"

repeat
   print key_down_code ; "  " ; scancode : pause 1000
 until key_down_code = 27
' until scancode = 27
print key_down_code ; "  " ; scancode
message "terminé"