Nouveau chez panoramic

' début du programme principal.
' ceci est exécuté une seule fois, au lancement du programme*

' on va définir ici les labels des routines évènement
' (un seul dans notre cas)
label valider

' on crée un libellé avec ses charactéristiques
alpha 10 : ' ici, on crée l'objet ALPHA qui est un libellé
top 10,20 : ' on le place verticalement au pixel 20 de la fenêtre active
left 10,30 : ' on le place horisontalement au pixel 30 de la fenêtre active
caption 10,"Nom de famille:" : ' on installe le texte de la fenêtre

' on crée la zone de saisie
edit 23 : ' ici, on crée un objet EDIT
top 23,20 : ' on place cet objet à la même hauteur que le libellé
left 23,120 : ' et à droite du libellé

' on crée un bouton de validation
button 47 : ' ici, on crée un objet BUTTON
top 47,50 : ' on place ce bouton en-desous du EDIT
left 47,120 : ' au même alignement
caption 47,"Valider" : ' on donne un libellé au bouton
on_click 47,valider : ' et on indique la routine évènement

' fin du programme principal.
' le programme se met en attente d'un évènement
end

' évènement ON_CLICK du bouton
valider:
message "Le nom saisi est: "+text$(23)
return : ' on rend la main au système

rem ============================================================================

label evenement, fin
' Le LABEL définit un emplacement du programme pour y accéder soit par GOTO,
' soit par GOSUB, soit par un événement (ON_CLICK, ON_DOUBLE_CLICK, ON_KEY_UP etc...)
dim n% : ' déclaration d'une variable entière
edit 1
' Un EDIT sert à visualiser une zone où l'on peut entrer ou modifier une ligne de texte
top 1,50   : ' Position verticale de l'objet 1 qui est un EDIT
width 1,150 : ' Largeur de l'objet 1
text 1,"double-cliquez ici" : ' un texte affiché dans l'EDIT
' On associe l'évenement DOUBLE CLIC à l'emplacement du programme défini par le LABEL evenement
on_double_click 1, evenement

button 2 : ' On définit un bouton
top 2, 100 : left 2,200 : caption 2,"Quitter"
on_click 2,fin

alpha 3 : ' un ALPHA sert à visualiser (avec la commande CAPTION) un texte statique
top 3,50 : left 3,250


end : ' ce END est indispensable pour que le programme s'arrête,
' mais le programme reste actif pour traiter les événements
rem ============================================================================
evenement:   : ' Le sous-programme qui traite l'évenement du double clic
    n% = n% + 1
    caption 3,"Vous avez double-cliqué " + str$(n%) + " fois"
return
rem ============================================================================
fin:   : ' Le sous-programme qui traite le clic sur le bouton Quitter
  if message_confirmation_yes_no("Vous voulez vraiment quitter ?") = 1 then terminate
return
rem ============================================================================