Erreur...avec le compilateur.

' NOM DE L APPLICATION :
' AUTEUR DE L APPLICATION :
' DATE DE CREATION
' ==============================================================================
' VARIABLES
' ==============================================================================
dim no%
' gestion des datas
dim dat$,fr$,PNum%(28,2),idgain$,TGain%(23,3)
' gestion des boutons de choix de numéro
dim EtatButCx%(28),z%,cx%,MaSelection%(7)
' gestion des messages
dim mess%,t$
' gestion des gains
dim mise%,wallet%,bet%,
' gestion des tirages
dim NbrTirs%,Partie%(12),PartBleu%(7),PartJaune%(5),cell%(28,2)
' ==============================================================================
' CONSTANTES
' ==============================================================================
' Fichiers
dim ButtImg1$(28)
dim ButtImg2$(28)
dim TmpWallet$
dim MemoTirages$
' Objets
dim F_or%
dim F_ow%
dim Frame%(3)
dim Pub1%
dim ButtCx%(28)
dim Alph%(10)
dim ContMise%
dim OptMise%(5)
dim ContTirs%
dim OptTirs%(4)
dim ButtValid%
dim Scene1%
dim TableGains%
dim BaseTir%
dim FenMess%
' ==============================================================================
' LABELS
' ==============================================================================
label CLIC
label FIN
' ==============================================================================
' DATAS
' ==============================================================================
idgain$= "0400002,1300002,2200002,3100002,4000005,"
idgain$= idgain$+"0500003,1400003,2300003,3200003,4100008,5000040,"
idgain$= idgain$+"1500015,2400015,3300015,4200020,5100055,6000500,"
idgain$= idgain$+"2500100,3400100,4300105,5200140,6100600,7025000,"
' ------------------------------------------------------------------------------
dat$= "040035,120035,200035,280035,360035,440035,5200035,"
dat$= dat$+"040115,120115,195115,275115,355115,435115,515115,"
dat$= dat$+"035195,115195,195195,275195,355195,435195,515195,"
dat$= dat$+"035275,115275,195275,275275,355275,435275,515275,"
' ==============================================================================
' PROGRAMME
' ==============================================================================
InitAdrFichiers()
InitNoObjets()
InitDatas()
InitWallet()
Gui()
end
' ==============================================================================
' SOUS PROGRAMMES
' ==============================================================================
CLIC:
   for z%=1 to 28
      if number_click =ButtCx%(z%)
         if EtatButCx%(z%)=0
            if cx%<7
               EtatButCx%(z%)=1
               file_load ButtCx%(z%),dir_current$+"\img\SelectionRed"+str$(z%)+".bmp"
               cx%=cx%+1
               AddToMaSelection(z%)
            else
               mess%= message_warning_ok("Sélection complète !")
            end_if
         else
            EtatButCx%(z%)=0
            file_load ButtCx%(z%),dir_current$+"\img\SelectionBlue"+str$(z%)+".bmp"
            cx%=cx%-1
            DeleteToMaSelection(z%)
         end_if
         exit_for
      end_if
   next z%
  
   if number_click = OptMise%(1)
      Mise%=2
      MajTableGains(TableGains%,1)      
   end_if
   if number_click = OptMise%(2)
      Mise%=4
      MajTableGains(TableGains%,2)    
   end_if
   if number_click = OptMise%(3)
      Mise%=6
      MajTableGains(TableGains%,3)    
   end_if
   if number_click = OptMise%(4)
      Mise%=8
      MajTableGains(TableGains%,4)    
   end_if
   if number_click = OptMise%(5)
      Mise%=10
      MajTableGains(TableGains%,5)    
   end_if
  
   for z%=1 to 4
      if number_click = OptTirs%(z%)
         NbrTirs% = z%
         exit_for
      end_if
   next z%
  
   if number_click = ButtValid%
      inactive Frame%(1)
      bet% = NbrTirs%*mise%
      if wallet%>bet%
         wallet%=wallet%-bet%
         z%=0
         repeat
            z%=z%+1
            RazPlateau()
            CreationPlateau(Scene1%)
            Tirage()
         until z%=NbrTirs%                
      else
         if wallet%=0
            t$= "Votre porte monnaie est vide !"
            t$= t$+chr$(13)+"Pour le recharger, vous devez redémarrer l' application."
            mess%=message_information_ok(t$)
            file_delete TmpWallet$
            Terminate
         else
            t$= "Vous avez parié "+str$(bet%)+" €"
            t$= t$+chr$(13)+"Mais il ne vous reste que "+str$(wallet%)+" €."
            t$= t$+chr$(13)+"Diminuez votre mise."
            mess%=message_information_ok(t$)            
         end_if
      end_if
      active Frame%(1)
   end_if
