Pour mon menu...

Voilà je me suis fait mon petit menu mais il est vraiment nul ! On pourait pas sans servir dans la réalité et en plus tout est mélangé...Est ce que quelqu'un pourait m'aidé à : trouver comment on fait couper,copier,coller et pour réellement ouvrir un fichier et réelement en enregistrer un...

Code:

LABEL nouveau, ouvrir, enregistrer, quitter, aide, quitte_aide

CAPTION 0,"Menu"

MAIN_MENU 1

SUB_MENU 2 : PARENT 2,1 : CAPTION 2,"Fichier"
SUB_MENU 3 : PARENT 3,1 : CAPTION 3,"Edition"
SUB_MENU 4 : PARENT 4,1 : CAPTION 4,"Aide"

SUB_MENU 5 : PARENT 5,2 : CAPTION 5,"Nouveau"
SUB_MENU 6 : PARENT 6,2 : CAPTION 6,"Ouvrir"
SUB_MENU 7 : PARENT 7,2 : CAPTION 7,"Enregistrer"
SUB_MENU 8 : PARENT 8,2 : CAPTION 8,"Quitter"

SUB_MENU 9 : PARENT 9,3 : CAPTION 9,"Couper    Ctrl+X"
SUB_MENU 10: PARENT 10,3: CAPTION 10,"Copier  Ctrl+C"
SUB_MENU 11: PARENT 11,3: CAPTION 11,"Coller  Crtl+V"

SUB_MENU 12: PARENT 12,4: CAPTION 12,"Aide"



ON_CLICK 5,nouveau
ON_CLICK 6,ouvrir
ON_CLICK 7,enregistrer
ON_CLICK 8,quitter



FORM 18:TOP 18,200:LEFT 18,200
HIDE 18
MEMO 19:PARENT 19,18
WIDTH 19,310:HEIGHT 19,150

BUTTON 20:TOP 20,160:LEFT 20,110:CAPTION 20,"Ferme"
PARENT 20,18
ITEM_ADD 19,"Ceci est le fichier d'aide,"
ITEM_ADD 19,"qui est sensé être utile"
ITEM_ADD 19,"pour aidé l'utilisateur..."

ON_CLICK 12,aide
ON_CLICK 20,quitte_aide

END

nouveau:
MEMO 15

RETURN

ouvrir:
DIM a$ : REM déclarer une variable string

OPEN_DIALOG 16 : REM créer un OPEN_DIALOG
a$=FILE_NAME$(16) : REM choisir un nom de fichier avec l'OPEN_DIALOG numéro 1
IF a$ <> "_" THEN - - - : REM si a$ contient un nom de fichier, alors - - -

enregistrer:
 SAVE_DIALOG 17 : REM créer un SAVE_DIALOG
    REM pour sauvegarder le contenu du memo avec le save_dialog
    FILE_SAVE 2,FILE_NAME$(17)

quitter:
MESSAGE "voulez vous vraiment quitter? Si oui cliquez sur le bouton OK si non et bien sais trop tard"
TERMINATE

aide:
SHOW 18
RETURN

quitte_aide:
HIDE 18
RETURN

PS: je sais il est très mal organisé...

Pour un début, ce n'est pas mal du tout.

Avant de tester ton source, je remarque à la lecture:

1 - qu'à chaque fois que tu vas executer le sous-programme en "ouvrir" (c'est à dire à chaque fois qu'on fera Fichier puis Ouvrir), on va déclarer la variable a$. La première fois, c'est correct, a$ est déclarée, mais la deuxième fois qu'on exécute ouvrir, comme la variable est déjà déclarée, il y a une erreur.
Il est conseillé de mettre les déclarations de variable en début de programme, comme ça, c'est fait une fois pour toutes.

2 - de même, l'open_dialog numéro 18, qui a déja été créé la première fois, ne peut pas être recréé. Il y aura une erreur à la deuxième exécution.

3 - si je vais exécuter une deuxième fois nouveau, comme MEMO numéro 15 est déjà créé, je ne peux le recréer et il y aura une erreur.

4 - les sous-programmes nouveau, ouvrir, enregistrer, et quitter ne se terminent pas par RETURN. Quand on exécute nouveau, on continue ensuite à exécuter ouvrir, enregistrer, quitter et l'exécution ne s'arrête qu'au TERMINATE de quitter ! c'est à dire que dans le menu, quoi qu'on fasse: ouvrir, enregistrer ou quitter, le programme s'arrètera avec TERMINATE.
En fait, il s'arrète car THEN - - - n'est pas correct.

Passons maintenant à l'amélioration de ton source:

1 - sous-programme NOUVEAU
Pour éviter de créer une deuxième fois le MEMO numéro 18, je suggère d'empêcher de refaire Fichier Nouveau et rendant inactif ce sous-menu:
INACTIVE 5
Nouveau devient donc inactif et grisé dans le Menu.

