Truc tout bête avec EDIT

hide 0

LABEL Calc
LABEL KeyboardTimer, ActiveKeyTimer


' --------------------------------------------
' Variables de calcul
' --------------------------------------------
dim bac_hauteur,bac_longueur,bac_profondeur,bac_epaisseur
dim bac_volume,bac_poids

dim baci_hauteur,baci_longueur,baci_profondeur
dim baci_cm,baci_volume
' --------------------------------------------
'    Définition du formulaire de saisie
' --------------------------------------------
dim sbac_hauteur,sbac_longueur,sbac_profondeur,sbac_epaisseur
dim sbac_volume,sbac_poids
sbac_hauteur=100:sbac_longueur=102:sbac_profondeur=104:sbac_epaisseur=106
sbac_volume=118:sbac_poids=120

dim sbaci_volume,sbaci_cm,sbaci_poids
sbaci_volume=200:sbaci_cm=202:sbaci_poids=204

' construction des champs
dim i,j
dim nb_cont,id_cont: nb_cont=2
dim nb_ele
dim txt$,value,value2

data 1,"Dimensions",10,10,4
data "Longueur  (m) :",sbac_longueur,1.5,""
data "Hauteur    (m) :",sbac_hauteur,0.5,""
data "Profondeur (m) :",sbac_profondeur,0.5,""
data "Epaisseur (mm) :",sbac_epaisseur,8,"Note:la densité pour du verre sodo-calcique de qualité courante est de 2,53"

data 2,"Volumes",left(1)+width(1)+10,10,4
data "Volume brut (litre)  :",sbac_volume,0,""
data "Volume interne (litre):",sbaci_volume,0,""
data "Poids à vide (kg):",sbac_poids,0,"le poids ne tient pas compte du poids des renforts, des entretoises, raidisseurs et verre de couverture"
data "Nb litres/cm:",sbaci_cm,0,""

for i = 1 to nb_cont
  read id_cont: container id_cont : read txt$: caption id_cont,txt$
  read value: left id_cont,value  : read value: top id_cont,value
  read nb_ele : height id_cont,((nb_ele+1)*20)+10 : width id_cont,200
  for j=1 to nb_ele
    read txt$ : read value
    edit value : left value, 118+10 : top value,(20*j):width value, 50: parent value,id_cont
    alpha value+1 : caption value+1, txt$ : left value+1, 10 : top value+1,top(value)+5 : parent value+1, id_cont
    read value2: text value, str$(value2)
    if (value2=0)
      color value,200,255,200
      inactive value
    end_if
    read txt$:hint value,txt$
  next j
next i

' timer pour traitement de saisie des champs
DIM KeyboardTimer%  : KeyboardTimer% = 1000
TIMER KeyboardTimer% : TIMER_OFF KeyboardTimer% : TIMER_INTERVAL KeyboardTimer%,3000
ON_TIMER KeyboardTimer%,KeyboardTimer

' les evenements :
on_change sbac_longueur, ActiveKeyTimer
on_change sbac_hauteur, ActiveKeyTimer
on_change sbac_profondeur, ActiveKeyTimer
on_change sbac_epaisseur, ActiveKeyTimer
gosub Calc
show 0
END

' ===============================================================================================
' ===============================================================================================

' Calculs divers
Calc:
  bac_longueur = val(text$(sbac_longueur))
  bac_hauteur = val(text$(sbac_hauteur))
  bac_profondeur = val(text$(sbac_profondeur))
  bac_epaisseur = val(text$(sbac_epaisseur))/1000
  ' dimensions internes
  baci_longueur = bac_longueur - ( 2 * bac_epaisseur)
  baci_hauteur = bac_hauteur - bac_epaisseur
  baci_profondeur = bac_profondeur - ( 2 * bac_epaisseur)
  ' calcul du volume brut
  bac_volume = bac_longueur * bac_hauteur * bac_profondeur * 1000
  text sbac_volume,str$(int(bac_volume*10)/10)
  ' calcul du volume interne
  baci_volume =(baci_longueur * baci_hauteur * baci_profondeur) * 1000
  text sbaci_volume,str$(int(baci_volume*10)/10)
  ' calcul du volume des vitres (pour détermination du poids du bac à vide :
  bac_poids = (bac_volume - baci_volume) * 2.53
  text sbac_poids,str$(int(bac_poids*100)/100)
  ' calcul du nombre de litre / cm
  baci_cm = baci_longueur * baci_profondeur * 10
  text sbaci_cm, str$(int(baci_cm*100)/100)
return

' ----------------------------------------------------------------
' Edition
' ----------------------------------------------------------------
ActiveKeyTimer:
  TIMER_OFF KeyboardTimer%
  TIMER_INTERVAL KeyboardTimer%, 1500 : ' réarme la bdt du timer
  TIMER_ON KeyboardTimer%
RETURN

KeyboardTimer:
  TIMER_OFF KeyboardTimer%  : ' désactive
  GOSUB Calc
RETURN