Perdu dans l'espace

' Elite - based on the '80s BBC Micro game

label action,fin,noseup,nosedown,rollleft,rollright,accel,decel

' number of planets
Dim N%: N%=8
dim j%,ship%,sol%,halo1%,halo2%,s,m,n,o
' angles a,b, t=pitch step & u=roll step (mt & ut for mouse)
dim a,b,t,u,mt,mu
' Space station object indices & variables
dim stn%,shome,stnrot,stnspk1%,stnspk2%,stnring%,stnhub%,stndoor%,hubhit%,doorhit%
' Alien indices & vars
dim aliendisc%,alienbridge%,ala,alaxis
' constants
dim pi : pi=3.14159264
' Arrays for planets' positions x,y,z, orbital radius r
dim x(N%+2),y(N%+2),z(N%+2),r(N%+2)
' Ship's variables: position,speed,speed increment,rotations
dim sx,sy,sz,sp,boost,xrot,yrot,zrot

sp=0:boost=0.001:stnrot=0:xrot=0:yrot=0:zrot=0
doorhit%=0:hubhit%=0 : ' docking/crash detection
t=0.5 : ' pitch increment
u=1 : ' roll increment

 full_space 0
' height 0,570
' width 0,870

scene3d 1:full_space 1
cursor_cross 1
' Sun is light source, at origin, therefore,
light_position 0,0,0
' It's in space!
color 1,0,0,0

3d_skybox 2
' 3d_load_texture_bottom 2,"Bitmaps\stars.bmp"
' 3d_load_texture_top 2,"Bitmaps\stars.bmp"
' 3d_load_texture_left 2,"Bitmaps\stars.bmp"
' 3d_load_texture_right 2,"Bitmaps\stars.bmp"
' 3d_load_texture_front 2,"Bitmaps\stars.bmp"
' 3d_load_texture_back 2,"Bitmaps\stars.bmp"

' Planets created first to keep array index (j%) low without offset. Further object indices will be relative to end of array.
for j%=3 to N%+2 : ' 3 because of frame(0), scene3d(1), skybox(2); N%+2 as arrays start at zero.
   a = rnd(pi*1000)/500 : ' Full circle in radians
   r(j%)=rnd(100000)+5000 : ' solar systems are BIG!
   x(j%)=r(j%)*cos(a) : ' Circular coordinate
   y(j%)=(rnd(2000)-1000)/20 : ' A random offset from plane
   z(j%)=r(j%)*sin(a) : ' Circular coordinate
   s = power(r(j%),1.3)/10000 : ' size of planet
   caption 0,s : ' just to check
   3d_sphere j%,s
   3d_position j%,x(j%),y(j%),z(j%)
   3d_color j%,rnd(40),rnd(40),rnd(40)
   ' special home planet first:
   if j%=3
'      3d_load_texture j%,"Bitmaps\planet.bmp"
      shome=s*2 : ' radius of station rel. to size of planet (smaller=easier to find)
      3d_sphere j%+100,s*1.03 : ' safe index offset for (& may have others with) atmosphere
      3d_position j%+100,x(j%),y(j%),z(j%)
      3d_color j%+100,20,20,155
      3d_transparent j%+100,180
    end_if
next j%

' Sun
sol%=j%+1
3d_sphere sol%,800
3d_color sol%,255,245,50

halo1%=sol%+1
3d_sphere halo1%,900
3d_color halo1%,255,210,140
3d_transparent halo1%,190

halo2%=sol%+2
3d_sphere halo2%,1500
3d_color halo2%,255,55,140
3d_transparent halo2%,240

' Initialise spaceship coordinates near space station (for now)
sx=x(3)+shome+rnd(100)-50:sy=y(3)+shome+rnd(100)-50:sz=z(3)+shome+rnd(100)-50

ship%=sol%+3 : ' required for collision detection
3d_box ship%,0.8,0.2,0.8 : ' wide,thick,long
3d_position ship%,sx,sy,sz
' Pointing box at 0,0,0 (object sol%) so that camera is lined up with its Z.
3d_point_object ship%,sol%
' 3d_load_texture ship%,"Bitmaps\flare.bmp"
3d_color ship%,255,0,0

' Several concentric parts of the station follow:
stn%=sol%+4
3d_dodecahedron stn%
3d_scale stn%,3,3,3
' 3d_color stn%,55,55,40
3d_position stn%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stn%,3