Return
' ------------------------------------------------------------------------------
FIN:
   file_delete TmpWallet$
   file_open_write F_ow%,TmpWallet$
   file_writeln F_ow%,str$(wallet%)
   file_close F_ow%
   Terminate
Return
' ==============================================================================
' PROCEDURES
' ==============================================================================
Sub InitAdrFichiers()
   dim_local i%
  
   for i%=1 to 28
      ButtImg1$(i%)=dir_current$+"\img\SelectionBlue"+str$(i%)+".bmp"
      ButtImg2$(i%)=dir_current$+"\img\SelectionRed"+str$(i%)+".bmp"
   next i%
   TmpWallet$ = "C:\Temp\SoftAmigoWallet.txt"
   MemoTirages$ = "C:\Temp\SoftAmigoTirages.txt"
End_sub
' ------------------------------------------------------------------------------
Sub InitNoObjets()
   dim_local i%
  
   for i%=1 to 3  : no%=no%+1 : Frame%(i%)=no%  : next i%
   no%=no%+1 : Pub1%=no%
   for i%=1 to 28 : no%=no%+1 : ButtCx%(i%)=no% : next i%
   for i%=1 to 10 : no%=no%+1 : Alph%(i%)=no%   : next i%
   no%=no%+1 : ContMise%=no%
   for i%=1 to 5  : no%=no%+1 : OptMise%(i%)=no%: next i%
   no%=no%+1 : ContTirs%=no%
   for i%=1 to 4  : no%=no%+1 : OptTirs%(i%)=no%: next i%
   no%=no%+1 : Scene1%=no%
   no%=no%+1 : TableGains%=no%
   no%=no%+1 : ButtValid%=no%
   no%=no%+1 : F_or%=no%
   no%=no%+1 : F_ow%=no%
   no%=no%+1 : BaseTir%=no%
   no%=no%+1 : FenMess%=no%
End_sub
' ------------------------------------------------------------------------------
Sub InitDatas()
   dim_local i%,n$,x%,y%
  
   for i%=1 to 28
      n$=left$(dat$,instr(dat$,",")-1)
      dat$=right$(dat$,len(dat$)-instr(dat$,","))
      x%=val(left$(n$,3))
      y%=val(right$(n$,3))
      PNum%(i%,1)=x%
      PNum%(i%,2)=y%
   next i%
  
   for i%=1 to 23
      n$= left$(idgain$,instr(idgain$,",")-1)
      TGain%(i%,1)= val(mid$(n$,1,1))
      TGain%(i%,2)= val(mid$(n$,2,1))
      TGain%(i%,3)= val(mid$(n$,3,5))
      idgain$= right$(idgain$,len(idgain$)-instr(idgain$,","))
   next i%
end_sub
' ------------------------------------------------------------------------------
Sub InitWallet()
   dim_local l$
  
   if file_exists(TmpWallet$)=1
      file_open_read F_or%,TmpWallet$
      l$=file_readln$(F_or%)
      wallet%=val(l$)
      file_close F_or%
   else
      file_open_write F_ow%,TmpWallet$
      file_writeln F_ow%,"100"
      wallet%=100
      file_close F_ow%
   end_if
