Memory Starwars - Reedition

REM Memory en Panoramic
REM Par Jean-Charles
REM V1.1

dim Max_Carte, S_b%, LevelMax

Max_Carte = 50 : S_b% = 19 : LevelMax = 16

dim chemin$, carte$, dos$, Niveau%, nbl, nbc, ligne, col, S%, xM%, yM%
dim lC1%,cC1%, temp%,C1%,C2%, cases(Max_Carte), melange(Max_Carte), compteur%, max%

label Niveau, Test_clic, TraiteC1C2

Niveau% = 3: C1%=0 : C2%=0 : compteur% = 0 : Carte$ = "starwars\C_" : Dos$ = Carte$+"dos.bmp"

scene2d 1
For S% = (S_b% + 1) to (S_b% + 1) + Max_Carte: sprite S% : next S%
timer 2 :timer_interval 2,70 : timer_off 2: on_timer 2, Test_clic
gosub Niveau
end

Test_clic:
if mouse_left_down(1)=1
 timer_off 2
 xM% = mouse_x_left_down(1)
 yM% = mouse_y_left_down(1)
 col = int((xM% - 200) / 110)+1
 ligne = int((yM% - 200) / 110)
 temp% = ligne * Nbc + col
 if melange(temp%) = 0 and C1% = 0
    C1% = temp%
    sprite_file_load S_b% + C1%, Carte$ + right$("00"+STR$(cases(temp%)), 2) +".bmp"
    sprite_position S_b% + C1%, 205 + 110*(col-1), 205 + 110*ligne
    cC1% = col : lC1% = ligne
  else
    if melange(temp%) = 0 and  C2% = 0 and temp% <> C1%
          C2% = temp%
          sprite_file_load S_b% + C2%, chemin$ + Carte$ + right$("00"+STR$(cases(temp%)), 2) +".bmp"
          sprite_position S_b% + C2%, 205 + 110*(col-1), 205 + 110*ligne
          gosub traiteC1C2
      end_if
 end_if
end_if
if compteur% = 0 then gosub Niveau
timer_on 2
Return

TraiteC1C2:

if cases(C1%) = cases(C2%)
  melange(C1%) = cases(C1%)
  melange(C2%) = cases(C2%)
  compteur% = compteur% - 2
else
  wait 1000
  sprite_file_load S_b% + C1%, chemin$ + dos$
  sprite_position  S_b% + C1%, 205 + 110*(cC1%-1), 205 + 110*lC1%
  sprite_file_load S_b% + C2%, chemin$ + dos$
  sprite_position  S_b% + C2%, 205 + 110*(col-1), 205 + 110*ligne
end_if
C1% = 0 : C2% = 0
return

Niveau:
if Niveau% < LevelMax
  Niveau% = Niveau% + 1 : Caption 0,"Memory - niveau : " + str$(Niveau%)
  timer_off 2
  Select Niveau%
    case 1:  nbl = 2: nbc = 2 : Max% = 4
    case 2:  nbl = 2: nbc = 3 : Max% = 6
    case 3:  nbl = 2: nbc = 4 : Max% = 8
    case 4:  nbl = 2: nbc = 5 : Max% = 10
    case 5:  nbl = 3: nbc = 4 : Max% = 12
    case 6:  nbl = 2: nbc = 7 : Max% = 14
    case 7:  nbl = 4: nbc = 4 : Max% = 16
    case 8:  nbl = 3: nbc = 6 : Max% = 18
    case 9:  nbl = 4: nbc = 5 : Max% = 20
    case 10: nbl = 4: nbc = 6 : Max% = 24
    case 11: nbl = 4: nbc = 7 : Max% = 28
    case 12: nbl = 5: nbc = 6 : Max% = 30
    case 13: nbl = 4: nbc = 8 : Max% = 32
    case 14: nbl = 6: nbc = 6 : Max% = 36
    case 15: nbl = 5: nbc = 8 : Max% = 40
    case 16: nbl = 6: nbc = 7 : Max% = 42
  End_Select
  width 0, 110* Nbc + 27 : height 0, 50 + 110 * Nbl
  full_space 1 : stretch_on 1: File_load 1, "blanc.bmp"
  S% = 1
  while S%<= Max_Carte
    if S% <= Max%
        melange(S%) = 1
    else
        melange(S%) = 0
    end_if
    S% = S% +1
  end_while
  S% = 1
  while S%  <=  Max%
    temp% = 0
    while temp% = 0
        temp% = int(rnd(Max%/2))+1
        if temp% > (Max%/2) then temp% = 0
      if temp% > 0
        if melange(2*temp%- 1) = 1
          melange(2*temp%- 1) = 0
        else
          if melange(2*temp%) = 1
            melange(2*temp%) = 0
          else
            temp% = 0
          end_if
        end_if
      end_if
    end_while
    cases(S%) = temp%
    S%=S%+1
  end_while
  top 1, -200: left 1, -200: width 1, width(0) +167 : height 1, height(0) +150
  for ligne = 0 to (Nbl - 1)
    for col = 0 to (Nbc - 1)
      S% = (S_b% + 1) + ligne * Nbc + col
      sprite_file_load S%, chemin$ + dos$
      sprite_position S%, 205 + 110*col, 205 + 110*ligne
      compteur% = compteur% + 1
    next col
  next ligne
  timer_on 2
else
  Message "Bravo"
  wait 4000
  Terminate
End_if
return