' Spokes
stnspk1%=sol%+5
3d_box stnspk1%,0.8,20,0.1
' 3d_color stnspk1%,255,255,240
' 3d_color stnspk1%,100,100,50
' 3d_load_texture stnspk1%,"Bitmaps\mcheck4.bmp"
3d_position stnspk1%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnspk1%,3

stnspk2%=sol%+6
3d_box stnspk2%,20,0.8,0.1
' 3d_color stnspk1%,255,255,240
' 3d_color stnspk2%,100,100,50
' 3d_load_texture stnspk1%,"Bitmaps\mcheck4.bmp"
3d_position stnspk2%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnspk2%,3

' Ring
stnring%=sol%+7
3d_torus stnring%,10,0.5
3d_position stnring%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnring%,3

' Cylinder hub
stnhub%=sol%+8
3d_cylinder stnhub%,3,1.3,1.3
3d_position stnhub%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnhub%,3
3d_x_rotate stnhub%,90

' Box to give illusion of door (bug?: color 0,0,0 does not cover all sides)
stndoor%=sol%+9
3d_box stndoor%,0.3,1.3,3.01 : ' height,width,>cylinderlength
3d_position stndoor%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stndoor%,3
3d_color stndoor%,100,100,1
3d_transparent stndoor%,80

' Alien flying saucer
aliendisc%=sol%+10
alienbridge%=sol%+11
3d_sphere aliendisc%,1
3d_sphere alienbridge%,0.25
3d_y_scale aliendisc%,0.06
3d_y_scale alienbridge%,0.6
' Init at space station for now
3d_position aliendisc%,x(3)+shome,y(3)+shome,z(3)+shome
3d_position alienbridge%,x(3)+shome,y(3)+shome,z(3)+shome
3d_color aliendisc%,20,60,50
3d_color alienbridge%,10,40,70

' Initialize objects for collision
3d_collision_as_faces ship% : ' Idea is to rotate ship so that its wide shape fits in door!
3d_collision_as_faces stnhub% : ' Also need all other parts added
3d_collision_as_faces stndoor% : ' The good one to hit

' Point the alien at us
3d_point_object aliendisc%,ship%:3d_point_object alienbridge%,ship%

' View from inside space ship; we will move/rotate both together
cam_position sx,sy,sz

' MAIN LOOP (Timer)
' -=-=-=-=-=-=-=-=-=-=-
' on_close 0,fin
timer 99
timer_interval 99,10
on_timer 99,action

' === This steps back so you can see the ship for testing
' cam_move -1.5
' =================

end

' =====================

action:
   timer_off 99 : ' Not to trigger repeat in loop.
   select scancode
      case 38:gosub nosedown: ' up key (some may prefer opposite)
      case 40:gosub noseup: ' down key
      case 37:gosub rollleft: ' left key
      case 39:gosub rollright: ' right key
      case 81:boost=0.1: ' Q - fast acceleration & decel.
      case 65:boost=0.01: ' A - medium
      case 90:boost=0.001: ' Z - fine
      case 160:gosub accel: ' left shift
      case 162:gosub decel: ' left control
      case 32:sp=0: ' SPACE, dead stop (temporary cheat!)
      case 27:goto fin: ' ESCAPE (Why the warning beep from system?)
   end_select
   ' Rotate ship & cam on mouse position
   mt=2*(mouse_y_position(1)-height(1)/2)/height(1)
   mu=2*(mouse_x_position(1)-width(1)/2)/width(1)
   xrot=xrot-mt
   yrot=yrot-mu
   3d_x_rotate ship%,xrot : ' Object rotations are absolute
   3d_y_rotate ship%,yrot
   cam_pitch -1*mt        : ' Camera rotations are relative
   cam_turn mu
