Mon interface Panoramic

Sujet: Re: Mon interface Panoramic Ven 17 Oct 2014 - 19:23

@ jl35
peux-tu me mettre en exemple comment faire cette manip de message(a$) :j'apprends .
comme jean-claude j'ai clip . version du fichier 6.0.6000.16386 du 2/11/2006.
taille 26Ko
est-ce une bonne version ?
encore 15 mn et je vous dit a demain.

Sujet: Re: Mon interface Panoramic Ven 17 Oct 2014 - 19:26

Salut tout le monde.

@ Ceux chez qui ça n’a pas marché.
Je pense que l’erreur réside dans les chemins de vos répertoires/fichiers.
Il manque des \.
Ajoutez ces \ à la fin des lignes 6 et 8 et ça marchera.

Code:: ' ============================ CHEMINS À PRÉCISER ==============================
Edp$ = "C:\Users\acer\Desktop\Panoramic\PANORAMIC_EDITOR_V0.9.26i2.exe": ' Éditeur
Pan$ = "C:\Users\acer\Desktop\Panoramic\": ' ajouter le \ à la fin
' ==============================================================================
ra$ = Pan$+"Manuel\": ' Ajouter le \ à la fin
fl$ = ra$+"ListeMC.txt": ' liste brute des mots-clés (créé)
fa$ = ra$+"Aide.txt": ' doc des mots-clés (créé)

Vous mettez, bien sûr, vos chemins tout en AJOUTANT LES \

Après cette modification, ça marche chez moi.
Et surtout ce n’est pas une question de CLIP, car CLIP.exe est intégré dans Windows vista, 7, 8.

Edit
@ RMont

RMont a écrit:: peux-tu me mettre en exemple comment faire cette manip de message(a$) :j'apprends .

Chez toi c’est la ligne 31 qui provoque l’erreur.
Donc avant cette ligne 31, modifie la ligne 30 comme ceci pour lire la variable a$

Code:: a$ = CLIPBOARD_STRING_PASTE$: message a$ : stop : i% = INSTR(a$,"/")

Sujet: Re: Mon interface Panoramic Ven 17 Oct 2014 - 23:20

Merci papydall, tu as raison bien sûr, tout vient du fait qu'il manquait le '\' à la fin des noms de répertoires, lignes 6 et 8.
Des rectifications de dernière minute, et comme je ne repassais pas par ces branches-là ça m'a échappé, mille excuses.

Je recommande de prendre la dernière version (rectifiée), page 3, post du 17 à 16h24 (version avec sub sans ResHacker, donc un peu long la 1ère fois).

~~Pour clip, il me semblait bien que ça n'existait pas encore dans Vista ?~~ autant pour moi, il semble bien que si.

@RMont,
Comme t'a dit papydall, pour voir l'état d'une variable à n'importe quel endroit du programme, la commande MESSAGE est bien pratique pendant la mise au point, on peut l'insérer où on veut, le programme affiche la valeur de la variable à cet instant, et attend confirmation pour continuer:
MESSAGE a$ -> affiche le contenu de a$
MESSAGE STR$(v%) -> affiche la valeur de v%
il faut évidemment ensuite ôter cette commande quand on n'en a plus besoin.

Sujet: Re: Mon interface Panoramic Sam 18 Oct 2014 - 1:13

Je vois qu’on a parfois besoin d’un Papy (Papydall Laughing

entre autres, mais un autre Papy peut toujours faire l’affaire!) pour débloquer une certaine situation.

Mais tout le mérite revient à l'auteur du code : Merci PapyJL35 ! Mon interface Panoramic - Page 3 Haha-rire-395

Mon interface Panoramic - Page 3 Haha-rire-395

Sujet: Re: Mon interface Panoramic Sam 18 Oct 2014 - 13:25

Et merci à toi mon papy alter ego pour ta clairvoyance !
Et j'espère bien que si certains se posent encore des questions sur !e sujet (pas des papys, mais des mots-clés) ils n'hésiteront pas à les poser ici !

Sujet: Re: Mon interface Panoramic Sam 18 Oct 2014 - 19:36

Bonsoir a tous !

Ca fonctionne parfaitement chez moi.