End_sub
' ------------------------------------------------------------------------------
Sub Gui()
   dim_local i%,j%,n%,y%,x%
  
   height 0,600 : width 0,1000
   top 0,(screen_y-height(0))/2 : left 0,(screen_x-width(0))/2
   border_small 0
   caption 0,"SOFT  AMIGO"
   font_name 0,"Arial" : font_size 0,10 : font_bold 0 : font_color 0,0,0,0
   on_close 0,FIN
      
   panel Frame%(1)
   height Frame%(1),height_client(0)-20 : width Frame%(1),300
   top Frame%(1),10 : left Frame%(1),10
   color Frame%(1),255,0,0
  
   picture pub1%
   parent pub1%,Frame%(1)
   height pub1%,93 : width pub1%,243
   top pub1%,5 : left pub1%,(width_client(Frame%(1))-width(pub1%))/2
   file_load pub1%,"C:\Users\Yannick\Desktop\SrcCompiloCompatibles\SoftAmigo\img\Sans titre.bmp"
      y%=110 : x%=-25
      for i%=1 to 4
         y%=y%+40
         for j%=1 to 7
            x%=x%+40
            n%=n%+1
            button_picture ButtCx%(n%)
            parent ButtCx%(n%),Frame%(1)
            height ButtCx%(n%),30 : width ButtCx%(n%),30
            top ButtCx%(n%),y% : left ButtCx%(n%),x%
            file_load ButtCx%(n%),ButtImg1$(n%)
            cursor_point ButtCx%(n%)
            EtatButCx%(n%)=0
            on_click ButtCx%(n%),CLIC
         next j%
         x%=-25
      next i%

      alpha Alph%(1)
      parent Alph%(1),Frame%(1)
      caption Alph%(1),"Mise / tirage" : font_name Alph%(1),"Arial" : font_size Alph%(1),12 : font_bold Alph%(1)
      font_color Alph%(1),255,255,255
      top Alph%(1),top(ButtCx%(28))+50 : left Alph%(1),(width_client(Frame%(1))-width(Alph%(1)))/2
      
      container_option ContMise%
      parent ContMise%,Frame%(1)
      height ContMise%,50 : width ContMise%,width_client(Frame%(1))-10
      top ContMise%,top(Alph%(1))+height(Alph%(1))+5 : left ContMise%,5

      option OptMise%(1) : parent OptMise%(1),ContMise%
      font_name OptMise%(1),"Arial" : font_size OptMise%(1),10 : font_bold OptMise%(1) : font_color OptMise%(1),255,255,255
      top OptMise%(1),20 : left OptMise%(1),10 : caption OptMise%(1),"2 €"
      cursor_point OptMise%(1) : on_click OptMise%(1),CLIC
      mark_on OptMise%(1)
      
      option OptMise%(2) : parent OptMise%(2),ContMise%
      font_name OptMise%(2),"Arial" : font_size OptMise%(2),10 : font_bold OptMise%(2) : font_color OptMise%(2),255,255,255
      top OptMise%(2),20 : left OptMise%(2),left(OptMise%(1))+50 : caption OptMise%(2),"4 €"
      cursor_point OptMise%(2) : on_click OptMise%(2),CLIC
      
      option OptMise%(3) : parent OptMise%(3),ContMise%
      font_name OptMise%(3),"Arial" : font_size OptMise%(3),10 : font_bold OptMise%(3) : font_color OptMise%(3),255,255,255
      top OptMise%(3),20 : left OptMise%(3),left(OptMise%(2))+50 : caption OptMise%(3),"6 €"
      cursor_point OptMise%(3) : on_click OptMise%(3),CLIC
      
      option OptMise%(4) : parent OptMise%(4),ContMise%
      font_name OptMise%(4),"Arial" : font_size OptMise%(4),10 : font_bold OptMise%(4) : font_color OptMise%(4),255,255,255
      top OptMise%(4),20 : left OptMise%(4),left(OptMise%(3))+50 : caption OptMise%(4),"8 €"
      cursor_point OptMise%(4) : on_click OptMise%(4),CLIC
      
      option OptMise%(5) : parent OptMise%(5),ContMise%
      width OptMise%(5),50
      font_name OptMise%(5),"Arial" : font_size OptMise%(5),10 : font_bold OptMise%(5) : font_color OptMise%(5),255,255,255
      top OptMise%(5),20 : left OptMise%(5),left(OptMise%(4))+50 : caption OptMise%(5),"10 €"
      cursor_point OptMise%(5) : on_click OptMise%(5),CLIC

      alpha Alph%(2)
      parent Alph%(2),Frame%(1)
      caption Alph%(2),"Nombre de tirages :" : font_name Alph%(2),"Arial" : font_size Alph%(2),12 : font_bold Alph%(2)
      font_color Alph%(2),255,255,255
      top Alph%(2),top(ContMise%)+70 : left Alph%(2),(width_client(Frame%(1))-width(Alph%(2)))/2

      container_option ContTirs%
      parent ContTirs%,Frame%(1)
      height ContTirs%,50 : width ContTirs%,width_client(Frame%(1))-10
      top ContTirs%,top(Alph%(2))+height(Alph%(2))+5 : left ContTirs%,5

      option OptTirs%(1) : parent OptTirs%(1),ContTirs%
      font_name OptTirs%(1),"Arial" : font_size OptTirs%(1),10 : font_bold OptTirs%(1) : font_color OptTirs%(1),255,255,255
      top OptTirs%(1),20 : left OptTirs%(1),50 : caption OptTirs%(1),"1"
      cursor_point OptTirs%(1) : on_click OptTirs%(1),CLIC
      mark_on OptTirs%(1)
      
      option OptTirs%(2) : parent OptTirs%(2),ContTirs%
      font_name OptTirs%(2),"Arial" : font_size OptTirs%(2),10 : font_bold OptTirs%(2) : font_color OptTirs%(2),255,255,255
      top OptTirs%(2),20 : left OptTirs%(2),left(OptTirs%(1))+50 : caption OptTirs%(2),"2"
      cursor_point OptTirs%(2) : on_click OptTirs%(2),CLIC
      
      option OptTirs%(3) : parent OptTirs%(3),ContTirs%
      font_name OptTirs%(3),"Arial" : font_size OptTirs%(3),10 : font_bold OptTirs%(3) : font_color OptTirs%(3),255,255,255
      top OptTirs%(3),20 : left OptTirs%(3),left(OptTirs%(2))+50 : caption OptTirs%(3),"3"
      cursor_point OptTirs%(3) : on_click OptTirs%(3),CLIC
      
      option OptTirs%(4) : parent OptTirs%(4),ContTirs%
      width OptTirs%(4),50
      font_name OptTirs%(4),"Arial" : font_size OptTirs%(4),10 : font_bold OptTirs%(4) : font_color OptTirs%(4),255,255,255
      top OptTirs%(4),20 : left OptTirs%(4),left(OptTirs%(3))+50 : caption OptTirs%(4),"4"
      cursor_point OptTirs%(4) : on_click OptTirs%(4),CLIC
      
      button ButtValid%
      parent ButtValid%,Frame%(1)
      caption ButtValid%,"Valider"
      top ButtValid%,height_client(Frame%(1))-(height(ButtValid%)+5) : left ButtValid%,(width_client(Frame%(1))-width(ButtValid%))/2
      cursor_point ButtValid%
      on_click ButtValid%,CLIC
      
   panel Frame%(2)
   height Frame%(2),height_client(0)-65 : width Frame%(2),width_client(0)-330
   top Frame%(2),10 : left Frame%(2),left(Frame%(1))+310
   color Frame%(2),255,0,0
  
      picture Scene1%
      parent Scene1%,Frame%(2)
      height Scene1%,330 : width Scene1%,570
      top Scene1%,10 : left Scene1%,(width_client(Frame%(2))-width(Scene1%))/2
      font_name Scene1%,"Arial" : font_size Scene1%,14 : font_bold Scene1%
      CreationPlateau(Scene1%)

      alpha Alph%(3)
      parent Alph%(3),Frame%(2)
      caption Alph%(3),"Table des gains :" : font_name Alph%(3),"Arial" : font_size Alph%(3),10 : font_bold Alph%(3)
      font_color Alph%(3),255,255,255
      top Alph%(3),top(Scene1%)+height(Scene1%)+10 : left Alph%(3),left(Scene1%)
      
      grid TableGains%
      parent TableGains%,Frame%(2)
      height TableGains%,120  : width TableGains%,160
      top TableGains%,top(Alph%(3))+20 : left TableGains%,left(Scene1%)
      color TableGains%,255,255,140
      font_name TableGains%,"Courier" : font_color TableGains%,0,0,255 : font_size TableGains%,8 : font_bold TableGains%
      grid_column_fixed TableGains%,0
      grid_row_fixed TableGains%,1
      grid_one_row_height TableGains%,1,24
      grid_fixed_color TableGains%,255,255,0
      grid_column TableGains%,3
      grid_row TableGains%,24
      grid_row_height TableGains%,18
      grid_one_column_width TableGains%,1,30
      grid_one_column_width TableGains%,2,30
      grid_one_column_width TableGains%,3,75
      MajTableGains(TableGains%,1)
      
   panel Frame%(3)
   height Frame%(3),40 : width Frame%(3),width_client(0)-330
   top Frame%(3),top(Frame%(2))+height(Frame%(2))+5 : left Frame%(3),left(Frame%(1))+310
   color Frame%(3),255,0,0
  
   dlist BaseTir%    
