Couleur Progress_bar

Bonjour,

qu'ils sont soyeux ces nouveaux membres ... affraid

un souhait serait d'avoir la possibilité de coloriser un objet Progress_bar.
je ne suis vraiment pas pressé mais j'ai remarqué que cela n'était pas possible, si un jour cela est envisageable je pense que ça pourrait être intéressant pour un design plus sympathique à l'utilisation de se contrôle.
voici un code exemple qui ne fonctionne pas:

Code:: dim i%
progress_bar 1
width 1, 500
max 1,200
color 1 ,100,150,250' ici la couleur.
for i% = 10 to 50 step 10
position 1,i%
pause 500
next i%

Merci de regarder et à bientôt. cheers

Bonsoir

J'ai fait ici une sub qui permet de le faire sunny

Super,
un grand merci et jolie démonstration ce code.
je pourrais maintenant personnaliser cette couleur sur mon petit jeu.
cheers

En tout cas Bravo le code fonctionne et répond à 100 % pour ma question de départ.
A+

Je n'ai pas ce pb ni sous windows XP, ni sous windows 10. scratch

Tiens, télécharge KGF.dll et fais marcher ceci:

Code:: dim res%, i%
progress_bar 1 : min 1,0 : max 1,255
progress_bar 2 : position 2,50 : top 2,40
dll_on "KGF.dll"
for i%=0 to 255
position 1,i%
res% = dll_call2("SetProgressBarColor",handle(1),i%)
pause 10
next i%
end

Tu verras 2 ProgressBars. La première défile de gauche à droite en virant du noir au rouge. La seconde est fixe en couleur bleue (défaut).

La fonction a la syntaxe suivante:
res% = dll_call2("SetProgressBarColor",handle(N%),couleur%)
N% est le numéro de la ProgressBar, et couleur%=hex("BBGGRR").

J'ai fait mieux: j'ai ajouté un paramètre pour gérer également la couleur de fond de la ProgressBar ! Rechargez la DLL, et essayez ceci:

Code:: dim res%
progress_bar 1 : min 1,0 : max 1,255
progress_bar 2 : position 2,50 : top 2,40
dll_on "KGF.dll"
position 1,100
res% = dll_call3("SetProgressBarColor",handle(1),hex("00FFFF"),hex("0000FF"))
end

La première ScrollBar aura une barre rouge sur fond jaune. Voici le résultat:
Couleur Progress_bar Aa181

Bonjour et merci à vous deux,
@Silverman,
oui tu as raison je vais modifié mon sujet plus haut, je n'ai pas de souci non plus (vérifier après plusieurs test)
je ne sais pas ce qui sait passer, je pense que ma couleur par défaut n'était pas ok au départ et en testant ton code elle s'est mis correctement , de ce fait j'ai cru que cela venait du code mais il n'en est rien, il fonctionne parfaitement je m'en excuse.
@Klauss,
Merci jolie réalisation c'est cool de pouvoir mettre deux couleurs différentes dans une même progress_bar.
je suis ravi de voir que le sujet à fait avancer la chose, pour le bonheur de tous.
vous êtes des champions.
Bonne journée et à bientôt.

J'ai ajouté un petit truc dans KGF.dll pour avoir des ProgressBar pesonnalisées. KGF.dll a été mise àjour sur mon WebDav dossier DLLs et sur les deux sites internet.

En-dehors du choix de la couleur pour une ProgressBar Panoramic, on peut maintenant créer des ProgressBars de plusieurs aspects, toujours avec affichage du texte donnant le pourcentage, et avec le choix des deux couleurs:
- texte seul
- barre horizontale
- barre verticale
- camembert
- aiguille dan cadran

Voici le programme de démo:

Code:: label creer, supprimer, animer, tick
dim res%, PB%, w%, h%, typ%, pos%
progress_bar 1 : min 1,0 : max 1,255 : top 1,100 : position 1,100
progress_bar 2 : position 2,50 : top 2,140

