Cryptage/décryptage d'un fichier quelconque

' Cryptage/décryptage d'un fichier texte ou binaire
DIM mp$, i, j, v, vc, f$, fc$, fd$, f1$, f2$
LABEL Codbin

mp$ = "MotDePasse": ' Code de cryptage, plus c'est long, mieux c'est
f$ = "C:\Textes\Lorem.txt": ' fichier à crypter
fc$ = "Z:\Fcod"
fd$ = "Z:\Fdec.txt"

PRINT "Codage..."
f1$ = f$: f2$ = fc$: GOSUB Codbin
PRINT "Décodage..."
f1$ = fc$: f2$ = fd$: GOSUB Codbin
PRINT "Terminé !"
END

Codbin: ' cryptage/décryptage (symétrique)
FILEBIN_OPEN_READ 1, f1$: FILEBIN_OPEN_WRITE 2, f2$
j = 1
FOR i = 1 TO FILEBIN_SIZE(1)
    FILEBIN_READ 1, v
    vc = BIN_XOR(v,  ASC(MID$(mp$, j, 1)))
    FILEBIN_WRITE 2, vc
    j = j + 1: IF j > LEN(mp$) THEN j = 1
NEXT i
FILEBIN_CLOSE 1: FILEBIN_CLOSE 2
RETURN

' Cryptage/décryptage d'un fichier texte ou binaire
DIM mp$, i%, j%, v%, vc%, f$, fc$, fd$, f1$, f2$, len_mp%
DIM val_mp%(50)
LABEL Codbin

mp$ = "MotDePasse": ' Code de cryptage, plus c'est long, mieux c'est
len_mp% = len(mp$)
for i%=1 to len_mp%
    val_mp%(i%) = ASC(MID$(mp$,i%,1))
next i%

f$ = "C:\Textes\Lorem.txt": ' fichier à crypter
fc$ = "Z:\Fcod"
fd$ = "Z:\Fdec.txt"

PRINT "Codage..."
f1$ = f$: f2$ = fc$: GOSUB Codbin
PRINT "Décodage..."
f1$ = fc$: f2$ = fd$: GOSUB Codbin
PRINT "Terminé !"
END

Codbin: ' cryptage/décryptage (symétrique)
FILEBIN_OPEN_READ 1, f1$: FILEBIN_OPEN_WRITE 2, f2$
j% = 1
FOR i% = 1 TO FILEBIN_SIZE(1)
    FILEBIN_READ 1, v%
    vc% = BIN_XOR(v%,  val_mp%(j%))
    FILEBIN_WRITE 2, vc%
    j% = j% + 1: IF j% > len_mp% THEN j% = 1
NEXT i%
FILEBIN_CLOSE 1: FILEBIN_CLOSE 2
RETURN

j%=j%+1 : if j%>mp% then j%=1

j%=j%-int(j%/10)*10+1

dim ecranL,ecranT
dim a$,b$,doss$,cx
dim code$,visible%,affich$
DIM mp$, i%, j%, v%, vc%, f$, fc$, fd$, f1$, f2$, len_mp%
DIM val_mp%(50),act$
code$="#1971#"
affich$=""
label Nouv,Ouvrir,Ouvrir2,Enrgt,Quit,Crypt,Decrypt,Mail,Charg_list
label digicode,clk1,clk2,clk3,clk4,clk5,clk6,clk7,clk8,clk9,clk10,clk11,clk12
label Codbin,clef
caption 0,"Messages secrets"
height 0,550:width 0,760
ecranL=(screen_x-760)/2:ecranT=(screen_y-550)/2
top 0,ecranT:left 0,ecranL