'   caption 0,"Pitch: "+str$(mt)+"   -   Yaw: "+str$(mu)

   ' Continually rotate space station
   3d_z_rotate stn%,stnrot
   3d_z_rotate stnspk1%,stnrot
   3d_z_rotate stnspk2%,stnrot
   3d_z_rotate stnring%,stnrot
   3d_z_rotate stndoor%,stnrot
   stnrot=wrap_value(stnrot+0.5): ' Is this necessary?
  
  ' Move ship & cam according to current speed
   cam_move sp
   3d_move ship%,sp

   ' MOVE ALIEN (choose random angle & axis)
   ala=ala+(rnd(200)-93)/1000 : ' odd calc due to bias in random if use rnd(2)-1, tweak neg number for stable direction
   alaxis=rnd(2) : ' Just choose an axis to rotate round at random
   select alaxis
      case 0 : 3d_x_rotate aliendisc%,ala:3d_x_rotate alienbridge%,ala
      case 1 : 3d_y_rotate aliendisc%,ala:3d_y_rotate alienbridge%,ala
      case 2 : 3d_z_rotate aliendisc%,ala:3d_z_rotate alienbridge%,ala
   end_select
   3d_move aliendisc%,0.05:3d_move alienbridge%,0.05

   ' TESTS
   ' Docking or collision with space station?  (Not perfect, but works, need other objects tested too)
   if o3d_collision(ship%,stndoor%)=1 then doorhit%=1
   if o3d_collision(ship%,stnhub%)=1 then hubhit%=1
   if hubhit%=1 : ' Can't avoid hitting hub, but...
      if doorhit%=0 then message "Crashed!":return : ' ...Missed door.
      if doorhit%=1 then message "Successfully docked!":return : ' ...hit door.
   end_if
   display
   timer_on 99
return


noseup:
   cam_pitch t
   xrot=xrot+t
   3d_x_rotate ship%,xrot
return

nosedown:
   cam_pitch -1*t
   xrot=xrot-t
   3d_x_rotate ship%,xrot
return

rollleft:
   cam_roll u
   zrot=zrot-u
   3d_z_rotate ship%,zrot
return

rollright:
   cam_roll -1*u
   zrot=zrot+u
   3d_z_rotate ship%,zrot
return

accel:
   sp=sp+boost
   caption 0,sp
return

decel:
   sp=sp-boost
   caption 0,sp
return

fin:
   terminate
'  ^^^^^^^^^

' * key ESC ==> terminate PROGRAM
' Touches arrowed to manage the objects 3d_cube and the camera
' ********************************************************************
' rot=angle which is the invisible cube of the engine 3d, is 3d_y_rotate mv,rot
' Chy=Y position of the camera, or cam_y_position or chy
' phy=Y position of the point aimed by the camera, or point_y_position or phy
' vrot=Rotation speed when we revolve to the left or to the right (arrows left or right)
' vd=Speed of travel(movement) when we move forward, moves(puts) back, goes right or to the left
' mv=number object of engine 3d =================> 1000 (3d_cube 1000,1)
' pv=number object of point aimed by the camera => 1001 (3d_cube 1001,1) (in your program, the ship ?)

dim rot,chy,phy,vrot,vd,mv,pv
rot=180:chy=1.5:phy=1.5:vrot=1:vd=0.2

label move

full_space 0:scene3d 1:full_space 1:color 1,0,0,255

3d_plane number_3d_objects+1:3d_x_rotate number_3d_objects,90
3d_color number_3d_objects,0,255,0:3d_scale number_3d_objects,100,100,1

3d_cone number_3d_objects+1,10,3:3d_color number_3d_objects,255,255,0

3d_cube 1000,1:' Driving vehicle (camera)
3d_y_rotate 1000,rot
3d_move 1000,-13:' you can use point_position
3d_hide 1000:' invisible
mv=1000

3d_cube 1001,1:' Driving vehicle (point_position)
' 3d_hide 1001: ' The object must be hidden in normal use
pv=1001

timer 200:timer_interval 200,1:on_timer 200,move
end

move:
timer_off 200
select scancode
   case 27:terminate
   case 37:rot=rot+vrot:3d_y_rotate mv,rot
   case 39:rot=rot-vrot:3d_y_rotate mv,rot
   case 38:3d_move mv,vd
   case 40:3d_move mv,vd-(2*vd)
'   case 65:3d_z_rotate mv,o3d_z_rotate(mv)-1
'   case 90:3d_z_rotate mv,o3d_z_rotate(mv)+1
end_select
' case 65 and case 90 need more complex calculations

3d_position pv,o3d_x_position(mv),o3d_y_position(mv),o3d_z_position(mv)
3d_rotate pv,o3d_x_rotate(mv),o3d_y_rotate(mv),o3d_z_rotate(mv)
3d_move pv,1
cam_position o3d_x_position(mv),chy,o3d_z_position(mv)
point_position o3d_x_position(pv),phy,o3d_z_position(pv)

timer_on 200
return

dim rep$:rep$="C:\jeubasic\3d\travail\":dir_change rep$: ' <=== to change, to adapt "rep$"
dim vrot:vrot=1
full_space 0:scene3d 1:full_space 1:color 1,0,0,0
cam_position 10,10,10:light_position 10,10,10