timer 8 : on_timer 8,tick : timer_off 8 : timer_interval 8,10
combo 9 : top 9,180 : left 9,10 : width 9,90
item_add 9,"Texte seul"
item_add 9,"Horizontal"
item_add 9,"Vertical"
item_add 9,"Camembert"
item_add 9,"Aiguille"
button 10 : top 10,210 : left 10,10 : caption 10,"Créer" : on_click 10,creer
button 11 : top 11,210 : left 11,110 : caption 11,"Supprimer" : on_click 11,supprimer
button 12 : top 12,240 : left 12,10 : caption 12,"Animer" : on_click 12,animer

dll_on "KGF.dll"
res% = dll_call3("SetProgressBarColor",handle(1),hex("00FFFF"),hex("0000FF"))
res% = dll_call2("SelectComboBoxItem",handle(9),2)
end

creer:
typ% = item_index(9) - 1
select typ%
case 0
w% = 200
h% = 25
case 1
w% = 200
h% = 25
case 2
w% = 25
h% = 200
case 3
w% = 200
h% = 200
case 4
w% = 200
h% = 100
end_select
PB% = dll_call2("CreateProgressBar",handle(0),typ%)
res% = dll_call5("LocateProgressBar",PB%,250,10,w%,h%)
res% = dll_call3("SetProgressBarLimits",PB%,0,255)
res% = dll_call3("SetProgressBarColors",PB%,hex("00FFFF"),hex("0000FF"))
res% = dll_call2("SetProgressBarPosition",PB%,60)
return

supprimer:
timer_off 8
PB% = dll_call1("DeleteProgressBar",PB%)
return

animer:
pos% = 0
res% = dll_call2("SetProgressBarPosition",PB%,pos%)
timer_on 8
return

tick:
timer_off 8
pos% = pos% + 1
if pos%>=256 then return
res% = dll_call2("SetProgressBarPosition",PB%,pos%)
timer_on 8
return

Pour tester, il faut choisir le type de ProgressBar souhaité avec la combo, puis cliquer sur "Créer".
Le bouton "Supprimer" supprime la barre et permet d'en créer une autre.
Le bouton "Animate" fait défiler la barre 1 fois de son minimum à son maximum.

Un exemple, pour le camembert:
Couleur Progress_bar Aa182

Encore un petit plus pour agrémenter nos applications à nos couleurs préférées !

Tu n'es jamais à court d'inspiration à ce que je vois...
Et tant mieux car tu fais notre bonheur ! Laughing

Pour Klaus, HIP HIP HIP.... HOURRA ! cheers

Houra à mon tour, c'est trop génial.

merci pour les belles réalisations et la distribution de cette nouvelle Dll.
A bientôt.

Pour la peine, j'ai ajouté un nouveau type de ProgressBar: un anneau elliptique (largeur et hauteur de l'ellipse sont réglables, ainsi que le diamètre du "trou" intérieur). Seule la bande représentant la ScrollBar sera affichée - le reste de la fenêtre transparaîtra à côté ou à travers l'anneau et est même cliquable.

La nouvelle version de KGF.dll est sur le WebDav dossier DLLs ainsi que sur mes deux sites internet.

Voici le programme de démo. J'ai affiché un picture coloré sur lequel les ScrollBars vont s'afficher. Essayez l'anneau via la COMBO de sélection, vous pouvez régler le diamètre intérieur par le SPIN, puis cliquez zue "Créer". Vous pouvez lancer l'animation, cliquer à travers l'anneau...

Code:: label creer, supprimer, animer, tick, click
dim res%, PB%, w%, h%, typ%, pos%, inner%, x%
progress_bar 1 : min 1,0 : max 1,255 : top 1,100 : position 1,100
progress_bar 2 : position 2,50 : top 2,140