End_sub
' ------------------------------------------------------------------------------
Sub CreationPlateau(obj%)
   dim_local x%,y%,x2%,y2%,i%,j%,n%
  
   2d_target_is obj%
   2d_pen_color 0,0,0
      
   n%=0 : x%=-70 : y%=-70
   for i%=1 to 4
      y%=y%+80
      for j%=1 to 7
         n%=n%+1
         x%=x%+80
         cell%(n%,1)=x%
         cell%(n%,2)=y%
         x2%=x%+70
         y2%=y%+70
         2d_rectangle x%,y%,x2%,y2%      
      next j%
      x%=-70  
   next i%
  
   for i%=1 to 28
      font_color obj%,0,0,0
      print_target_is obj%
      print_locate PNum%(i%,1),PNum%(i%,2)
      print str$(i%)  
   next i%
End_sub
' ------------------------------------------------------------------------------
Sub RazPlateau()
   dim_local i%,j%
  
   2d_target_is Scene1%
   2d_clear
   if object_exists(FenMess%)=1 : delete FenMess% : end_if
End_sub
' ------------------------------------------------------------------------------
Sub AddToMaSelection(c%)
   dim_local i%,x%
  
   for i%=1 to 7
      x%=MaSelection%(i%)
      if x%=0 : MaSelection%(i%)=c% : end_if
   next i%