Super ! Le programme a pris sa place a coté de panoramic.exe pour l'avoir toujours près de moi.

Bravo et merci a JL35 et aux autres... cheers

Sujet: Re: Mon interface Panoramic Sam 18 Oct 2014 - 20:23

Eh bien, voilà qui fait plaisir ! Merci Minibug pour ton appréciation.

Sujet: Re: Mon interface Panoramic Sam 18 Oct 2014 - 22:31

Intervention supprimée... j'ai eu une fausse bonne idée qui ne marche pas bien !

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 0:01

Persévérant comme tu l’as maintes fois prouvé, ça ne tardera pas à bien marcher ta ~~fausse~~ bonne idée !

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 11:50

Bon, puisque tu me le demandes avec insistance papydall ( Very Happy

), ma fausse ~~bonne~~ idée était celle-ci (en liaison avec le programme ci-dessus):
Dans le cas de régénération complète de l'aide, qui dure entre 15 et 20s, je voulais afficher une espèce de chrono qui tourne, pour faire patienter l'opérateur.
Pour ce faire:
- dans le programme principal, appel d'une sub qui lance un exécutable, par exemple chrono.exe, avec comme paramètre un nom de fichier.
- lancement de l'exécution de la mise à jour de la doc
- relancement de la sub: suppression du fichier paramètre.

Le programme exécutable est lancé avec un nom de fichier qui contient les coordonnées d'affichage du chrono animé.
Ca se met à tourner, avec surveillance permanente de présence du fichier: dès qu'il n'existe plus: Terminate.
(ce programme est évidemment écrit en panoramic, et compilé avec Panoramic_Editor.
Donc, en principe, fonctionnement complètement indépendant du programme appelant).

La réalité est moins rose, puisque ça commence à tourner normalement, puis au bout d'un moment le programme principal s'arrête brutalement en plein travail, sans autre forme de procès, il se termine, sans signaler d'erreur.

Il y a manifestement une interférence entre le programme chrono et le programme appelant, mais je ne vois pas pourquoi et je n'y comprends rien scratch

Question: est-ce que deux exécutables, compilés en panoramic, peuvent tourner simultanément indépendamment l'un de l'autre ou bien est-ce qu'ils font appel à des ressources communes ?

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 16:33

Bon, à la demande générale de papydall, voici ma solution, qui marche chez moi (j'avais un problème de passage de paramètre entre les deux programmes, j'ai contourné en passant par le clipboard...)

1) Il faut donc un petit exécutable indépendant: Chronos.exe, qui va tourner parallèlement à l'extraction de la liste en affichant une aiguille tournante pour faire patienter (17 secondes chez moi), donc source ci-dessous à compiler en Chronos.exe:

Code:: ' Exécutable d'affichage d'un chrono rotatif sur l'écran
' Paramètre dans le clipboard: fichier contenant les coordonnées d'affichage.
' Arrêt quand le fichier donné en paramètre n'existe plus
DIM ft$,a$,x%,y%,i%
ft$ = CLIPBOARD_STRING_PASTE$
FILE_OPEN_READ 1,ft$
   FILE_READLN 1,a$: x% = VAL(a$)
   FILE_READLN 1,a$: y% = VAL(a$)
FILE_CLOSE 1
WIDTH 0,120: HEIGHT 0,80: TOP 0,y%: LEFT 0,x%: BORDER_HIDE 0
COLOR 0,255,255,0
FONT_NAME 0,"Wingdings 2": FONT_SIZE 0,64: FONT_BOLD 0: FONT_COLOR 0,128,0,0
i% = 135
WHILE FILE_EXISTS(ft$) = 1
   PRINT_LOCATE 28,0: PRINT CHR$(i%)
   i%=i%+1: IF i% > 146 THEN i% = 135
   WAIT 200
END_WHILE
TERMINATE