' 3d_skybox 1
' 3d_load_texture_top 1,"texture3.bmp"
' 3d_load_texture_left 1,"texture3.bmp"
' 3d_load_texture_back 1,"texture3.bmp"
' 3d_load_texture_front 1,"texture3.bmp"
' 3d_load_texture_right 1,"texture3.bmp"
' 3d_load_texture_bottom 1,"texture3.bmp"

3d_box 2,10000000,1,10000000:3d_position 2,1,-5000000,1:3d_color 2,250,000,000:' 3d_load_texture 2,"texture3.bmp":' 3d_hide 2
3d_box 3,10000000,10000000,1:3d_position 3,1,1,05000000:3d_color 3,000,250,000:' 3d_load_texture 3,"texture3.bmp":' 3d_hide 3
3d_box 4,10000000,10000000,1:3d_position 4,1,1,-5000000:3d_color 4,000,000,250:' 3d_load_texture 4,"texture3.bmp":' 3d_hide 4
3d_box 5,10000000,1,10000000:3d_position 5,1,05000000,1:3d_color 5,250,250,000:' 3d_load_texture 5,"texture3.bmp":' 3d_hide 5
3d_box 6,1,10000000,10000000:3d_position 6,-5000000,1,1:3d_color 6,250,000,250:' 3d_load_texture 6,"texture3.bmp":' 3d_hide 6
3d_box 7,1,10000000,10000000:3d_position 7,05000000,1,1:3d_color 7,000,250,250:' 3d_load_texture 7,"texture3.bmp":' 3d_hide 7

axes_show

' 3d_mesh 8:3d_load_object 8,"VAISSEAU2.3ds":3d_load_texture 8,"texture1.bmp":3d_position 8,1,1,1
3d_cube 8,6:3d_scale 8,0.1,1,1
3d_cube 9,5:3d_scale 9,1,0.1,1

while scancode <>27
if scancode=37 then cam_turn vrot*-1      :' camera turn to the left ==========> Key "left arrow"
if scancode=39 then cam_turn vrot         :' camera turn to the right =========> Key "right arrow"
if scancode=38 then cam_move 0.1          :' camera Move forward ==============> Key "up arrow"
if scancode=40 then cam_move -0.1         :' camera Move back =================> Key "down arrow"
if scancode=86 then cam_roll vrot*-1      :' camera roll to the left ==========> Key "V"
if scancode=78 then cam_roll vrot         :' camera roll to the right =========> Key "N"
if scancode=66 then cam_pitch vrot*-1     :' camera looping down ==============> Key "B"
if scancode=72 then cam_pitch vrot        :' camera looping up ================> Key "H"
if scancode=79 then cam_position 10,10,10 :' camera origine ===================> Key "O"
if scancode=65 then point_object 4        :' camera towards -Z  ===============> Key "A"
if scancode=90 then point_object 3        :' camera towards +Z  ===============> Key "Z"
if scancode=84 then point_object 2        :' camera towards -Y  ===============> Key "T"
if scancode=89 then point_object 5        :' camera towards +Y  ===============> Key "Y"
if scancode=87 then point_object 6        :' camera towards -X  ===============> Key "W"
if scancode=88 then point_object 7        :' camera towards +X  ===============> Key "X"
end_while
terminate

dim rep$:rep$="C:\jeubasic\3d\travail\":dir_change rep$: ' <=== to change, to adapt "rep$"
dim d,rx,ry,rz,px,py,pz,vrot:vrot=1:' px=1:py=1:pz=1
full_space 0:scene3d 1:full_space 1:color 1,0,0,0
cam_position 10,10,10:light_position 10,10,10

' 3d_skybox 1
' 3d_load_texture_top 1,"texture3.bmp"
' 3d_load_texture_left 1,"texture3.bmp"
' 3d_load_texture_back 1,"texture3.bmp"
' 3d_load_texture_front 1,"texture3.bmp"
' 3d_load_texture_right 1,"texture3.bmp"
' 3d_load_texture_bottom 1,"texture3.bmp"

