Editeur de polices avec typographie

' -----------------------------------------------------------
' Editeur de polices avec typographie par MiNiBuG - Aout 2019
' -----------------------------------------------------------

DIM no% : no%=1 : ' Numérotation des objets
DIM n%          : ' variable generique
DIM n$          : ' variable generique

DIM nb%        : ' Nombre de polices dans la liste

DIM DL%        : ' Numero du DLIST
DIM CT%        : ' Numero du CONTAINER
DIM SB%        : ' Numero du SCROLL_BAR
DIM AL%(20)    : ' Numeros des lignes d'ALPHA formant la liste
DIM PL%        : ' Numero de l'ALPHA police
DIM MM%        : ' Numero du MEMO

LABEL dep_liste , select_liste


DLIST no% : FONT_NAMES_LOAD no% : nb%=COUNT(no%) : DL%=no% : no%=no%+1

CONTAINER no% : PARENT no%,0 : LEFT no%,5 : TOP no%,5 : WIDTH no%,300 : HEIGHT no%,395
  COLOR no%,255,255,255 : CAPTION no%," LISTE DES POLICES " : CT%=no% : no%=no%+1
 
  SCROLL_BAR no% : VERTICAL no% : PARENT no%,CT% : LEFT no%,278 : TOP no%,10 : HEIGHT no%,380
      MIN no%,1 : MAX no%,nb%-19 : ON_CHANGE no%,dep_liste : SB%=no% : no%=no%+1

FOR n%=1 TO 20
  n$=ITEM_READ$(DL%,n%)
  ALPHA no% : PARENT no%,CT% :  LEFT no%,5 : TOP no%,n%*19-4 : WIDTH no%,280 : HEIGHT no%,10
      COLOR no%,255,255,255 : FONT_SIZE no%,11 : FONT_NAME no%,n$ : CAPTION no%,n$
      ON_CLICK no%,select_liste : AL%(n%)=no% : no%=no%+1
NEXT n%

ALPHA no% : PARENT no%,0 : LEFT no%,310 : TOP no%,5 : FONT_SIZE no%,10 : PL%=no% : no%=no%+1

MEMO no% : PARENT no%,0 : LEFT no%,310 : TOP no%,25 : WIDTH no%,270 : HEIGHT no%,375
  FONT_SIZE no%,11
  ITEM_ADD no%,"abcdefghijklmnopqrstuvwxyz" : ITEM_ADD no%,"ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  ITEM_ADD no%,"1234567890" : ITEM_ADD no%,""
  ITEM_ADD no%,"Servez à ce monsieur, le vieux petit juge blond assis au fond, une bière hollandaise et des kiwis, parce qu'il y tient."
  MM%=no% : no%=no%+1

ALPHA no% : PARENT no%,0 : LEFT no%,27 : TOP no%,410 : FONT_SIZE no%,12 : FONT_BOLD no%
  FONT_NAME no%,"Arial Black" : CAPTION no%,"Editeur de polices avec typographie par MiNiBuG - Aout 2019"

END

dep_liste:
  FOR n%=1 TO 20
  n$=ITEM_READ$(DL%,POSITION(SB%)+n%-1)
      FONT_BOLD_OFF AL%(n%) : FONT_COLOR AL%(n%),0,0,0 : FONT_NAME AL%(n%),n$ : CAPTION AL%(n%),n$
  NEXT n%
RETURN

select_liste:
  FOR n%=1 TO 20 : FONT_BOLD_OFF AL%(n%) : FONT_COLOR AL%(n%),0,0,0 : NEXT n%
  n%=NUMBER_CLICK : FONT_BOLD n% : FONT_COLOR n%,0,0,255 : FONT_NAME MM%,CAPTION$(n%)
  CAPTION PL%,"Police : "+ CAPTION$(n%)
RETURN