main_menu 1
 sub_menu 2:caption 2,"Fichier"          :parent 2,1
 sub_menu 3:caption 3,"Nouveau"          :parent 3,2  :on_click 3,Nouv
 sub_menu 5:caption 5,"Enregistrer"      :parent 5,2  :on_click 5,Enrgt
 sub_menu 6:caption 6,"Quitter"          :parent 6,2  :on_click 6,Quit
 sub_menu 7:caption 7,"Edition"          :parent 7,1
 sub_menu 8:caption 8,"Cryptage"          :parent 8,7  :on_click 8,Crypt
 sub_menu 9:caption 9,"Décryptage"        :parent 9,7  :on_click 9,Decrypt
 sub_menu 10:caption 10,"Options"        :parent 10,1
 sub_menu 11:caption 11,"Envoyer par mail":parent 11,10 :on_click 11,Mail
 
alpha 12:caption 12,"Messages édités":font_name 12,"arial":top 12,15:left 12,15
list 13:top 13,35:left 13,15:width 13,170:height 13,200:color 13,254,250,131
font_color 13,0,0,255 :font_name 13,"Times new roman":font_size 13,10:on_click 13,Ouvrir

alpha 14:caption 14,"Messages reçus":font_name 14,"arial":top 14,250:left 14,15

list 15:top 15,270:left 15,15:width 15,170:height 15,200:color 15,254,250,131
font_color 15,255,0,0:font_name 15,"Times new roman":font_size 15,10:on_click 15,Ouvrir2

alpha 16:caption 16,"Corps du message":font_name 16,"arial":top 16,15:left 16,220

memo 17:top 17,35:left 17,220 :height 17,435:width 17,500
font_name 17,"Times new roman":font_size 17,10:font_color 17,91,1,72:color 17,254,250,131

gosub Charg_list
end

 Charg_list:
 doss$=dir_current$
 clear 13
 dir_change "Edit"
 item_add 13,file_find_first$
 a$=file_find_next$
 while a$<>"_"
 item_add 13,a$
 a$=file_find_next$
 end_while
 file_find_close
 dir_change doss$
 clear 15
 dir_change "Recep"
 item_add 15,file_find_first$
 b$=file_find_next$
 while b$<>"_"
 item_add 15,b$
 b$=file_find_next$
 end_while
 file_find_close
 dir_change doss$
 return
 
 Nouv:
 cx=message_confirmation_yes_no("Voulez vous enregistrer le texte édité ?")
 if cx=1
 gosub Enrgt
 else
 clear 17
 end_if
 return
 
 Ouvrir:
 if item_index$(13)<>"_"
 clear 17
 file_load 17,"Edit\"+item_index$(13)
 end_if
 return
 
 Ouvrir2:
 if item_index$(15)<>"_"
 clear 17
 file_load 17,"Recep\"+item_index$(15)
 end_if
 return
 
 Enrgt:
 cx=message_input("Nommer le fichier","Nom du fichier :","")
 if cx=1
 file_save 17,"Edit\"+message_text$+".txt"
 clear 17
 gosub charg_list
 end_if
 return
 
digicode:
visible%=1
form 20
height 20,210:width 20,140
top 20,260:left 20,450
command_target_is 20
button 21 :width 21,25  :top 21,45  :left 21,15  :caption 21,"1"  :cursor_point 21  :on_click 21,clk1
button 22 :width 22,25  :top 22,45  :left 22,45  :caption 22,"2"  :cursor_point 22  :on_click 22,clk2
button 23 :width 23,25  :top 23,45  :left 23,75  :caption 23,"3"  :cursor_point 23  :on_click 23,clk3
button 24 :width 24,25  :top 24,75  :left 24,15  :caption 24,"4"  :cursor_point 24  :on_click 24,clk4
button 25 :width 25,25  :top 25,75  :left 25,45  :caption 25,"5"  :cursor_point 25  :on_click 25,clk5
button 26 :width 26,25  :top 26,75  :left 26,75  :caption 26,"6"  :cursor_point 26  :on_click 26,clk6
button 27 :width 27,25  :top 27,105 :left 27,15  :caption 27,"7"  :cursor_point 27  :on_click 27,clk7
button 28 :width 28,25  :top 28,105 :left 28,45  :caption 28,"8"  :cursor_point 28  :on_click 28,clk8
button 29 :width 29,25  :top 29,105 :left 29,75  :caption 29,"9"  :cursor_point 29  :on_click 29,clk9
button 30:width 30,25  :top 30,135 :left 30,15  :caption 30,"0"  :cursor_point 30 :on_click 30,clk10
button 31:width 31,25  :top 31,135 :left 31,45  :caption 31,"#"  :cursor_point 31 :on_click 31,clk11
button 32:width 32,25  :top 32,135 :left 32,75  :caption 32,"Ok" :cursor_point 32 :on_click 32,clk12
edit 33  :width 33,85  :top 33,15  :left 33,15  :secret_on 33:font_name 33,"arial":font_bold 33:text 33,"******"
color 33,199,199,255
return