3d_box 2,10000000,1,10000000:3d_position 2,1,-5000000,1:3d_color 2,250,000,000:' 3d_load_texture 2,"texture3.bmp":' 3d_hide 2
3d_box 3,10000000,10000000,1:3d_position 3,1,1,05000000:3d_color 3,000,250,000:' 3d_load_texture 3,"texture3.bmp":' 3d_hide 3
3d_box 4,10000000,10000000,1:3d_position 4,1,1,-5000000:3d_color 4,000,000,250:' 3d_load_texture 4,"texture3.bmp":' 3d_hide 4
3d_box 5,10000000,1,10000000:3d_position 5,1,05000000,1:3d_color 5,250,250,000:' 3d_load_texture 5,"texture3.bmp":' 3d_hide 5
3d_box 6,1,10000000,10000000:3d_position 6,-5000000,1,1:3d_color 6,250,000,250:' 3d_load_texture 6,"texture3.bmp":' 3d_hide 6
3d_box 7,1,10000000,10000000:3d_position 7,05000000,1,1:3d_color 7,000,250,250:' 3d_load_texture 7,"texture3.bmp":' 3d_hide 7

axes_show

3d_cube 8,6:3d_scale 8,0.1,1,1
3d_cube 9,5:3d_scale 9,1,0.1,1
' 3d_mesh 8:3d_load_object 8,"VAISSEAU2.3ds"
' 3d_x_rotate 8,rx:3d_position 8,1,1,1:
' 3d_load_texture 8,"texture1.bmp"

while scancode <>27
if scancode=104 then d=d+0.005:' ship Accelerate and Move forward ======> accélère et avance key "8"
if scancode=098 then d=d-0.005:' ship Slow down and stop ===============> freine et s'arrête key "2"
if scancode=100 then ry=ry+1:' ship turn to the left =================> tourne à gauche    key "4"
if scancode=102 then ry=ry-1:' ship turn to the right ================> tourne à droite    key "6"
if scancode=034 then rx=rx-1:' ship Fall forward and come down(fall) => pique en avant et descend  key "page down"
if scancode=033 then rx=rx+1:' ship ascension ========================> pointe en l'air et monte   key "page up"
if scancode=097 then rz=rz-1:' ship roll left ===> fait 1 tonneau sur la gauche  key "1"
if scancode=099 then rz=rz+1:' ship roll rigt ===> fait 1 tonneau sur la droite  key "3"
if scancode=107 then py=py+0.05:' ship go up =================> monte   key "+"
if scancode=109 then py=py-0.05:' ship go down ===============> descend key "-"
3d_rotate 8,rx,ry,rz:3d_rotate 9,rx,ry,rz
3d_y_position 8,py:3d_y_position 9,py
if d>0.1 then d=0.1
if d<0 then d=0
3d_move 8,d:3d_move 9,d
px=o3d_x_position(8):py=o3d_y_position(8):pz=o3d_z_position(8)
ship()
end_while
terminate

sub ship()
point_position px,py,pz
cam_position px-9,py+9,pz-9
end_sub

' Syzygy
' PLEASE NOTE: ESCAPE THEN Alt-F4 to QUIT
'                     ^^^^^^^^^^^
'              ESCAPE ... ALT-F4 pour quitter.

label action,slowpanel,fin

' number of planets
Dim N%: N%=5
' General control variables
dim quit%,cursor%,fps,i%
quit%=0:cursor%=1
' Objects
dim j%,ship%,lead%,sol%,halo1%,halo2%,a%,s,m,n,o
' angles a,b, t=pitch step & u=roll step (mousey & ut for mouse)
dim a,b,t,u,mousey,mousex,rng
' Space station object indices & variables
dim stn%,shome,stnrot,stnspk1%,stnspk2%,stnring%,stnhub%,stndoor%,hubhit%,doorhit%
' Alien indices & vars
dim abod%,acab%,dummy%,xd,yd,zd,rngchk%,kill%,au,ar,apch%,ayaw%,u2n,r2n,maxsp
' constants
dim pi : pi=3.14159264
' Arrays for planets' positions x,y,z, orbital radius r
dim x(N%+2),y(N%+2),z(N%+2),r(N%+2)
' Ship's variables: position,speed,speed increment,rotations
dim sx,sy,sz,sp,boost,xrot,yrot,zrot
' Control Panel
dim stickx%,sticky%

sp=0:boost=0.001:stnrot=0:xrot=0:yrot=0:zrot=0
doorhit%=0:hubhit%=0 : ' docking/crash detection
t=0.5 : ' pitch increment
u=1 : ' roll increment
rngchk%=1
au=1:ar=0
maxsp=0.5

border_hide 0
width 0,screen_x:height 0,screen_y
color 0,64,64,64
font_color 0,55,55,255
font_bold 0
to_foreground 0

