Pouvoir utiliser des fichiers *.HLP sous Vista, W7, ...

helpexplorer.exe -F "C:\Documents and Settings\Klaus\Mes documents\Mes projets Panoramic\Help file\KGF.hlp"

' Menu_Aide.bas

label labels : gosub labels
gosub constantes
gosub variables
gosub donnees
gosub form0
gosub menu
gosub GUI
gosub initialisations
end

labels:
  label constantes, variables, donnees, form0, menu, GUI, initialisations
  label choix, fermer, sel, taille_debut, taille_choix
  return

constantes:
  dim dll$ : dll$ = "KGF.dll"
  dim icone$ : icone$ = "Menu_Aide.jpg"
  return
 
variables:
  dim no%, i%, n_help%, no_fichiers%, no_libelles%, s$, file$, n%, no_icone%
  dim version$, w7%
  return

donnees:
  data "KGF.hlp","KGF.dll de Klaus"
' ajouter ici les autres dlls: data fichier HLP,libellé
  data "*eof*"  : ' fin de la liste
  return

form0:
  border_small no%
  gosub taille_debut
  on_close 0,fermer
  return

menu:
  return

GUI:
  no% = no% + 1 :  dlist no% : no_fichiers% = no%
  no% = no% + 1 : combo no% : no_libelles% = no% : hide no% : width no%,200
    on_click no%,choix
  no% = no% + 1 : picture no% : no_icone% = no% : width no%,32 : height no%,32
    file_load no%,icone$ : on_click no%,sel
 
  return

initialisations:
  dll_on dll$
  version$ = string$(255," ")
  i% = dll_call1("GetWindowsVersion",adr(version$))
  w7% = instr(version$,"Windows 7")
  read s$
  while s$<>"*eof*"
    n_help% = n_help% + 1
    item_add no_fichiers%,s$
    read s$
    item_add no_libelles%,s$
    read s$
  end_while
  return
 
choix:
  n% = item_index(no_libelles%)
  file$ = item_read$(no_fichiers%,n%)
  i% = dll_call2("Help",1,adr(file$))
  i% = dll_call2("Help",2,0)
  hide no_libelles%
  gosub taille_debut
  show no_icone%
  return
 
sel:
  hide no_icone%
  gosub taille_choix
  show no_libelles%
  return
 
fermer:
  i% = dll_call2("Help",0,0)
  dll_off
  return

taille_debut:
  if w7%>0
    width 0,70 : height 0,70
  else
    width 0,42 : height 0,60
  end_if
  return
 
taille_choix:
  width 0,210 : height 0,50
  return