2) Je redonne en entier le programme principal, avec la nouvelle sub Chronos() à la fin, et l'appel à cette sub de chaque côté de l'appel à la sub MotsClesPano (reconstitution de la liste des mots-clés).
Donc penser à remettre à jour les chemins en tête, et vérifier les chemins dans la nouvelle sub (chemin de l'exécutable)

Code:: ' ********** Création et consultation des fichiers d'aide par mot-clé **********
LABEL Afm, afm1, Perso
DIM Edp$,Pan$,ra$, fl$, fa$, fp$, i%, k%, a$, b$,q$,fct$(10)
' ============================ CHEMINS À PRÉCISER ==============================
Edp$ = "C:\Program Files (x86)\Panoramic Editor\PANORAMIC_EDITOR.exe": ' Éditeur
Pan$ = "C:\PANORAMIC\": ' Répertoire des sources Panoramic <********************
' ==============================================================================
ra$ = Pan$+"Manuel\": ' Répertoire de la documentation Panoramic (créé) <=======
fl$ = ra$+"ListeMC.txt": ' liste brute des mots-clés (créé)
fa$ = ra$+"Aide.txt": ' doc des mots-clés (créé)
DATA "","","DÉFINITION","FONCTION","SYNTAXE","USAGE","CAS D'ERREUR"
DATA "EXEMPLES","EN RAPPORT"
FOR i% = 1 TO 9: READ fct$(i%): NEXT i%
q$ = CHR$(34)

WIDTH 0,800: HEIGHT 0,SCREEN_Y-50: BORDER_SMALL 0
LIST 1: WIDTH 1,200: HEIGHT 1,HEIGHT(0)-35: FONT_NAME 1,"Consolas"
COLOR 1,200,255,200: ON_CLICK 1,Afm: font_size 1,10
MEMO 2: TOP 2,23: LEFT 2,WIDTH(1): WIDTH 2,WIDTH(0)-WIDTH(1)-16: HEIGHT 2,HEIGHT(1)-23
COLOR 2,255,255,200: FONT_NAME 2,"Consolas": FONT_SIZE 2,11
BAR_VERTICAL 2
MEMO 3: HIDE 3
BUTTON 4: TOP 4,HEIGHT(0)-60: LEFT 4,WIDTH(0)-120: CAPTION 4,"Ajouter"
ON_CLICK 4,Perso
ALPHA 5: TOP 5,0: LEFT 5,LEFT(2): HEIGHT 5,23: FONT_NAME 5,"Consolas": FONT_SIZE 5,14
FONT_BOLD 5
IF DIR_EXISTS(ra$) = 0 THEN DIR_MAKE ra$
EXECUTE_WAIT "CMD.exe /C DIR "+q$+Edp$+q$+" /TC | clip"
a$ = CLIPBOARD_STRING_PASTE$: i% = INSTR(a$,"/")
i% = VAL(MID$(a$,i%+4,4)+MID$(a$,i%+1,2)+MID$(a$,i%-2,2)): ' date Editeur actuel
b$ = "0"
IF FILE_EXISTS(fa$) = 1
   FILE_OPEN_READ 1,fa$: FILE_READLN 1,b$: FILE_CLOSE 1
   IF LEN(b$) >= 8
   b$ = LEFT$(b$,8): ' date de la dernière mise à jour (forme: aaaammjj)
   ELSE
   b$ = "0"
   END_IF
END_IF
IF VAL(b$) < i%
   ITEM_ADD 1,"Reconstitution de la liste"
   Chronos(1,40,50): ' affichage d'un chrono circulaire
   MotsClesPano(Edp$,fl$,fa$): ' Création initiale, ou mise à jour de la doc
   Chronos(0): ' fin chrono
END_IF
FILE_LOAD 3,fl$
CLEAR 1: FOR i% = 1 TO COUNT(3): ITEM_ADD 1,ITEM_READ$(3,i%): NEXT i%
SORT 1
a$ = "#INCLUDE "+q$+"F"+q$: GOSUB afm1
END
' ==============================================================================
Afm:
a$ = ITEM_INDEX$(1)
afm1:
FILE_OPEN_READ 1,fa$
FILE_READLN 1,b$: WHILE MID$(b$,4,50)<>a$: FILE_READLN 1,b$: END_WHILE
a$ = TRIM$(MID$(b$,4,50)): i% = WIDTH(2)/TEXT_WIDTH(" ",5): ' nb car
CAPTION 5, STRING$(INT((i%-LEN(a$))/2)," ")+a$
FILE_READLN 1,b$
CLEAR 2
WHILE LEFT$(b$,3)<>"1_ " AND FILE_EOF(1)=0
   IF MID$(b$,2,2) = "_ "
   i% = VAL(LEFT$(b$,1)): ITEM_ADD 2,""
   IF i%>2 THEN ITEM_ADD 2,"==================== "+fct$(i%)+" ===================="
   b$ = MID$(b$,4,200)
   END_IF
   ITEM_ADD 2,b$
   FILE_READLN 1,b$
END_WHILE
FILE_CLOSE 1
fp$ = ra$+a$+".txu"
IF FILE_EXISTS(fp$) = 1: ' fichier de commentaire perso pour ce mot-clé
   ITEM_ADD 2,""
   ITEM_ADD 2,"*=*=*=*=*=*=*=*=*=*=*=* PERSO *=*=*=*=*=*=*=*=*=*=*=*"
   FILE_OPEN_READ 1,fp$
   WHILE FILE_EOF(1) = 0
   FILE_READLN 1,b$: ITEM_ADD 2,b$
   END_WHILE
   FILE_CLOSE 1
END_IF
RETURN
' ==============================================================================
Perso:
' commentaires perso
a$="Notepad.exe "+q$+fp$+q$
EXECUTE_WAIT "CMD.exe /C "+a$
RETURN
' ==============================================================================
SUB MotsClesPano(Edp$,fl$,fa$)
' Extraction depuis Edp$ (Panoramic_Editor.exe) de la documentation des mots-clés
' Panoramic.
' Résultats dans:
' - fl$: liste brute des mots-clés
' - fa$: documentation complète, par mot-clé
DIM_LOCAL rm$,sd$,sf$,p%,fz$,a$,sz%,k%,k1%,nmc%,dl%
rm$ = FILE_EXTRACT_PATH$(fl$): ' répertoire de travail provisoire
fz$ = rm$+"ppp.txt": ' fichier provisoire de travail (créé puis supprimé)
sd$ = "300D0A23494E434C554445": ' séquence début de recherche = 0<=#INCLUDE
sf$ = "0D0A460D0A46": ' séquence fin de recherche = <=F<=F
p% = 0: ' recherche à partir du début de l'Éditeur
FILEBIN_OPEN_READ 8,Edp$: FILEBIN_OPEN_WRITE 9,fz$: sz% = FILEBIN_SIZE(8)
FILEBIN_POSITION 8,p%
FILEBIN_HEXA_READ 8,2000,a$: k% = INSTR(a$,sd$)
WHILE k% < 1
   IF FILEBIN_POS(8) >= sz%
   CLIPBOARD_STRING_COPY STRING$(16,"0"): ' séquence début non trouvée
   FILEBIN_CLOSE 8: FILEBIN_CLOSE 9: EXIT_SUB
   END_IF
   p% = p%+2000-LEN(sd$): FILEBIN_POSITION 8,p%
   FILEBIN_HEXA_READ 8,2000,a$: k% = INSTR(a$,sd$)
END_WHILE
k1% = INSTR_POS(a$,sf$,k%)
IF k1% > 0
   a$ = MID$(a$,k%,k1%+LEN(sf$)-k%)
   FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$)
