Gestionnaire de Projets Panoramic

hide 0
Variables()
Labels()
Init()
Gui()
show 0
end

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' DECLARATION DES VARIABLES
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SUB Variables()
' -Fichiers
   dim kgf$    : kgf$    = "KGF.dll"
   dim temp$   : temp$   = "C:\PanoSubTemp"
   dim biblio$ : biblio$ = "C:\PanoSubTemp\biblio.txt"
' -Numérotation des objets
   dim no%
   dim Frame0% : no% = no%+1 : Frame0% = no%
   dim Frame1% : no% = no%+1 : Frame1% = no%
   dim Frame2% : no% = no%+1 : Frame2% = no%
   dim biblio% : no% = no%+1 : biblio% = no%
   dim import% : no% = no%+1 : import% = no%
   dim proc%   : no% = no%+1 : proc%   = no%
   dim view%   : no% = no%+1 : view%   = no%
   dim affich% : no% = no%+1 : affich% = no%
   dim ListCat%: no% = no%+1 : ListCat%= no%
   dim flire%  : no% = no%+1 : flire%  = no%
END_SUB

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' DECLARATION DES LABELS
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SUB Labels()
   Label Clic
   Label Close0
END_SUB

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' INITIALISATIONS
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SUB Init()
   dim_local res%,url$,fic$
   dll_on kgf$
   if dir_exists(temp$)=0 : dir_make temp$ : end_if
   url$ = "http://panoramiclemag.magix.net/public/Telechargements2/biblio.txt"
   fic$ = Temp$+"\biblio.txt"
   res% = DLL_call2("DownloadFile",adr(url$),adr(fic$))
END_SUB

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' INTERFACE UTILISATEUR
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SUB Gui()
   dim_local i%,h%,w%

   height 0,480
   width 0,940
   top 0,(screen_y-height(0))/2
   left 0,(screen_x-width(0))/2
   font_name 0,"Arial" : font_size 0,8 : font_bold 0
   caption 0,"PanoSub - Reader"
   on_close 0,close0
  
   Panel Frame0% : full_space Frame0% : h%=height(Frame0%) : w%=width(Frame0%)

   Panel Frame1%
   parent Frame1%,Frame0%
   height Frame1%,26 : width Frame1%,w% : Top Frame1%,0 : Left Frame1%,0
  
   Panel Frame2%
   parent Frame2%,Frame0%
   height Frame2%,h%-26 : width Frame2%,w% : Top Frame2%,26 : Left Frame2%,0
  
   Combo Biblio%
   Parent Biblio%,Frame1%
   width Biblio%,250 : Top Biblio%,2 : Left Biblio%,5
   initbiblio()
   on_click biblio%, clic

   list Proc%
   Parent Proc%,Frame2%
   height Proc%,height(frame2%)-10 : width Proc%,290 : Top Proc%,5 : Left Proc%,5
   font_color proc%,0,0,200
   on_click proc%,clic
   cursor_point proc%

   memo affich%
   parent affich%,frame2%
   height affich%,height(frame2%)-10 : width affich%,width(frame2%)-310
   top affich%,5 : left affich%,305
   bar_both affich%
  
END_SUB

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' MENUS
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Clic:
   if number_click = biblio% : ImportBiblio(text$(biblio%)) : end_if
   if number_click = proc%
      if count(proc%)>0
         AffichSub(item_index$(proc%))
      end_if
   end_if
return

Close0:
   MrPropre()
return

' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
' FONCTIONS
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SUB MrPropre()
   dim_local res%
   res% = dll_call1("DeleteFileToRecycleBin",adr(temp$))
END_SUB

SUB InitBiblio()
   dim_local a$,i%
   clear biblio%
   item_add biblio%,"--- Bibliothèques ---" : text biblio%,"--- Bibliothèques ---"
   if file_exists(biblio$)=1
      file_open_read flire%,biblio$
      while file_eof(flire%)<>1
         file_readln flire%,a$
         item_add biblio%,a$
      end_while
   else
      i%=message_warning_ok("Le fichier :"+chr$(13)+biblio$+chr$(13)+"est introuvables !")
   end_if
END_SUB

SUB ImportBiblio(F$)
   dim_local res%,url$,fic$,a$,i%,fil$
   fil$ = F$
   if fil$ = "--- Bibliothèques ---" : exit_sub : end_if
   remplace_caractere(fil$,"è","e") : fil$ = retour$
   remplace_caractere(fil$,"é","e") : fil$ = retour$
   remplace_caractere(fil$,"ë","e") : fil$ = retour$
   remplace_caractere(fil$,"à","a") : fil$ = retour$
   remplace_caractere(fil$,"-","_") : fil$ = retour$
   remplace_caractere(fil$," ","_") : fil$ = retour$
  
   url$ = "http://panoramiclemag.magix.net/public/Telechargements2/"+Fil$+".zip"
   fic$ = temp$+""+Fil$+".zip"
'  nettoyage du dossier
   dir_change temp$
   a$ = file_find_first$
      if Upper$(file_extract_extension$(a$))=".BAS"
         file_delete a$
      end_if
   a$ = file_find_next$
   while a$<>"_"
      if Upper$(file_extract_extension$(a$))=".BAS"
         file_delete a$
      end_if
      a$=file_find_next$
   end_while
   file_find_close
'  telechargement du zip
   res% = DLL_call2("DownloadFile",adr(url$),adr(fic$))
'  dezippage
   archiver_on
   archiver_extract fic$,temp$
   archiver_off
'  suppressioon du zip
   file_delete fic$
'  remplisage du combo des procedures
   clear Proc%
   dir_change temp$
   a$ = file_find_first$
      if upper$(file_extract_extension$(a$))=".BAS"
         item_add Proc%,file_extract_name$(a$)
      end_if
   a$ = file_find_next$
   while a$<>"_"
      if upper$(file_extract_extension$(a$))=".BAS"
         item_add Proc%,file_extract_name$(a$)
      end_if
      a$ = file_find_next$
   end_while
   file_find_close
END_SUB

SUB remplace_caractere(texte$,char_indesirable$,char_subsitution$)
    dim_local l% : l% = len(texte$)
    dim_local chaine$(l%),i%
    if variable ("retour$") = 0 then dim retour$
    retour$ = ""
    for i% = 1 to l%
       chaine$(i%)= mid$(texte$,i%,1)
       if chaine$(i%) = char_indesirable$  then  chaine$(i%) = char_subsitution$
    next i%
    for i% = 1 to l%
       retour$ = retour$+chaine$(i%)
    next i%
END_SUB

SUB AffichSub(F$)
   dim_local fil$
   fil$ = F$
   clear affich%
   file_load affich%,fil$
END_SUB