End_sub
' ------------------------------------------------------------------------------
Sub DeleteToMaSelection(c%)
   dim_local i%,x%
  
   for i%=1 to 7
      x%=MaSelection%(i%)
      if x%=c% : MaSelection%(i%)=0 : end_if
   next i%  
End_sub
' ------------------------------------------------------------------------------
Sub MajTableGains(obj%,multi%)
   dim_local i%,b$,j$,g$
  
   if object_exists(obj%)=0 then exit_sub
   grid_write obj%,1,1,chr$(32)+"B"
   grid_write obj%,1,2,chr$(32)+"J"
   grid_write obj%,1,3,string$(2,chr$(32))+"GAINS"
   for i%=1 to 23
      b$=str$(TGain%(i%,1)) : grid_write obj%,25-i%,1,chr$(32)+b$
      j$=str$(TGain%(i%,2)) : grid_write obj%,25-i%,2,chr$(32)+j$
      g$=str$(TGain%(i%,3)*multi%) : grid_write obj%,25-i%,3,string$(7-len(g$),chr$(32))+g$
   next i%
End_sub
' ------------------------------------------------------------------------------
Sub Tirage()
   dim_local i%,j%,n%,eq%,tir$
  
   for i%=1 to 12 : Partie%(i%)=0    : next i%
   for i%=1 to 7  : PartBleu%(i%)=0  : next i%
   for i%=1 to 5  : PartJaune%(i%)=0 : next i%
  
   FenMessage("Tirage des 7 numéros bleus")
   pause 3000
   hide FenMess%
  
   i%=0
   for j%=1 to 12 : Partie%(j%)=0 : next j%
  
   while i%<>12
      n%=rnd(27)+1
      for j%=1 to 12
         if Partie%(j%)=n% : eq%=1 : end_if
      next j%
      if eq%<>1
         i%=i%+1
         Partie%(i%)=n%
         if i%<8
            ColorCaseTirage(n%,Scene1%)
            PartBleu%(i%)=n%
         else
            if i%=8
               FenMessage("Tirage des 5 numéros Bonus")
               pause 3000
               hide FenMess%
            end_if
            ColorCaseBonus(n%,Scene1%)
            PartJaune%(i%-7)=n%
         end_if
      else
         eq%=0
      end_if
   end_while
   for i%=1 to 12 : tir$=tir$+str$(Partie%(i%))+" " : next i%
   item_add BaseTir%,tir$
   file_save BaseTir%,MemoTirages$
