Afficher correctement une image JPEG

label JPEG_Init
gosub JPEG_Init : ' Init des variables de traitement Jpg




dim img$

' Une image quelconque de dimension superieure à 105x105 pixels...
img$="D:\PERSO\RESETPLL.JPG"


PICTURE 1: FILE_LOAD 1,img$ : ' Que c'est pas beau !!!

JPEG_open%=2 : JPEG_open$=img$ : gosub JPEG_open : ' Là ça va mieux !

' on attend 3 secondes avant de refermer l'image..
WAIT 3000 : gosub JPEG_close


end





' *******************************************************************************************
' * PROCEDURES FORMAT JPEG
' *******************************************************************************************

' ----- Initialisation des differentes variables de traitement de Jpg
JPEG_Init:
  ' -- JPEG_dim
  dim JPEG_dim$,JPEG_dim%(6),JPEG_Height%,JPEG_Width%
  label JPEG_dim
  ' -- JPEG_open / close
  dim JPEG_open%,JPEG_open$
  label JPEG_open,JPEG_close
return

' ----- Affiche une image centrée par rapport à l'écran
' Utilise 2 objets : JPEG_open% et JPEG_open%+1
JPEG_open:
  ' init du formulaire qui va contenir l'objet picture
  FORM JPEG_open% : COMMAND_TARGET_IS JPEG_open%
  BORDER_HIDE JPEG_open%
  JPEG_dim$=JPEG_open$: gosub JPEG_dim : ' on récupère les dimensions de l'image
  ' puis on centre le formulaire :
  LEFT JPEG_open%,(SCREEN_X - JPEG_Width%)/2
  TOP JPEG_open%,(SCREEN_Y - JPEG_Height%)/2
  ' avec les bonnes dimensions
  WIDTH JPEG_open%,JPEG_Width%
  HEIGHT JPEG_open%,JPEG_Height%
  ' init du picture
  PICTURE JPEG_open%+1
  WIDTH JPEG_open%+1,JPEG_Width%
  HEIGHT JPEG_open%+1,JPEG_Height%
  FILE_LOAD JPEG_open%+1,JPEG_open$
  COMMAND_TARGET_IS 0
return

JPEG_close:
  DELETE JPEG_open%+1 : ' supprime l'objet picture
  DELETE JPEG_open%  : ' supprime le formulaire
return


' ----- Determination des dimensions d'une image JPG
JPEG_dim:
  FILEBIN_OPEN_READ JPEG_open%+2,JPEG_dim$
  FILEBIN_POSITION JPEG_open%+2,4
  FILEBIN_BLOCK_READ JPEG_open%+2,2,JPEG_dim%(0)
  JPEG_dim%(5)=(JPEG_dim%(0)*256)+JPEG_dim%(1)
  FILEBIN_BLOCK_READ JPEG_open%+2,5,JPEG_dim%(0)
  JPEG_dim$=chr$(JPEG_dim%(0))+chr$(JPEG_dim%(1))+chr$(JPEG_dim%(2))+chr$(JPEG_dim%(3))
  if JPEG_dim$<>"JFIF"
    JPEG_dim%(0)=message_warning_OK("JPEG_dim: Format de fichier incorrect !")
    FILEBIN_CLOSE JPEG_open%+2
    return
  end_if
  JPEG_dim%(2)=255:JPEG_dim%(3)=255: JPEG_dim%(4)=2
  WHILE (JPEG_dim%(2)<>255) or ((JPEG_dim%(3)<>192) and (JPEG_dim%(3)<>194))
    JPEG_dim%(4) = JPEG_dim%(4) + JPEG_dim%(5) + 2
    FILEBIN_POSITION JPEG_open%+2,JPEG_dim%(4)
    FILEBIN_BLOCK_READ JPEG_open%+2,2,JPEG_dim%(2)
    FILEBIN_BLOCK_READ JPEG_open%+2,2,JPEG_dim%(0) :JPEG_dim%(5)=(JPEG_dim%(0)*256)+JPEG_dim%(1)
  END_WHILE
  FILEBIN_READ JPEG_open%+2,JPEG_dim%(0)
  FILEBIN_BLOCK_READ JPEG_open%+2,2,JPEG_dim%(0): JPEG_Height%=(JPEG_dim%(0)*256)+JPEG_dim%(1)
  FILEBIN_BLOCK_READ JPEG_open%+2,2,JPEG_dim%(0): JPEG_Width%=(JPEG_dim%(0)*256)+JPEG_dim%(1)
  FILEBIN_CLOSE JPEG_open%+2
  JPEG_dim%(0)=0
RETURN