scene3d 1
' full_space 1
width 1,screen_x-200
height 1,screen_y-70
left 1,100:top 1,10

stickx%=screen_x/2
sticky%=570

cursor_hide 0
cursor_cross 1
' Sun is light source, at origin, therefore,
light_position 0,0,0
' It's in space!
color 1,0,0,0

' 3d_skybox 2
' 3d_load_texture_bottom 2,"Bitmaps\stars.bmp"
' 3d_load_texture_top 2,"Bitmaps\stars.bmp"
' 3d_load_texture_left 2,"Bitmaps\stars.bmp"
' 3d_load_texture_right 2,"Bitmaps\stars.bmp"
' 3d_load_texture_front 2,"Bitmaps\stars.bmp"
' 3d_load_texture_back 2,"Bitmaps\stars.bmp"

' Planets created first to keep array index (j%) low without offset. Further object indices will be relative to end of array.
for j%=3 to N%+2 : ' 3 because of frame(0), scene3d(1), skybox(2); N%+2 as arrays start at zero.
   a% = rnd(360):' Not degrees, radians, but any large number will do
  r(j%)=rnd(100000)+5000 : ' solar systems are BIG!
   x(j%)=r(j%)*cos(a%) : ' Circular coordinate
   y(j%)=(rnd(2000)-1000)/20 : ' A random offset from plane
   z(j%)=r(j%)*sin(a%) : ' Circular coordinate
   s = power(r(j%),1.3)/5000 : ' size of planet (temp. bigger than nec.)
   3d_sphere j%,s
   3d_position j%,x(j%),y(j%),z(j%)
   3d_color j%,rnd(40),rnd(40),rnd(40)
   ' special home planet first:
   if j%=3
'       3d_load_texture j%,"Bitmaps\tardis_support.bmp"
      shome=s*2 : ' radius of station rel. to size of planet (smaller=easier to find)
      3d_sphere j%+100,s*1.03 : ' safe index offset for (& may have others with) atmosphere
      3d_position j%+100,x(j%),y(j%),z(j%)
      3d_color j%+100,20,20,155
      3d_transparent j%+100,180
    end_if
next j%

' Sun
sol%=j%+1
3d_sphere sol%,800
3d_color sol%,255,245,50

halo1%=sol%+1
3d_sphere halo1%,900
3d_color halo1%,255,210,140
3d_transparent halo1%,190

halo2%=sol%+2
3d_sphere halo2%,1500
3d_color halo2%,255,55,140
3d_transparent halo2%,240

' Initialise spaceship coordinates near space station (for now)
sx=x(3)+shome+rnd(100)-50:sy=y(3)+shome+rnd(100)-50:sz=z(3)+shome+rnd(100)-50

ship%=sol%+3 : ' required for collision detection
3d_box ship%,0.8,0.2,0.8 : ' width,thickness,length
' 3d_load_texture ship%,"Bitmaps\flare.bmp"

' Leading object ahead of ship to point camera at (merci bignono!)
lead%=sol%+4
3d_cube lead%,2
' 3d_hide lead%
3d_color lead%,255,255,255
3d_transparent lead%,128

' Several concentric parts of the station follow:
stn%=sol%+5
3d_dodecahedron stn%
3d_scale stn%,3,3,3
' 3d_color stn%,55,55,40
3d_position stn%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stn%,3

' Spokes
stnspk1%=sol%+6
3d_box stnspk1%,0.8,20,0.1
' 3d_color stnspk1%,255,255,240
' 3d_color stnspk1%,100,100,50
' 3d_load_texture stnspk1%,"Bitmaps\mcheck4.bmp"
3d_position stnspk1%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnspk1%,3

stnspk2%=sol%+7
3d_box stnspk2%,20,0.8,0.1
' 3d_color stnspk1%,255,255,240
' 3d_color stnspk2%,100,100,50
' 3d_load_texture stnspk1%,"Bitmaps\mcheck4.bmp"
3d_position stnspk2%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnspk2%,3

' Ring
stnring%=sol%+8
3d_torus stnring%,10,0.5
3d_position stnring%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnring%,3

' Cylinder hub
stnhub%=sol%+9
3d_cylinder stnhub%,3,1.3,1.3
3d_position stnhub%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stnhub%,3
3d_x_rotate stnhub%,90

