Animation 3D 2 faces avec le logo de Panoramic

' ------------------------------------------------------------------------------
'  PANORAMIC Animation 2 faces Logo Panoramic
'  Marc - May 2018 - Panoramic v0.9.28.i18
'  http://panoramic-language.pagesperso-orange.fr/French/index.html
'  http://panoramic.top-forum.net
' ------------------------------------------------------------------------------
' main
    Init()
    Skin()
    Sides()
    Instructions()
    Animation()
END
' ------------------------------------------------------------------------------
SUB Init()
    LABEL ColorChange,Quit
    DIM on,c,x
    c=1
    HEIGHT 0,540 + HEIGHT(0)-HEIGHT_CLIENT(0)
    WIDTH 0,500 + WIDTH(0)-WIDTH_CLIENT(0)
    LEFT 0,(SCREEN_X-WIDTH(0))/2
    TOP 0,(SCREEN_Y-HEIGHT(0))/2
    PICTURE 1
    WIDTH 1,200
    HEIGHT 1,200
    ON_CLOSE 0, Quit
END_SUB
' ------------------------------------------------------------------------------
SUB Sides()
    DIM_LOCAL i%
    SCENE3D 100
    HEIGHT 100,500
    WIDTH 100,500
    COLOR 100,250,250,250
    CAM_MOVE -15
    FOR i% = 1 TO 2
        3D_PLANE i%
        3D_V_TILE i%,1
        3D_U_TILE i%,1
        3D_IMAGE_TEXTURE i%,10
    NEXT i%
    3D_Y_ROTATE 1,180
    3D_X_ROTATE 2,0
END_SUB
' ------------------------------------------------------------------------------
SUB Skin()
    2D_TARGET_IS 1
    COLOR 1,250,250,250
    PRINT_TARGET_IS 1
    FONT_NAME 1,"Times New Roman"
    FONT_SIZE 1,95
    FONT_COLOR 1,0,0,200
    2D_FILL_COLOR 250,250,250
    FONT_BOLD 1
    PRINT_LOCATE 65,28
    PRINT "P"
    2D_FILL_OFF
    2D_PEN_COLOR 250,0,0
    2D_PEN_WIDTH 8
    2D_CIRCLE 100,100,85
    2D_CIRCLE 100,100,70
    IMAGE 10
    2D_IMAGE_COPY 10,0,0,200,200
END_SUB
' ------------------------------------------------------------------------------
SUB Instructions()
    PICTURE 50
    HEIGHT 50,40
    WIDTH 50,500
    TOP 50,500
    COLOR 50,255,255,255
    2D_TARGET_IS 50
    2D_FILL_COLOR 255,255,255
    PRINT_TARGET_IS 50
    FONT_NAME 50,"Times New Roman"
    FONT_SIZE 50,18
    FONT_ITALIC 50
    PRINT_LOCATE 55,8
    PRINT "Click on the picture / Cliquez sur l'image"
END_SUB                       
' ------------------------------------------------------------------------------
SUB Animation()
    on=1
    ON_CLICK 100,ColorChange
    WHILE on=1
        3D_Y_ROTATE 1,x+180
        3D_Y_ROTATE 2,x
        x=x+1
        IF x > 360 THEN x = 0
        PAUSE 20
    END_WHILE
END_SUB
' ------------------------------------------------------------------------------
ColorChange:
    IF c=0
        COLOR 100,250,250,250
        c=1
    ELSE
        COLOR 100,0,0,0
        c=0
    END_IF       
RETURN
' ------------------------------------------------------------------------------
Quit:
    on=0
    TERMINATE
RETURN