2 - sous-programme OUVRIR
je suppose que tu veux remplir le MEMO numéro 15 avec le contenu du fichier choisi:
FILE_LOAD 15,a$

3 - sous-programme ENREGISTRER
si tu veux enregistrer le contenu du MEMO comme le dit ta remarque, c'est l'objet 15 et non 2 qui est un sous-menu:
FILE_SAVE 15,FILE_NAME$(17)

4 - Il y a maintenant un problèmes de logique à résoudre:
empêcher de faire OUVRIR et ENREGISTRER quand le MEMO n'a pas été créé par NOUVEAU.
Tu peux utiliser pour cela INACTIVE et ACTIVE:
après création des sous-menus 6 et 7 tu les passes inactifs:
INACTIVE 6:INACTIVE 7
puis dans le sous-programme nouveau, tu les rends actifs en mettant:
ACTIVE 6:ACTIVE 7

5 - enfin, petite amélioration: rendre MEMO numéro 15 plus grand avec:
FULL_SPACE 15
et lui mettre un ascenseur pour qu'on puisse se balader dans les longs fichiers:
BAR_VERTICAL 15

Voila le source "amélioré":

Code:

LABEL nouveau, ouvrir, enregistrer, quitter, aide, quitte_aide
DIM a$ : REM déclarer une variable string

CAPTION 0,"Menu"

MAIN_MENU 1

SUB_MENU 2 : PARENT 2,1 : CAPTION 2,"Fichier"
SUB_MENU 3 : PARENT 3,1 : CAPTION 3,"Edition"
SUB_MENU 4 : PARENT 4,1 : CAPTION 4,"Aide"

SUB_MENU 5 : PARENT 5,2 : CAPTION 5,"Nouveau"
SUB_MENU 6 : PARENT 6,2 : CAPTION 6,"Ouvrir"
SUB_MENU 7 : PARENT 7,2 : CAPTION 7,"Enregistrer"
SUB_MENU 8 : PARENT 8,2 : CAPTION 8,"Quitter"
INACTIVE 6:INACTIVE 7

SUB_MENU 9 : PARENT 9,3 : CAPTION 9,"Couper    Ctrl+X"
SUB_MENU 10: PARENT 10,3: CAPTION 10,"Copier  Ctrl+C"
SUB_MENU 11: PARENT 11,3: CAPTION 11,"Coller  Crtl+V"

SUB_MENU 12: PARENT 12,4: CAPTION 12,"Aide"

ON_CLICK 5,nouveau
ON_CLICK 6,ouvrir
ON_CLICK 7,enregistrer
ON_CLICK 8,quitter

FORM 18:TOP 18,200:LEFT 18,200
HIDE 18
MEMO 19:PARENT 19,18
WIDTH 19,310:HEIGHT 19,150

BUTTON 20:TOP 20,160:LEFT 20,110:CAPTION 20,"Ferme"
PARENT 20,18
ITEM_ADD 19,"Ceci est le fichier d'aide,"
ITEM_ADD 19,"qui est sensé être utile"
ITEM_ADD 19,"pour aidé l'utilisateur..."

ON_CLICK 12,aide
ON_CLICK 20,quitte_aide

END

nouveau:
MEMO 15
INACTIVE 5
ACTIVE 6:ACTIVE 7
FULL_SPACE 15
BAR_VERTICAL 15
RETURN

ouvrir:
OPEN_DIALOG 16 : REM créer un OPEN_DIALOG
a$=FILE_NAME$(16) : REM choisir un nom de fichier avec l'OPEN_DIALOG numéro 1
IF a$ <> "_" THEN FILE_LOAD 15,a$ : REM si a$ contient un nom de fichier, alors on remplit le MEMO
RETURN

enregistrer:
SAVE_DIALOG 17 : REM créer un SAVE_DIALOG
REM pour sauvegarder le contenu du memo avec le save_dialog
FILE_SAVE 15,FILE_NAME$(17)
RETURN

quitter:
MESSAGE "voulez vous vraiment quitter? Si oui cliquez sur le bouton OK si non eh bien c'est trop tard"
TERMINATE

aide:
SHOW 18
RETURN

quitte_aide:
HIDE 18
RETURN

Eh bien, on commence à avoir un traitement de texte écrit avec PANORAMIC.

Vivement la suite !

un traitement de texte en panoramic ^^
si 'il a de bonne fonctions ca pourra etre une alternative a word ^^
(et leger en plus de ca !)

Et ben vraiment merci ! ! cette version est 10 fois mieux que ma version a moi ^^

une petite chose...on peu mettre combien de sub_menu parce que j'ai éséyé de créer un menu comme celui de panoramic mais sa me mais une erreur et je ne suis pas sur de se qu'elle veut dire (la numéros 47)