' Box to give illusion of door (bug?: color 0,0,0 does not cover all sides)
stndoor%=sol%+10
3d_box stndoor%,0.3,1.3,3.01 : ' height,width,>cylinderlength
3d_position stndoor%,x(3)+shome,y(3)+shome,z(3)+shome
3d_point_object stndoor%,3
3d_color stndoor%,120,120,10

' "Alien" flying saucer
abod%=sol%+11
acab%=sol%+12
3d_sphere abod%,1
3d_sphere acab%,0.25
3d_y_scale abod%,0.06
3d_z_scale abod%,0.5
3d_y_scale acab%,0.6
3d_z_scale acab%,1.6
' Init at space station for now
3d_position abod%,x(3)+shome,y(3)+shome,z(3)+shome
3d_position acab%,x(3)+shome,y(3)+shome,z(3)+shome
3d_color abod%,20,60,50
3d_color acab%,10,40,70
3d_transparent acab%,80

dummy%=sol%+13
3d_cube dummy%,0.01:3d_hide dummy% : ' Allows us to point alien in its flying direction!

' Initialize objects & methods used for collision
3d_collision_as_faces ship% : ' Idea is to rotate ship so that its wide shape fits in door!
3d_collision_as_faces stnhub% : ' Also need all other parts added
3d_collision_as_faces stndoor% : ' The good one to hit

' View from inside space ship; we will move/rotate both together
' cam_position sx,sy,sz
' point_position x(3)+shome,y(3)+shome,z(3)+shome
' 3d_point_object ship%,stn%

3d_position ship%,sx,sy,sz
3d_point_object ship%,sol%
cam_position sx,sy,sz
point_object sol%
3d_y_rotate ship%,180
cam_turn 180
' WHY DOES THIS NOT WORK?
' IT SHOULD BEGIN GAME WITH US LOOKING DIRECTLY AWAY FROM THE SUN!

' on_close 0,fin

timer 99
timer_interval 99,100
on_timer 99,slowpanel

i%=0: ' Counter for fps (frames per second)
gosub action
' timer_off_all
end
' =====================

' MAIN LOOP
action:
while quit%=0
   i%=i%+1
   select scancode
      case 38:xrot=xrot-t: ' up key (some may prefer opposite)
      case 40:xrot=xrot+t: ' down key
      case 37:zrot=zrot-u: ' left key
      case 39:zrot=zrot+u: ' right key
      case 81:boost=0.1: ' Q - fast acceleration & decel.
      case 65:boost=0.01: ' A - medium
      case 90:boost=0.001: ' Z - fine
      case 160:sp=sp+boost: ' left shift
      case 161:sp=sp+boost: ' right shift
      case 162:sp=sp-boost: ' left control
      case 163:sp=sp-boost: ' right control
      case 32:sp=0: ' SPACE, dead stop (temporary cheat!)
      case 27:goto fin: ' ESCAPE (Why the warning beep from system?)
      case 67:cursor_cross 1 : ' C (Cross hairs on)
      case 68:cursor_hide 1 : ' D  (-"- off)
   end_select
   ' Rotate ship & cam on mouse position
   mousey=4*(mouse_y_position(1)-height(1)/2)/height(1)
   mousex=4*(mouse_x_position(1)-width(1)/2)/width(1)
   xrot=xrot-mousey
   yrot=yrot-mousex
   xrot=wrap_value(xrot)
   yrot=wrap_value(yrot)
   zrot=wrap_value(zrot)
   3d_move ship%,sp
   3d_rotate ship%,xrot,yrot,zrot
   3d_position lead%,o3d_x_position(ship%),o3d_y_position(ship%),o3d_z_position(ship%)
   3d_rotate lead%,xrot,yrot,zrot
   3d_move lead%,10
   cam_position o3d_x_position(ship%),o3d_y_position(ship%),o3d_z_position(ship%)