timer 8 : on_timer 8,tick : timer_off 8 : timer_interval 8,10
combo 9 : top 9,180 : left 9,10 : width 9,90
item_add 9,"Texte seul"
item_add 9,"Horizontal"
item_add 9,"Vertical"
item_add 9,"Camembert"
item_add 9,"Aiguille"
item_add 9,"Anneau"
alpha 91 : top 91,180 : left 91,120 : caption 91,"Anneau: diamètre intérieur:"
spin 92 : top 92,180 : left 92,250 : width 92,45
min 92,0 : max 92,199 : position 92,160
picture 93 : top 93,5 : left 93,295 : width 93,210 : height 93,210 : color 93,0,255,255
on_click 93,click
button 10 : top 10,210 : left 10,10 : caption 10,"Créer" : on_click 10,creer
button 11 : top 11,210 : left 11,110 : caption 11,"Supprimer" : on_click 11,supprimer
button 12 : top 12,240 : left 12,10 : caption 12,"Animer" : on_click 12,animer

dll_on "KGF.dll"
res% = dll_call3("SetProgressBarColor",handle(1),hex("00FFFF"),hex("0000FF"))
res% = dll_call2("SelectComboBoxItem",handle(9),2)
end

creer:
typ% = item_index(9) - 1
x% = 300
select typ%
case 0
w% = 200
h% = 25
inner% = 0
case 1
w% = 200
h% = 25
inner% = 0
case 2
w% = 25
h% = 200
inner% = 0
case 3
w% = 200
h% = 200
inner% = 0
case 4
w% = 200
h% = 100
inner% = 0
case 5
x% = 150
w% = 200
h% = 400 : ' intentionnellement en ellipse pour montrer cela !
inner% = position(92)
end_select
PB% = dll_call2("CreateKGFProgressBar",handle(0),typ%)
res% = dll_call6("LocateKGFProgressBar",PB%,x%,10,w%,h%,inner%)
res% = dll_call3("SetKGFProgressBarLimits",PB%,0,255)
res% = dll_call3("SetKGFProgressBarColors",PB%,hex("00FFFF"),hex("0000FF"))
res% = dll_call2("SetKGFProgressBarPosition",PB%,60)
return

supprimer:
timer_off 8
PB% = dll_call1("DeleteKGFProgressBar",PB%)
return

animer:
pos% = 0
res% = dll_call2("SetKGFProgressBarPosition",PB%,pos%)
timer_on 8
return

tick:
timer_off 8
pos% = pos% + 1
if pos%>=256 then return
res% = dll_call2("SetKGFProgressBarPosition",PB%,pos%)
timer_on 8
return

click:
message "Clic dans le picture 93"
return

Voici de quoi ça a l'air, avec un anneau colontairement en ellipse (évidemment, un cercle est possible !):
Couleur Progress_bar Aa184

D'après ce que je constate, l'anneau se place par-dessus les ALPHA et PICTURE, mais en-dessous des BUTTON et autres contrôles avec handle.

Avec ces fonctions, on peut aussi faire ceci (assez spectaculaire):

Code:: ' test_2_ProgressBar_concentriques

dim res%, PBinner%, PBouter%, i%

dll_on "KGF.dll"

PBinner% = dll_call2("CreateKGFProgressBar",handle(0),5)
res% = dll_call6("LocateKGFProgressBar",PBinner%,100,100,200,200,0)
res% = dll_call3("SetKGFProgressBarLimits",PBinner%,0,255)
res% = dll_call3("SetKGFProgressBarColors",PBinner%,hex("00FFFF"),hex("0000FF"))

PBouter% = dll_call2("CreateKGFProgressBar",handle(0),5)
res% = dll_call6("LocateKGFProgressBar",PBouter%,80,80,240,240,200)
res% = dll_call3("SetKGFProgressBarLimits",PBouter%,0,255)
res% = dll_call3("SetKGFProgressBarColors",PBouter%,hex("FFFF00"),hex("FF0000"))

for i%=0 to 255
res% = dll_call2("SetKGFProgressBarPosition",PBinner%,i%)
res% = dll_call2("SetKGFProgressBarPosition",PBouter%,256-i%)
pause 20
next i%

end

Essayez-le !

» Barre de titre sans les 3 boutons
» Resultat de couleur
» Brightness ne ce met pas en couleur !
» Couleur et objet TAB
» De la couleur partout^^