clk1:
affich$=affich$+"1"
text 33,affich$
return
clk2:
affich$=affich$+"2"
text 33,affich$
return
clk3:
affich$=affich$+"3"
text 33,affich$
return
clk4:
affich$=affich$+"4"
text 33,affich$
return
clk5:
affich$=affich$+"5"
text 33,affich$
return
clk6:
affich$=affich$+"6"
text 33,affich$
return
clk7:
affich$=affich$+"7"
text 33,affich$
return
clk8:
affich$=affich$+"8"
text 33,affich$
return
clk9:
affich$=affich$+"9"
text 33,affich$
return
clk10:
affich$=affich$+"0"
text 33,affich$
return
clk11:
affich$=affich$+"#"
text 33,affich$
return
clk12:
if affich$=code$
hide 20
command_target_is 0
gosub clef
else
cx=message_confirmation_yes_no("Voulez vous réessayer")
  if cx=1
  text 33,""
  affich$=""
  else
  hide 20
  gosub quit
  end_if
end_if
return

clef:
mp$ = affich$:' Code de cryptage, plus c'est long, mieux c'est
len_mp% = len(mp$)
for i%=1 to len_mp%
    val_mp%(i%) = ASC(MID$(mp$,i%,1))
next i%


if act$="code"

file_save 17,doss$+"\Base.txt"
f$ = doss$+"\Base.txt"
fc$ = doss$+"\Fcod"

f1$ = f$: f2$ = fc$: GOSUB Codbin

file_load 17,doss$+"\Fcod"
file_delete doss$+"\Base.txt"
file_delete doss$+"\Fcod"

else
file_save 17,doss$+"\Fcod"
fc$ = doss$+"\Fcod"
fd$ = doss$+"\Fdec.txt"

f1$ = fc$: f2$ = fd$: GOSUB Codbin

file_load 17,doss$+"\Fdec.txt"
file_delete doss$+"\Fcod"
file_delete doss$+"\Fdec.txt"

end_if
return

Codbin:
FILEBIN_OPEN_READ 1, f1$: FILEBIN_OPEN_WRITE 2, f2$
j% = 1
FOR i% = 1 TO FILEBIN_SIZE(1)
    FILEBIN_READ 1, v%
    vc% = BIN_XOR(v%,  val_mp%(j%))
    FILEBIN_WRITE 2, vc%
    j% = j% + 1: IF j% > len_mp% THEN j% = 1
NEXT i%
FILEBIN_CLOSE 1: FILEBIN_CLOSE 2
return

 Crypt:
 act$="code"
 if visible%=1
 show 20
 affich$=""
 else
 gosub digicode
 end_if
 return
 
 Decrypt:
 act$="decode"
 if visible%=1
 show 20
 affich$=""
 else
 gosub digicode
 end_if
 return
 
 Mail:
 cx=message_input("Envoyer par mail","Destinataire :","")
 if cx=1
 execute "mailto:"+message_text$+"?subject=Message&body="+text$(17)
 end_if
 return
 
 Quit:
 terminate