'   point_position o3d_x_position(lead%),o3d_y_position(lead%),o3d_z_position(lead%)
   point_object lead%
   cam_roll -1*zrot

   ' Continually rotate space station
   3d_z_rotate stn%,stnrot
   3d_z_rotate stnspk1%,stnrot
   3d_z_rotate stnspk2%,stnrot
   3d_z_rotate stnring%,stnrot
   3d_z_rotate stndoor%,stnrot
   stnrot=wrap_value(stnrot+0.5): ' Is this necessary?
  
  ' MOVE ALIEN
   xd=o3d_x_position(ship%)-o3d_x_position(abod%)
   yd=o3d_y_position(ship%)-o3d_y_position(abod%)
   zd=o3d_z_position(ship%)-o3d_z_position(abod%)
   rng=sqr(xd*xd+yd*yd+zd*zd)
   3d_x_position abod%,o3d_x_position(abod%)+m
   3d_y_position abod%,o3d_y_position(abod%)+n
   3d_z_position abod%,o3d_z_position(abod%)+o
   3d_x_position acab%,o3d_x_position(acab%)+m
   3d_y_position acab%,o3d_y_position(acab%)+n
   3d_z_position acab%,o3d_z_position(acab%)+o
   3d_position dummy%,o3d_x_position(acab%)+m,o3d_y_position(acab%)+n,o3d_z_position(acab%)+o
   3d_point_object acab%,dummy%
   3d_point_object abod%,dummy%
   if kill%=0
      m=m+0.000000002*power(xd,3)*rng: ' *sgn(xd)
      n=n+0.000000002*power(yd,3)*rng: ' *sgn(yd)
      o=o+0.000000002*power(zd,3)*rng: ' *sgn(zd)
      if abs(m)>maxsp then m=maxsp*sgn(m)
      if abs(n)>maxsp then n=maxsp*sgn(n)
      if abs(o)>maxsp then o=maxsp*sgn(o)
   end_if
      ' This tries to correct endless orbiting, making alien dive towards us.
   if rnd(2000)<1 and rng>35 then kill%=30
   if kill%>0
      m=m*0.9
      n=n*0.9
      o=o*0.9
      kill%=kill%-1
   end_if
'   orng=rng
   display

' TESTS
   ' Docking or collision with space station?  (Not perfect, but works)
   if o3d_collision(ship%,stndoor%)=1 then doorhit%=1
   if o3d_collision(ship%,stnhub%)=1 then hubhit%=1
   if hubhit%=1 : ' Can't avoid hitting hub, so...
      if doorhit%=0 then message "Crashed!":quit%=1 : ' ...Missed door.
      if doorhit%=1 then message "Successfully docked!":quit%=1 : ' ...hit door.
   end_if
end_while : ' Main loop ends when quit%=1
return

' OUTPUT ON DASHBOARD
slowpanel:
   fps=i%*10:i%=0
   timer_off 99 : ' No trigger repeat in loop. Also "return" without resetting timer ends game".
   ' Speed
   2d_fill_color 5,255,5
   print_locate 2,80:print "Spd ";int(sp*1000);"  "
   ' Position
   print_locate 2,100:print "X ";int(o3d_x_position(ship%));" "
   print_locate 2,120:print "Y ";int(o3d_y_position(ship%));" "
   print_locate 2,140:print "Z ";int(o3d_z_position(ship%));" "
   ' Alien Position
   print_locate 2,250:print "aX ";int(o3d_x_position(abod%));" "
   print_locate 2,270:print "aY ";int(o3d_y_position(abod%));" "
   print_locate 2,290:print "aZ ";int(o3d_z_position(abod%));" "
   ' Alien "speed" (kinda)
   print_locate 2,320:print "aSpd ";int((sqr(m*m+n*n+o*o)*1000));" "
'   print_locate 2,340:print "ar ";ar;" "
   print_locate 2,400:print "Range ";int(rng);".";int(frac(rng)*1000);" "
   2d_fill_color 5,5,255
   2d_pen_width 1
   2d_rectangle stickx%-30,sticky%-30,stickx%+30,sticky%+30
   2d_pen_width 2
   2d_line stickx%,sticky%,stickx%+sqr(abs(400*mousex))*sgn(mousex),sticky%+sqr(abs(400*mousey))*sgn(mousey)
   2d_pen_width 5
   2d_line stickx%+sqr(abs(400*mousex))*sgn(mousex),sticky%+sqr(abs(400*mousey))*sgn(mousey),stickx%+sqr(abs(400*mousex))*sgn(mousex),sticky%+sqr(abs(400*mousey))*sgn(mousey)

   ' My data
   2d_fill_color 5,255,255
   print_locate screen_x-95,40:print fps;" fps"
   print_locate screen_x-95,80:print "Mx ";mousex;"    "
   print_locate screen_x-95,100:print "My ";mousey;"    "
   print_locate screen_x-95,140:print "xrot ";xrot;"    "
   print_locate screen_x-95,160:print "yrot ";yrot;"    "
   print_locate screen_x-95,180:print "zrot ";zrot;"    "

   timer_on 99
return

' ==============

fin:
   quit%=1
return