End_sub
' ------------------------------------------------------------------------------
Sub ColorCaseTirage(c%,obj%)
   dim_local i%,j%,r%,g%,b%,c$
  
   2d_target_is obj%
   font_color obj%,250,250,250
   print_target_is obj%
   print_locate Pnum%(c%,1),Pnum%(c%,2)
   print str$(c%)  
   2d_pen_color 0,0,255
   for i%=cell%(c%,1)+2 to cell%(c%,1)+66
      for j%=cell%(c%,2)+2 to cell%(c%,2)+66
         r%=color_pixel_red(obj%,i%,j%)
         g%=color_pixel_green(obj%,i%,j%)
         b%=color_pixel_blue(obj%,i%,j%)
         c$=str$(r%)+str$(g%)+str$(b%)
         if c$="255255255"
            2d_point i%,j%
         end_if
      next j%
   next i%  
End_sub
' ------------------------------------------------------------------------------
Sub ColorCaseBonus(c%,obj%)
   dim_local i%,j%,r%,g%,b%,c$
  
   2d_target_is obj%      
   font_color obj%,255,0,0
   print_target_is obj%
   print_locate Pnum%(c%,1),Pnum%(c%,2)
   print str$(c%)
   2d_pen_color 255,255,0        
   for i%=cell%(c%,1)+2 to cell%(c%,1)+66
      for j%=cell%(c%,2)+2 to cell%(c%,2)+66
         r%=color_pixel_red(obj%,i%,j%)
         g%=color_pixel_green(obj%,i%,j%)
         b%=color_pixel_blue(obj%,i%,j%)
         c$=str$(r%)+str$(g%)+str$(b%)
         if c$="255255255"
            2d_point i%,j%
         end_if
      next j%
   next i%
End_sub
' ------------------------------------------------------------------------------
Sub FenMessage(t$)
   if object_exists(FenMess%)=0
      form FenMess%
      border_hide FenMess%
      height FenMess%,100 : width FenMess%,300
      top FenMess%,(screen_y-height(FenMess%))/2 : left FenMess%,(screen_x-width(FenMess%))/2
      color FenMess%,0,0,255
      
      alpha Alph%(10)
      parent Alph%(10),FenMess%
      font_name Alph%(10),"Times new roman" : font_size Alph%(10),14 : font_color Alph%(10),255,255,0
      caption Alph%(10),t$
      top Alph%(10),30 : left Alph%(10),(width_client(FenMess%)-width(Alph%(10)))/2      
   else
      show FenMess%
      color FenMess%,255,255,0
      font_name Alph%(10),"Times new roman" : font_size Alph%(10),14 : font_color Alph%(10),255,0,0
      caption Alph%(10),t$
      top Alph%(10),30 : left Alph%(10),(width_client(FenMess%)-width(Alph%(10)))/2
   end_if  
end_sub

         repeat
            z%=z%+1
            RazPlateau()
            CreationPlateau(Scene1%)
            Tirage()
         until z%=NbrTirs%