Encore merci pour votre aide panoramic

L'erreur 47 (numéro d'objet hors limites) te rappelle simplement que tu as entre les mains une version d'essai de PANORAMIC. Cette version est gratuite, mais en contrepartie, cette version a des limitations: si tu regardes le paragraphe 19 du manuel utilisateur, tu y lis que le nombre d'objets systèmes est limité à 35.
Un menu est un objet système, un sous-menu aussi.
Avec 35 objets, tu as de quoi t'entrainer , apprendre la programmation avec PANORAMIC, et créer des applications qui "tiennent la route".

Il est inutile de me demander une version complète payante: elle n'existe pas. Tous les jours, je recois des mails privés de gens qui me la demande.

Elle n'existe pas pour une raison majeure: PANORAMIC a encore des bugs, que je dois corriger, PANORAMIC a encore beaucoup de progrès à faire (utiliser le joystick, utiliser d'autres objets système très intéressants comme le TIMER, des DLL, les API, les liaisons série, l'USB, ...) avant d'avoir une version V 1 qui serait diffusable.

^^ o utu fais comme moi plusieur programmes XD

Oui mais pour un menu je ne vois pas comment tu peu faire

Comment faire pour que dans "Edition" "copier" aboutisse à quelque chose?

PS: pareilpour coller et couper ....

ouais c'est vrai qu'avec un menu ^^ ca marchera po ^^ regarde si y'a pasune commande copy et paste dans le manuel

Ouai je verrai qand j'aurais le temps...

Pour autant que je sache, il n'existe pas de commandes d'accès au presse-papier de Windows (copier, coller).

En effet, il n'existe pas de commandes en relation avec le presse papier, mais si certains sont intéressés par cette possibilité, on peut créer les commandes:
CLIPBOARD_COPY et CLIPBOARD_PASTE

bonjour

oui il serai interessant d'avoir les commandes

CLIPBOARD_COPY et CLIPBOARD_PASTE moi personnellement
je suis pour .

j'epère que sa interessera d'autre personne a voir.

bonne journée a tous

Idem, ça peut être intéressant pour passer des données, ou récupérer des données d'un autre programme sous Windows.
Exemple d'utilisation personnelle: consultation et archivage des comptes sur internet. Au moment de la consultation, je copie la page dans le pp (Ctrl/C). Dans le programme de traitement écrit sous Panoramic, je récupére ensuite et je traite les données du presse-papier.
Actuellement je lance depuis mon programme Panoramic un utilitaire externe (Clip.exe) qui copie les données du pp dans un fichier, et je les récupère dans ce fichier.
Ce serait mieux, évidemment, de pouvoir y lire directement, du moins pour les données "texte" qui m'intéressent.
Pour les données "images" c'est sans doute peu utile, ou pas du tout, et sans doute aussi beaucoup plus compliqué à réaliser.

PS: Clip.exe est une ancienne version d'un utilitaire freeware trouvé sur internet, qui se lance en ligne de commande, donc possibilité à partir d'un autre programme. Il semble que les nouvelles versions soient plus difficiles (impossibles ?) à utiliser de cette façon.
La syntaxe est (était) simple:
CLIP fichier -> copie du fichier donné dans le pp
CLIP fichier /r -> copie du pp dans le fichier donné
DIR | CLIP.exe -> redirection de la sortie d'un programme (ici DIR)
CLIP fichier.bmp -> copie d'une image bitmap dans le pp

PS2: pour ceux que ça intéresserait, j'ai retrouvé la version que j'utilise là: http://www.wordstar2.com/modules.php?name=Downloads&d_op=viewdownloaddetails&lid=54&ttitle=Dave_Navarro,_Jr.%27s_Clip.exe_-_Utility
(cliquer sur "Download this file Now !") c'est un .zip tout petit (15k) contenant clip.exe et clip.txt

PS3 il existe dans Windows Vista un clip (taper clip /? en ligne de commande) qui permet d'écrire dans le presse-papier, mais pas d'y lire autrement que par Coller dans un programme (sauf dans Notepad: bug).

je crois que quand on clique droit dans l'editeur de texte que lutcho a fait y'a la fonction mais je ne suis pas sur
Sinon pas bete le logiciel ^^

Oui avec le clique droit sa marche mais sa enrichie quand même le menu et sa peu être intéressant pour d'autre chose...Donc je vote également pour rajouter cette commande si sa ne demande pas trop de temps...

ba ouais c'est oujours meiux d'avoir des nouvelles fonctions ^^

Oui et puis apparemment sa peu être utile pour d'autre chose que je n'est pas très bien compris donc si sa peu également être utile autre que pour enrichir certaine fonction de menu c'est encore mieux.