ELSE
   a$ = RIGHT_POS$(a$,k%): k% = 0
   WHILE k% < 1
   FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$
   p% = p%+2000-LEN(sf$)
   FILEBIN_HEXA_READ 8,2000,a$: k%=INSTR(a$,sf$)
   END_WHILE
   a$ = LEFT$(a$,k%-1)+sf$
   FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$
END_IF
FILEBIN_CLOSE 8: FILEBIN_CLOSE 9
print time$+" fin extr"
FILE_OPEN_READ 8, fz$: FILE_OPEN_WRITE 9,fa$: FILE_OPEN_WRITE 6,fl$
EXECUTE_WAIT "CMD.exe /C DIR "+CHR$(34)+Edp$+CHR$(34)+" /TC | clip"
a$ = CLIPBOARD_STRING_PASTE$: k% = INSTR(a$,"/")
a$ = MID$(a$,k%+4,4)+MID$(a$,k%+1,2)+MID$(a$,k%-2,2)
FILE_WRITELN 9,a$+" * date de Panoramic_Editor": ' archivage de la date Éditeur
FILE_READLN 8,a$: nmc% = 0
WHILE FILE_EOF(8) = 0
   FILE_READLN 8,a$
   IF LEN(a$) = 1 AND NUMERIC(a$) = 1
   WHILE a$<>"1": FILE_READLN 8,a$: END_WHILE: FILE_WRITELN 9,"": ' saut de ligne
   FILE_READLN 8,a$: FILE_WRITELN 9,"1_ "+a$: nmc%=nmc%+1: ' MOT-CLÉ COMPLET
   IF LEFT$(a$,1) = "("
   IF INSTR(a$,"STEP") > 0
   a$ = "STEP"
   ELSE
   a$ = "TO"
   END_IF
   END_IF
   FILE_WRITELN 6,a$
   WHILE a$<>"2": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"2_ "+a$: ' RÉSUMÉ
   WHILE a$<>"3": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"3_ "+a$: ' DÉFINITION
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"4": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"4_ "+a$: ' FONCTION
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"5": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"5_ "+a$: ' SYNTAXE
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"6": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"6_ "+a$: ' USAGE
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"7": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"7_ "+a$: ' CAS D'ERREUR
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"8": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"8_ "+a$: ' EXEMPLES
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   WHILE a$<>"9": FILE_READLN 8,a$: END_WHILE
   FILE_READLN 8,a$: FILE_WRITELN 9,"9_ "+a$: ' EN RAPPORT
   FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
   END_IF
