Fermer un programme externe à PANORAMIC

rem ============================================================================
rem            Fermer un programme externe à PANORAMIC
rem ============================================================================
rem Pour fermer un programme, il suffit d envoyer le message WM_CLOSE à sa
rem fenêtre principale.
rem Tout d abord, on détermine le handle de la fenêtre du programme qu on désire
rem fermer.
rem Pour cela, on dispose de la fonction HANDLE_FORM() de Panoramic à laquelle
rem on transmettra le titre de la fenêtre en question.
rem Ensuite on envoie le message WM_CLOSE
rem ============================================================================
rem Comme exemple, on va tester notre SUB sur la calculatrice(calc.exe) puis sur
rem Notepad++.
rem (Vous pouvez bien sûr choisir un autre programme)
rem Lancez une instance de la calculatrice (calc.exe)
rem Observez que la barre de titre de la fenêtre est "calculatrice".
rem C est ce texte qu on va transmettre à la fonction HANDLE_FORM() pour
rem déterminer le handle de la fenêtre.
rem Si la fenêtre est trouvée (son handle est <> 0), on lui envoie le message
rem WM_CLOSE qui est tout simplement un code : 10 en hexa
rem La fenêtre de l application sera fermée
rem ============================================================================
rem Pour info :
rem On a utilisé la fonction "PosteMessageA" qui est asynchrone.
rem Son rôle est simplement de placer le message dans la queue des messages à
rem traiter et retourne immédiatement.
rem Elle ne se préoccupe donc pas de savoir si le message a été correctement traité.
rem ============================================================================
Close_Form("Calculatrice")
Close_Form("new 1 - Notepad++")
end
rem ============================================================================
SUB Close_Form(titre$)
    dim_local hWnd,WM_CLOSE,ret%
    WM_CLOSE = hex("10")
    dll_on "user32"
    hWnd = handle_form(titre$)
    if hWnd <> 0
       ret% = dll_call4("PostMessageA",hWnd,WM_CLOSE,0,0)
       if ret% = 1
          message "La fenêtre de : " + titre$ + " a été fermée"
       else
          message "ERREUR dans la fonction !!!"
       end_if
    else
       message "Impossible de trouver la fenêtre !"
    end_if
    dll_off
END_SUB
rem ============================================================================

EXECUTE_WAIT "cmd.exe /c taskkill.exe /F /IM Prog.exe /T"

tasklist.exe

rem ============================================================================
rem        "Tuer" Panoramic.exe
rem ============================================================================
rem Il arrive parfois que PANORAMIC.EXE plante pour une raison ou une autre.
rem La SUB Kill_Panoramic_exe() permet de "tuer" toute instance de PANORAMIC.exe
rem REMARQUE :
rem Pour "tuer" un .exe quelconque, il suffit de préciser son nom au lieu de
rem 'Panoramic.exe'
rem Vous pouvez paramétrer la SUB pour cela.
rem ============================================================================
hide 0
Kill_Panoramic_exe()
terminate : end
rem ============================================================================
SUB Kill_Panoramic_exe()
    dim_local scr$,q$
    scr$ = "C:\TEMP\killpano.vbs"
    q$ = chr$(34)
    FILE_OPEN_WRITE 9999,scr$
    FILE_WRITELN 9999,"strComputer = " + q$ +"." +q$
    FILE_WRITELN 9999,"strProcessKill = " + q$ + "'Panoramic.exe'" + q$
    FILE_WRITELN 9999,"Set objWMIService = GetObject(" + q$ + "winmgmts:"+ q$ + " _"
    FILE_WRITELN 9999,"& " + q$ + "{impersonationLevel=impersonate}!\\" + q$ + " & strComputer & " + q$ + "\root\cimv2" + q$ + ")"
    FILE_WRITELN 9999,"Set colProcessList = objWMIService.ExecQuery _"
    FILE_WRITELN 9999,"(" + q$ + "Select * from Win32_Process Where Name = " + q$ + " & strProcessKill )"
    FILE_WRITELN 9999,"For Each objProcess in colProcessList"
    FILE_WRITELN 9999,"objProcess.Terminate()"
    FILE_WRITELN 9999,"Next"
    FILE_WRITELN 9999,"WSCript.Echo " + q$ + "Just killed process " + q$ + " & strProcessKill"
    FILE_WRITELN 9999,"WScript.Quit"

    FILE_CLOSE 9999
    EXECUTE_wait scr$
    FILE_DELETE scr$ : ' La suppression du fichier n'aura pas lieu, puisque "Panoramic.exe" est déjà tué avant d'arriver ici!
END_SUB
rem ============================================================================