Fractales "Hopalong"

' Hopalong-Martin Process Like Fractal by "ganache"
' https://www.freebasic.net/forum/viewtopic.php?t=25349#p228080
' Adaptation pour FBCroco par J. Debord

const SW    = 1024     ' Taille de la fenetre
const SH    = 768

const DOTS  = 1000000  ' Nb de points
const SCALE = 25       ' Echelle
const DENS  = 0.9999   ' Densite des points

const MIDX  = SW \ 2
const MIDY  = SH \ 2
const DMAX  = sqr(MIDX * MIDX + MIDY * MIDY)

mode 3, "Hopalong Fractal - Pressez ESC pour quitter", SW, SH

origin MIDX, MIDY

randomize timer

dim i%, RR%, GG%, BB%, a, b, c, d, x, x2, y, z, j, xp, yp, ans$

repeat
    Cls

    'set up some random starting positions
    a = rnd(1)
    c = 2 - 2 * a
    x = 0
    j = 0
    y = rnd(1) * 12 + 0.1

    'calculate and draw the points
    for i = 0 to DOTS
        z = x
        x = DENS * y + j
        x2 = x * x
        j = a * x + c * x2 / (1 + x2)
        y = j - z
        xp = x * SCALE
        yp = y * SCALE
        d = sqr(xp * xp + yp * yp)
        HSVtoRGB 360 * d / DMAX, 1, 1, RR, GG, BB
        pen RGB(RR, GG, BB)
        plot xp,yp
    next i
    sleep 10
    ans = Inkey
until ans = "ESCAPE"