END_WHILE
FILE_CLOSE 8: FILE_CLOSE 9: FILE_CLOSE 6
FILE_DELETE fz$
dl%=1000: WHILE OBJECT_EXISTS(dl%)=1: dl%=dl%+1: END_WHILE
DLIST dl%: FILE_LOAD dl%,fl$: SORT dl%: FILE_SAVE dl%,fl$: DELETE dl%
END_SUB
' ==============================================================================
SUB Chronos(fct%,x%,y%)
' Affichage d'un chrono à aiguille tournante en x%,y% de l'écran
' fct%=1: lancement, fct%=0: arrêt
DIM_LOCAL Chron$, fpa$
Chron$ = Pan$+"Chronos.exe": ' affichage d'un chrono circulaire
fpa$ = Pan$+"Fminut.txt": ' fichier paramètres pour Chronos.exe
IF FILE_EXISTS(Chron$) = 0 THEN EXIT_SUB
IF fct% = 1
   FILE_OPEN_WRITE 1,fpa$
   FILE_WRITELN 1,STR$(x%): FILE_WRITELN 1,STR$(y%)
   FILE_CLOSE 1
   CLIPBOARD_STRING_COPY fpa$
   EXECUTE Chron$: ' programme d'affichage du chrono
ELSE
   FILE_DELETE fpa$: ' arrêt du chrono
END_IF
END_SUB
' ==============================================================================

Il me semble que j'avais déjà donné quelque chose de semblable, avec affichage d'un minuteur avec décompte des secondes, mais je trouve celui-ci plus original...

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 17:18

Désolé mais chez moi pas de chrono a l'écran.

- J'ai bien créer le premier programme en Chronos.exe
- Puis ajout des lignes dans après la condition : IF VAL(b$) < i%
- Et enfin ajout de la sub en fin de programme.
- Sauvegarde de l'ensemble en .exe et suppression du dossier Manuel

Pas d'erreur a l'exécution.
il y a bien un fichier Fminut.txt qui est créé durant l'exécution mais c'est tout.
Le fichier se supprime bien a la fin et les infos apparaissent.

Mais malheureusement pas de chrono en vu !

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 17:35

Bizarre... tu as bien vérifié les chemins, et que Chronos.exe est bien à l'emplacement donné dans la sub ? Tout se passe comme si le programme Chronos.exe n'était pas activé...

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 17:42

Ok ! Ca y est j'ai trouvé ! cheers

Mes chemins sont des noms longs. d'où l'erreur...

maintenant ça marche. Parfait et encore bravo !

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 17:47

Je suis content alors, parce que je pensais à des hypothèses un peu farfelues ! (entre autres que le programme se déroulait peut-être mais caché derrière la fenêtre principale, du coup j'ai ajouté un 'TO_FOREGROUND 0' dans Chronos.exe, mais apparemment ce n'est pas utile).

C'est vrai qu'il faudrait chaque fois mettre les chemins entre guillemets, au cas où...

Tout est bien qui finit bien, tu as vu c'est facile à faire ce petit dessin qui tourne, simplement avec une police de caractères adéquate...

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 18:03

Bon, cette fois, çà marche.

Mais il ne faut pas oublier de terminer le chemin de Pan$ en ligne 6 par \ .

Chez moi c'est huit secondes.

A+

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 18:08

Bon sang tu as raison Jean Claude, ces maudits anti-slash qui disparaissent, et bien sur les lignes 6 ET 8.
(j'ai édité le code que j'ai redonné ci-dessus).
Je les ai bien dans mon source, je ne comprends pas pourquoi ils ont sauté...

Et 8 secondes, mazette, tu as une bécane de course ! (ou moi une vraie brouette).

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 18:15

Bécane de course, pas tant que çà. C'est un processeur I3-4130 3,4 Ghz avec 4Go de RAM, il y a mieux (I5 avec 8Go de RAM).

Mais comme je ne fait pas de retouche vidéo, c'est largement suffisant.

A+

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 18:22

Alors c'est moi ! je ne connais pas trop mes caractéristiques, mais quand il m'a fallu changer (forcé) j'ai pris le moins cher que j'ai trouvé, avec seulement 2G de mémoire... mais ça me convient, j'ai le temps d'attendre...

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 20:12

Ca marche mais c'est vrai que j'ai quand même galéré pour mettre au point pano.exe.

D'ailleurs je pense que tu nous a pas encore tout montré... tes secrets sont biens gardés ! Wink

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 22:48

Bien sûr je n'ai pas tout montré, en particulier ~~pano.bas~~ aide.bas, le plus long, j'ai pensé que ça n'intéresserait peut-être pas grand monde, mais ce n'est pas de la mauvaise volonté, loin de là !
D'ailleurs tu vois bien, tu t'es enrichi en faisant ta mise au point toi-même.
Mais je peux montrer tout ce qu'on veut, aucun problème (j'ai d'ailleurs changé quelques bricoles, au fur et à mesure que je mettais des choses ici...)

Sujet: Re: Mon interface Panoramic Dim 19 Oct 2014 - 23:41

Citation :: D'ailleurs tu vois bien, tu t'es enrichi en faisant ta mise au point toi-même.

C'est vrai tu as raison.

Citation :: Bien sûr je n'ai pas tout montré, en particulier aide.bas, le plus long

On attends de voir cela avec impatiente...
Je l'avais bien remarqué dans le menu, il a aussi les SUB qui semblent très intéressantes...
Mais en fait tout est intéressant !! Very Happy

Sujet: Re: Mon interface Panoramic Lun 20 Oct 2014 - 13:45

Avant il faut que je revoie tout ça, il y a eu quelques modifs de principe entretemps (par exemple j'avais un fichier txt par mot-clé, maintenant tout est dans un seul fichier, ce qui est plus simple).
Pour les subs, vaste programme, actuellement j'en suis à une bibliothèque de 171 subs perso, sur des sujets variés, et d'intérêt parfois discutable, sans doute...

Sujet: Re: Mon interface Panoramic Lun 20 Oct 2014 - 19:06

bonjour a tous
ayant toujours des erreurs ,je demande comment vous faites pour les adresses exactes pour les variables des lignes 6 et 7. je pense que je n'ai pas commis d'erreur.
que j'active les lignes 5 ou 6 j'ai une erreur 29.
a quel moment les fichiers ,
ra$ = pan$+"manuel\"
fl$ = ra$+"listeMC.txt"
fa$ = ra$+"aide.txt"
sont_ils crées ?
voici cette erreur

Sujet: Re: Mon interface Panoramic Lun 20 Oct 2014 - 19:17

mon erreur n'est pas passée.
ce soir je n'arrive pas a expédier mon
erreur,mais elle est en ligne 31 . i% = ;;;;;;;;;;;;;;;

» Domotique avec Panoramic : Interface RS232 TTL
» Interface avec Outlook
» extension de l'interface avec les DLL
» extension de l'interface avec les DLL - bis
» Interface de puissance pour la régie lumière 8 canaux.