' musique.bas
'
' On saisit une ligne de notes selon le format suivant:
' nxx%y& avec: n = octave choisie {d,c,b,a,0,1,2,3,4}
' xx = nom de la note: {innn,vnnn,p,do,re,mi,fa,sol,la,si}
' i = instrument avec nnn=numéro d'instrument
' v = colume
' p = pause
' # = modificateur {[],#,b}
' y = durée inverse {[3],1,2,3,4,5,6} correspondant à {1,1/2,1/4,1/8,1/6,1/32}
' y = "note pointée" {[],.}
' volume: nnn=1...127 défaut: 100
' Les notes sont séparées par des espaces.
' 60=do 62=ré 64=mi 65=fa 67=sol 69=la 71=si 72=do
' en octave -4:
' 12=do 14=re 16=mi 17=fa 19=sol 21=la 23=si 24=do
' en octave -5: (octave fictive, servant de base pour les calculs)
' 0=do 2=re 4=mi 5=fa 7=sol 9=la 11=si 12=do
' mini: 21=la(-4) max: 108=do(+4) C'est l'étendu d'un clavier de piano
' delta octave: 12
label labels : gosub labels
gosub constantes
gosub variables
gosub donnees
gosub form0
gosub menu
gosub GUI
gosub initialisations
end
labels:
label constantes, variables, donnees, form0, menu, GUI, initialisations
label ajouter, start, compiler, jouer, sel_instrument, inserer, effacer
label sel_volume, demo, dessiner_note, dessiner, dessiner_pause, localiser_note
label dessiner_pause_1, dessiner_pause_2, dessiner_pause_3, dessiner_pause_4
label dessiner_pause_5, dessiner_pause_6, dessiner_point_1, dessiner_point_2
label dessiner_note_1, dessiner_note_2, dessiner_note_3, dessiner_note_4
label dessiner_note_5, dessiner_note_6, dessiner_point, creer_picture
label dessiner_lignes_audessus, dessiner_lignes_endessous, copier
label dessiner_modificateur,dessiner_dieze, dessiner_bmol, dessiner_cledesol
label dessiner_instrument, dessiner_volume, change_volume
label montrer_piano, cacher_piano, dessiner_piano, clic_piano, panoramic
label compiler_immediat, ouvrir, sauver, transplus, transmoins
label speedplus, speedmoins, speed
label tp1, tp2, tp3, tm1, tm2, tm3
return
constantes:
dim M1% : M1% = 0 - 1
dim M2% : M2% = 0 - 2
dim M3% : M3% = 0 - 3
dim M4% : M4% = 0 - 4
dim M5% : M5% = 0 - 5
dim octaves$ : octaves$ = "dcba01234"
dim liste_notes$ : liste_notes$ = "do ré mi fa solla si do "
dim demo1$ : demo1$ = "i48 asol5 asol5 asol5 0do4 0do4 0ré4 0ré4 0sol3 0mi5 0do5"
dim demo2$ : demo2$ = "i57 0do5 0mi5 0do5 ala4 0fa3 0ré5 asi5 0do2"
dim lig_start% : lig_start% = 120
dim lig_delta% : lig_delta% = 10
dim table_vertical%(9,6) : ' décalage des notes dans la portée par octave
' (oct,note) oct=1...9 note=0...6 0=do 6=si
return
variables:
dim no%, no1%, no2%, i%, j%, k%, n%, s$, s1$, s2$, w%, x%, y%
dim no_ligne%, no_partition%, no_instruments%, no_duree%, no_notes%
dim no_octaves%, no_modif%, no_volume%, no_picture%, no_dessiner%
dim no_aff_volume%, no_copier%, no_piano%, no_bouton_piano%, no_inserer%
dim no_panoramic%, no_code_panoramic%, no_ecoute_immediate%, no_jouer%
dim no_progress%, no_open%, no_save%
dim flag_pointe%, flag_done%, mode_immediat%, octave$
dim note%, octave%, modif%, volume%, note_origine%
dim index_ligne%, lignes_audessus%, lignes_endessous%
dim n_notes% : ' nombre de notes compilées
dim notes%(1000) : ' code de la note (-1=instrument 0=pause)
dim durees%(1000) : ' durée de la note ou code instrument
dim notes_origine%(1000,2) : ' (x,0)=note (0=do,...,6=si) (x,1)=octave (x,2)=modificateur
dim piano_octaves%(9,1) : ' valeurs x mini/maxi des octaves pour un clic dans le piano
dim flag_noire% : ' flag "touche noire frappée" sur le piano
dim largeur_blanche% : ' largeur d'une note blanche du piano
dim touche_blanche%, touche_noire%
dim no_arreter% : ' Papydall
return
donnees:
' instruments:
data "Piano"
data " 0 Acoustic grand piano"
data " 1 Bright acoustic piano"
data " 2 Electric grand piano"
data " 3 Honky-tonk piano"
data " 4 Rhodes piano"
data " 5 Chorused piano"
data " 6 Harpsichord"
data " 7 Clavinet"
data ""
data "Chromatic Percussion"
data " 8 Celesta"
data " 9 Glockenspiel"
data " 10 Music box"
data " 11 Vibraphone"
data " 12 Marimba"
data " 13 Xylophone"
data " 14 Tubular bells"
data " 15 Dulcimer"
data ""
data "Organ"
data " 16 Hammond organ"
data " 17 Percussive organ"
data " 18 Rock organ"
data " 19 Church organ"
data " 20 Reed organ"
data " 21 Accordion"
data " 22 Harmonica"
data " 23 Tango accordion"
data ""
data "Guitar"
data " 24 Acoustic guitar (nylon)"
data " 25 Acoustic guitar (steel"
data " 26 Electric guitar (jazz)"
data " 27 Electric guitar (clean)"
data " 28 Electric guitar (muted)"
data " 29 Overdriven guitar"
data " 30 Distortion guitar"
data " 31 Guitar harmonics"
data ""
data "Bass"
data " 32 Acoustic bass"
data " 33 Electric bass (finger)"
data " 34 Electric bass (pick)"
data " 35 Fretless bass"
data " 36 Slap bass 1"
data " 37 Slap bass 2"
data " 38 Synth bass 1"
data " 39 Synth bass 2"
data ""
data "Strings"
data " 40 Violin"
data " 41 Viola"
data " 42 Cello"
data " 43 Contrabass"
data " 44 Tremolo strings"
data " 45 Pizzicato strings"
data " 46 Orchestral harp"
data " 47 Timpani"
data ""
data "Ensemble"
data " 48 String ensemble 1"
data " 49 String ensemble 2"
data " 50 Synth. strings 1"
data " 51 Synth. strings 2"
data " 52 Choir Aahs"
data " 53 Voice Oohs"
data " 54 Synth voice"
data " 55 Orchestra hit"
data ""
data "Brass"
data " 56 Trumpet"
data " 57 Trombone"
data " 58 Tuba 66"
data " 59 Muted trumpet"
data " 60 French horn"
data " 61 Brass section"
data " 62 Synth. brass 1"
data " 63 Synth. brass 2"
data ""
data "Reed"
data " 64 Soprano sax"
data " 65 Alto sax"
data " Tenor sax"
data " 67 Baritone sax"
data " 68 Oboe"
data " 69 English horn"
data " 70 Bassoon"
data " 71 Clarinet"
data ""
data "Pipe"
data " 72 Piccolo"
data " 73 Flute"
data " 74 Recorder"
data " 75 Pan flute"
data " 76 Bottle blow"
data " 77 Shakuhachi"
data " 78 Whistle"
data " 79 Ocarina"
data ""
data "Synth Lead"
data " 80 Lead 1 (square)"
data " 81 Lead 2 (sawtooth)"
data " 82 Lead 3 (calliope lead)"
data " 83 Lead 4 (chiff lead)"
data " 84 Lead 5 (charang)"
data " 85 Lead 6 (voice)"
data " 86 Lead 7 (fifths)"
data " 87 Lead 8 (brass + lead)"
data ""
data "Synth Pad"
data " 88 Pad 1 (new age)"
data " 89 Pad 2 (warm)"
data " 90 Pad 3 (polysynth)"
data " 91 Pad 4 (choir)"
data " 92 Pad 5 (bowed)"
data " 93 Pad 6 (metallic)"
data " 94 Pad 7 (halo)"
data " 95 Pad 8 (sweep)"
data ""
data "Miscellaneous"
data " 96 Synth SFX 1 Ice Rain"
data " 97 Synth SFX 2 Sound Track"
data " 98 Synth SFX 3 Crystal"
data " 99 Synth SFX 4 Atmosphere"
data "100 Synth SFX 5 Brightness"
data "101 Synth SFX 6 Goblin"
data "102 Synth SFX 7 Echo Drops"
data "103 Synth SFX 8 Star Theme"
data "104 Sitar"
data "105 Banjo"
data "106 Shamisen"
data "107 Koto"
data "108 Kalimba"
data "109 Bagpipe"
data "110 Fiddle"
data "111 Shanai"
data "112 Tinkle Bells"
data "113 Agogo"
data "114 Steel Drums"
data "115 Woodblock"
data "116 Taiko Drum"
data "117 Melodic Drum"
data "118 Synth Drum"
data "119 Reverse Cymbal"
data ""
data "Sound Effects"
data "120 Guitar fret noise"
data "121 Breath noise"
data "122 Seashore"
data "123 Bird tweet"
data "124 Telephone ring"
data "125 Helicopter"
data "126 Applause"
data "127 Gunshot"
data "***"
' table_vertical%(1000,2) : ' (x,0)=note (0=do,...,6=si) (x,1)=octave (x,2)=modificateur
data 0,0,0,0,0,0,0 : ' octave 1 (d)
data 0,0,0,0,0,0,0 : ' octave 2 (c)
data 0,0,0,0,0,0,0 : ' octave 3 (b)
data 0,0,0,0,13,12,11 : ' octave 4 (a)
data 10,9,8,7,6,5,4 : ' octave 5 (0)
data 3,2,1,0,M1%,M2%,M3% : ' octave 6 (1)
data M4%,M5%,0,0,0,0,0,0 : ' octave 7 (2)
data 0,0,0,0,0,0,0 : ' octave 8 (3)
data 0,0,0,0,0,0,0 : ' octave 9 (4)
return
form0:
full_space 0
caption 0,"Jouer une mélodie
return
menu:
return
GUI:
no% = no% + 1 : open_dialog no% : no_open% = no%
filter no%,"Mélodies|*.mel"
no% = no% + 1 : save_dialog no% : no_save% = no%
filter no%,"Mélodies|*.mel"
' configurateur
no% = no% + 1 : container_option no% : no1% = no% : top no%,10 : left no%,10
caption no%,"Octave" : height no%,50 : width no%,370
no_octaves% = no%
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,10
caption no%,"d" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,50
caption no%,"c" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,90
caption no%,"b" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,130
caption no%,"a" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,170
caption no%,"0" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,210
caption no%,"1" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,250
caption no%,"2" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,290
caption no%,"3" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,330
caption no%,"4" : width no%,30
no% = no% + 1 : container_option no% : no1% = no% : top no%,10 : left no%,390
caption no%,"Note" : height no%,50 : width no%,330
no_notes% = no%
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,10
caption no%,"do" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,50
caption no%,"ré" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,90
caption no%,"mi" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,130
caption no%,"fa" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,170
caption no%,"sol" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,210
caption no%,"la" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,250
caption no%,"si" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,290
caption no%,"p" : width no%,30
no% = no% + 1 : container_option no% : no1% = no% : top no%,60 : left no%,390
caption no%,"Modificateur" : height no%,50 : width no%,130
no_modif% = no%
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,10
caption no%,"./." : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,50
caption no%,"#" : width no%,30
no% = no% + 1 : option no% : parent no%,no1% : top no%,20 : left no%,90
caption no%,"b" : width no%,30
no% = no% + 1 : container no% : no1% = no% : top no%,10 : left no%,730
caption no%,"Durée" : height no%,50 : width no%,200
no% = no% + 1 : combo no% : parent no%,no1% : top no%,20 : left no%,10
no_duree% = no% : width no%,120
no% = no% + 1 : check no% : parent no%,no1% : top no%,20 : left no%,140
caption no%,"pointé" : width no%,50
no% = no% + 1 : button no% : no_inserer% = no% : top no%,20 : left no%,940
caption no%,"Insérer" : on_click no%,inserer
no% = no% + 1 : combo no% : top no%,90 : left no%,10 : width no%,200
no_instruments% = no%
no% = no% + 1 : button no% : top no%,90 : left no%,left(no%-1)+width(no%-1)
caption no%,"Choisir" : on_click no%,sel_instrument
no% = no% + 1 : alpha no% : top no%,95 : left no%,650
caption no%,"Volume:"
no% = no% + 1 : scroll_bar no% : top no%,95 : left no%,700 : width no%,200
no_volume% = no% : min no%,1 : max no%,127 : position no%,100
on_change no%,change_volume
no% = no% + 1 : edit no% : no_aff_volume% = no% : width no%,25 : inactive no%
top no%,95 : left no%,left(no%-1)+width(no%-1) : text no%,100
no% = no% + 1 : button no% : top no%,90 : left no%,left(no%-1)+width(no%-1)
caption no%,"Choisir" : on_click no%,sel_volume
' ligne d'écriture
no% = no% + 1 : edit no% : top no%,120 : left no%,10 : width no%,width(0)-40
no_ligne% = no%
no% = no% + 1 : button no% : top no%,150 : left no%,200
caption no%,"Ajouter" : on_click no%,ajouter
no% = no% + 1 : button no% : top no%,150 : left no%,450
caption no%,"Démo" : on_click no%,demo
no% = no% + 1 : button no% : top no%,150 : left no%,700
caption no%,"Effacer" : on_click no%,effacer
' partition
no% = no% + 1 : progress_bar no% : no_progress% = no%
top no%,390 : left no%,10 : width no%,width(0)-40
min no%,0 : max no%,100 : position no%,0
no% = no% + 1 : memo no% : top no%,180 : left no%,10 : width no%,width(0)*0.8
no_partition% = no% : bar_vertical no% : height no%,200
no% = no% + 1 : button no% : top no%,180 : left no%,left(no%-1)+width(no%-1)+10
caption no%,"Ouvrir" : width no%,90 : on_click no%,ouvrir
no% = no% + 1 : button no% : top no%,205 : left no%,left(no%-1)
caption no%,"Sauver" : width no%,90 : on_click no%,sauver
no% = no% + 1 : button no% : top no%,260 : left no%,left(no%-1)
caption no%,"Transposer +1/2" : width no%,90 : on_click no%,transplus
no% = no% + 1 : button no% : top no%,285 : left no%,left(no%-1)
caption no%,"Transposer -1/2" : width no%,90 : on_click no%,transmoins
no% = no% + 1 : button no% : top no%,330 : left no%,left(no%-1)
caption no%,"Plus rapide" : width no%,90 : on_click no%,speedplus
no% = no% + 1 : button no% : top no%,355 : left no%,left(no%-1)
caption no%,"Moins rapide" : width no%,90 : on_click no%,speedmoins
no% = no% + 1 : button no% : no_jouer% = no% : top no%,410 : left no%,200
caption no%,"Jouer" : on_click no%,start : hide no%
no% = no% + 1 : button no%: no_dessiner% = no% : hide no% : top no%,410 : left no%,450
caption no%,"Partition" : on_click no%,dessiner
' Papydall
no% = no% +1 : button no% : no_arreter% = no% : top no%,410 : left no%,100
caption no%,"Arreter" : hide no%
no% = no% + 1 : button no%: no_copier% = no% : hide no% : top no%,410
left no%,left(no%-1)+width(no%-1)
caption no%,"Copier" : on_click no%,copier
no% = no% + 1 : button no%: no_panoramic% = no% : hide no% : top no%,410
left no%,left(no%-1)+width(no%-1)
caption no%,"Panoramic" : on_click no%,panoramic
no% = no% + 1 : no_picture% = no% : gosub creer_picture : hide no%
no% = no% + 1 : memo no% : hide no% : no_code_panoramic% = no%
' piano
no% = no% + 1 : picture no% : hide no% : no_piano% = no% : on_click no%,clic_piano
top no%,460 : left no%,10 : width no%,width(0)-40 : height no%,200
gosub dessiner_piano
no% = no% + 1 : button no% : no_bouton_piano% = no%
top no%,50 : left no%,940 : caption no%,"Montrer piano" : on_click no%,montrer_piano
no% = no% + 1 : check no% : no_ecoute_immediate% = no% : width no%,120
top no%,70 : left no%,700 : caption no%,"Ecoute immédiate"
return
creer_picture:
picture no_picture% : hide no_picture% : top no_picture%,460 : left no_picture%,10
width no_picture%,width(0)-40 : height no_picture%,300
return
ouvrir:
s$ = file_name$(no_open%)
if s$="_" then return
if lower$(right$(s$,4))<>".mel" then s$ = s$ + ".mel"
file_open_read 1,s$
file_readln 1,s1$
if s1$<>"; Mélodie"
message "Ce n'est pas un fichier mélodie valide"
file_close 1
return
end_if
while file_eof(1)=0
file_readln 1,s1$
item_add no_partition%,s1$
end_while
file_close 1
show no_jouer%
set_focus no_ligne%
return
sauver:
if count(no_partition%)=0
message "Il n'y a rien à sauvegarder."
return
end_if
s$ = file_name$(no_save%)
if s$="_" then return
if lower$(right$(s$,4))<>".mel" then s$ = s$ + ".mel"
file_open_write 1,s$
file_writeln 1,"; Mélodie"
for i%=1 to count(no_partition%)
file_writeln 1,trim$(item_read$(no_partition%,i%)) : ' +" "
next i%
file_close 1
return
montrer_piano:
show no_piano%
caption no_bouton_piano%,"Cacher piano"
on_click no_bouton_piano%,cacher_piano
return
cacher_piano:
hide no_piano%
caption no_bouton_piano%,"Montrer piano"
on_click no_bouton_piano%,montrer_piano
return
dessiner_piano:
2d_target_is no_piano%
print_target_is no_piano%
font_bold no_piano%
largeur_blanche% = (width(no_piano%)-2)/58
2d_pen_width 2
2d_rectangle 0,20,width(no_piano%),height(no_piano%)
2d_pen_width 1
for i%=1 to 58
2d_rectangle 1+(i%-1)*largeur_blanche%,20,1+i%*largeur_blanche%,height(no_piano%)
next i%
piano_octaves%(1,0) = 1
piano_octaves%(1,1) = 3*largeur_blanche%-1
2d_rectangle 1,1,3*largeur_blanche%,19
print_locate largeur_blanche%*1.4,3
print "d"
x% = 1 + 3*largeur_blanche%
for i%=1 to 8
piano_octaves%(i%+1,0) = x%
piano_octaves%(i%+1,1) = x% + 7*largeur_blanche% - 1
2d_rectangle x%,1,x%+7*largeur_blanche%-1,19
print_locate x% + largeur_blanche%*3.4,3
print mid$("cba01234",i%,1)
x% = x% + 7*largeur_blanche%
next i%
2d_fill_color 1,0,0
x% = 0.6*largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
for i%=1 to 8
x% = x% + largeur_blanche%
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
x% = x% + largeur_blanche%
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
x% = x% + largeur_blanche%
2d_rectangle x%,20,x%+largeur_blanche%*0.9,height(no_piano%)*0.6
next i%
return
initialisations:
read s$
while s$<>"***"
item_add no_instruments%,s$
read s$
end_while
text no_instruments%,item_read$(no_instruments%,2)
for i%=1 to 9
for j%=0 to 6
read table_vertical%(i%,j%)
next j%
next i%
item_add no_duree%,"1 (1) ronde"
item_add no_duree%,"2 (1/2) blanche"
item_add no_duree%,"3 (1/4) noire"
item_add no_duree%,"4 (1/8) croche"
item_add no_duree%,"5 (1/16) double-croche"
item_add no_duree%,"6 (1/32) triple croche"
text no_duree%,item_read$(no_duree%,3)
mark_on no_notes%+1
mark_on no_octaves%+5
mark_on no_modif%+1
midi_on
return
ajouter:
s$ = trim$(text$(no_ligne%))
if s$<>""
item_add no_partition%,s$
text no_ligne%,""
end_if
show no_jouer%
set_focus no_ligne%
return
effacer:
clear no_partition%
set_focus no_ligne%
2d_target_is 0
print_target_is 0
delete no_picture%
gosub creer_picture
2d_target_is no_picture%
print_target_is no_picture%
font_size no_picture%,12
font_bold no_picture%
font_italic no_picture%
hide no_dessiner%
hide no_copier%
hide no_panoramic%
hide no_jouer%
return
demo:
item_add no_partition%,demo1$
item_add no_partition%,demo2$
show no_jouer%
set_focus no_ligne%
return
start:
inactive no_jouer%
gosub compiler
gosub jouer
active no_jouer%
return
change_volume:
text no_aff_volume%,position(no_volume%)
return
compiler:
n_notes% = 0
if count(no_partition%)=0
message "Il n'y a rien à jouer !"
return
end_if
for i%=1 to count(no_partition%)
s$ = trim$(item_read$(no_partition%,i%))+" "
if len(s$)>0
compiler_immediat:
j% = instr(s$," ")
while j%>0
s1$ = lower$(trim$(left$(s$,j%-1)))
flag_done% = 0
' {innn,p,do,re,mi,fa,sol,la,si}
if left$(s1$,1)="i" : ' innn=instrument
s2$ = mid$(s1$,2,len(s1$))
if numeric(s2$)=0
message "instrument invalide dans "+s1$
return
end_if
n% = int(val(s2$))
if n%<1 or n%>127
message "instrument invalide dans "+s1$
return
end_if
n_notes% = n_notes% + 1
notes%(n_notes%) = M1%
notes_origine%(n_notes%,0) = M1%
notes_origine%(n_notes%,1) = 0
notes_origine%(n_notes%,2) = 0
durees%(n_notes%) = n%
flag_done% = 1
end_if
if left$(s1$,1)="v" : ' vnnn=volume
s2$ = mid$(s1$,2,len(s1$))
if numeric(s2$)=0
message "volume invalide dans "+s1$
return
end_if
n% = int(val(s2$))
if n%<1 or n%>127
message "volume invalide dans "+s1$
return
end_if
n_notes% = n_notes% + 1
notes%(n_notes%) = M2%
notes_origine%(n_notes%,0) = M2%
notes_origine%(n_notes%,1) = 0
notes_origine%(n_notes%,2) = 0
durees%(n_notes%) = n%
flag_done% = 1
end_if
if left$(s1$,1)="p" : ' pn.=pause
flag_pointe% = 0
s2$ = s1$
if right$(s2$,1)="."
flag_pointe% = 1
s2$ = left$(s2$,len(s2$)-1)
end_if
s2$ = mid$(s2$,2,len(s2$))
if numeric(s2$)=0
message "pause invalide dans "+s1$
return
end_if
n% = int(val(s2$))
if n%<1 or n%>6
message "pause invalide dans "+s1$
return
end_if
n% = (n%-1)*2 + flag_pointe%
n_notes% = n_notes% + 1
notes%(n_notes%) = 0
notes_origine%(n_notes%,0) = 0 : ' placer les pauses à la place d'un do
notes_origine%(n_notes%,1) = 6 : ' en octave 1 (indice 6 dans tableau des octaves)
notes_origine%(n_notes%,2) = 0
durees%(n_notes%) = n%
flag_done% = 1
end_if
if flag_done%=0
octave% = 0
modif% = 0
note% = M1%
s2$ = left$(s1$,1) : ' l'octave
octave% = instr(octaves$,s2$)
if octave%=0
message "octave invalide dans "+s1$
return
end_if
s2$ = mid$(s1$,2,len(s1$))
if left$(s2$,2)="do"
s2$ = mid$(s2$,3,len(s2$))
note% = 0
note_origine% = 0
end_if
if (left$(s2$,2)="re") or (left$(s2$,2)="ré")
s2$ = mid$(s2$,3,len(s2$))
note% = 2
note_origine% = 1
end_if
if left$(s2$,2)="mi"
s2$ = mid$(s2$,3,len(s2$))
note% = 4
note_origine% = 2
end_if
if left$(s2$,2)="fa"
s2$ = mid$(s2$,3,len(s2$))
note% = 5
note_origine% = 3
end_if
if left$(s2$,3)="sol"
s2$ = mid$(s2$,4,len(s2$))
note% = 7
note_origine% = 4
end_if
if left$(s2$,2)="la"
s2$ = mid$(s2$,3,len(s2$))
note% = 9
note_origine% = 5
end_if
if left$(s2$,2)="si"
s2$ = mid$(s2$,3,len(s2$))
note% = 11
note_origine% = 6
end_if
if note%=M1%
message "note inconnue dans "+s1$
return
end_if
modif% = 0
if left$(s2$,1)="#"
modif% = 1
s2$ = mid$(s2$,2,len(s2$))
else
if left$(s2$,1)="b"
modif% = M1%
s2$ = mid$(s2$,2,len(s2$))
end_if
end_if
flag_pointe% = 0
if right$(s2$,1)="."
flag_pointe% = 1
s2$ = left$(s2$,len(s2$)-1)
end_if
if numeric(s2$)=0
message "durée invalide dans "+s1$
return
end_if
n% = int(val(s2$))
if n%<1 or n%>6
message "durée invalide dans "+s1$
return
end_if
n% = (n%-1)*2 + flag_pointe%
note% = note% + octave%*12 + modif%
if (note%<21) or (note%>108)
message "note "+s1$+" en-dehors des possibilités"
return
end_if
n_notes% = n_notes% + 1
notes%(n_notes%) = note%
notes_origine%(n_notes%,0) = note_origine%
notes_origine%(n_notes%,1) = octave%
notes_origine%(n_notes%,2) = modif%
durees%(n_notes%) = n%
flag_done% = 1
end_if
if flag_done%=0
message "note inconnue dans "+s1$
return
end_if
s$ = trim$(mid$(s$,j%+1,len(s$)))
if len(s$)>0 then s$ = s$ + " "
j% = instr(s$," ")
end_while
if mode_immediat%=1 then return
end_if
next i%
show no_dessiner%
hide no_copier%
hide no_panoramic%
return
' 0do4 0re4 0mi4 0do4 i40 0do4 0re4 0mi4 0do4 0mi4 0fa4 0sol4 p4 0mi4 0fa4 0sol4
jouer:
if n_notes%=0
message "Il n'y a rien à jouer après analyse !"
return
end_if
show no_arreter% : ' Papydall
volume% = 100
for i%=1 to n_notes%
position no_progress%, int((i%-0.5)*100/n_notes%)
' message str$(notes%(i%))+" "+str$(durees%(i%))
if notes%(i%)=M1% : ' instrument
midi_instrument durees%(i%)
else
if notes%(i%)=m2%
volume% = durees%(i%)
midi_volume volume%
else
if notes%(i%)=0 : ' pause
midi_volume 1
midi_play 60,durees%(i%)
midi_volume volume%
else : ' vraie note
midi_volume 100
midi_play notes%(i%),durees%(i%)
' gosub dessiner_note
end_if
end_if
end_if
position no_progress%, int(i%*100/n_notes%)
' Papydall
if clicked(no_arreter%) = 1 then hide no_arreter%: show no_jouer% : exit_for
' Fin Papydall
next i%
position no_progress%,0
return
dessiner:
x% = 10
show no_picture%
color no_picture%,241,246,136
2d_target_is no_picture%
print_target_is no_picture%
font_size no_picture%,12
font_bold no_picture%
font_italic no_picture%
w% = width(no_picture%)
gosub dessiner_cledesol
for i%=1 to n_notes%
if width(no_picture%)<(x%+2*lig_delta%)
width no_picture%,width(no_picture%)+10*lig_delta%
2d_fill_color 241,246,136
2d_pen_color 241,246,136
2d_rectangle w%-1,0,width(no_picture%)-1,height(no_picture%)-1
w% = width(no_picture%)
2d_pen_color 0,0,0
end_if
2d_fill_color 0,0,0
if notes%(i%)>0 then gosub dessiner_note
if notes%(i%)=0 then gosub dessiner_pause
if notes%(i%)=M1% then gosub dessiner_instrument
if notes%(i%)=M2% then gosub dessiner_volume
next i%
' dessiner la portée maintenant seulement !
for i%=1 to 5
y% = lig_start% + (i%-1)*lig_delta%
2d_line 0,y%,w%,y%
next i%
show no_copier%
show no_panoramic%
return
dessiner_cledesol:
' clé de sol ( base du code fourni par Papydall)
if variable("theta")=0
dim theta ,pi, p, x1, y1, xp,yp ,xcentre,ycentre
pi = 4*atn(1) : p = pi/180
end_if
xcentre = x%+10 : ycentre = lig_start%+3*lig_delta% : ' Coordonnées du centre de l'écran
for theta = 0 to 1.625*2*pi step p :' Nombre de tours, ici 10
x1 = theta*cos(theta) : y1 = theta*sin(theta) : ' Equation paramétrique d'une spirale
' Son équation polaire étant RHO = THETA
xp = x1+xcentre : yp = y1 + ycentre
2d_point xp,yp
next theta
2d_line xp,yp,xp+15,yp-30
xp = xp + 15 : yp = yp - 30
xcentre = xcentre + 3 : ycentre = ycentre - 40
for theta = 0.8*pi to pi+0.55*2*pi step p
x1 = 5*cos(theta) : y1 = 5*sin(theta)
xp = xcentre-x1 : yp = ycentre+y1
2d_point xp,yp
next theta
2d_line xp,yp,xp+3,yp+58
xp = xp + 3 : yp = yp + 58
xcentre = xp-5 : ycentre = yp
for theta = 0 to 1.5*pi step p
x1 = (1-theta/2.5/pi)*5*cos(theta) : y1 = (1-theta/2.5/pi)*5*sin(theta)
xp = xcentre+x1 : yp = ycentre+y1
2d_point xp,yp
next theta
2d_fill_color 0,0,0
2d_circle xcentre,ycentre,3
x% = x% + 30
return
copier:
clipboard_copy no_picture%
message "La portée a été copiée dans le presse-papier"
return
panoramic:
clear no_code_panoramic%
item_add no_code_panoramic%,"midi_on"
n% = 100
for i%=1 to n_notes%
if notes%(i%)=m1% then item_add no_code_panoramic%,"midi_instrument "+str$(durees%(i%))
if notes%(i%)=m2%
n% = durees%(i%)
item_add no_code_panoramic%,"midi_volume "+str$(n%)
end_if
if notes%(i%)=0
item_add no_code_panoramic%,"midi_volume 1"
item_add no_code_panoramic%,"midi_play 60,"+str$(durees%(i%))
item_add no_code_panoramic%,"midi_volume "+str$(n%)
end_if
if notes%(i%)>0 then item_add no_code_panoramic%,"midi_play "+str$(notes%(i%))+","+str$(durees%(i%))
next i%
item_add no_code_panoramic%,"midi_off"
' clipboard_copy no_code_panoramic%
' ?????????? début du code pour remplacer clipboard_copy
s$ = ""
for i%=1 to count(no_code_panoramic%)
s$ = s$ + item_read$(no_code_panoramic%,i%)+chr$(13)+chr$(10)
next i%
clipboard_string_copy s$
' ?????????? fin du code pour remplacer clipboard_copy
message "Le code Panoramic a été copié dans le presse-papier"
return
dessiner_instrument:
2d_fill_color 241,246,136
2d_line x%,lig_start%+7*lig_delta%,x%,lig_start%+9*lig_delta%
print_locate x%,lig_start% + 9*lig_delta%
font_size no_picture%,8
font_italic_off no_picture%
print "I"+str$(durees%(i%))
font_italic no_picture%
font_size no_picture%,12
2d_fill_color 0,0,0
return
dessiner_volume:
2d_fill_color 241,246,136
2d_line x%,lig_start%+7*lig_delta%,x%,lig_start%+8*lig_delta%
print_locate x%,lig_start% + 8*lig_delta%
font_size no_picture%,8
font_italic_off no_picture%
print "V"+str$(durees%(i%))
font_italic no_picture%
font_size no_picture%,12
2d_fill_color 0,0,0
return
dessiner_note:
if (notes%(i%)>54) and (notes%(i%)<87) : ' note dans la fourchette dessinable
gosub localiser_note
gosub dessiner_modificateur
select durees%(i%)
case 0
gosub dessiner_note_1
case 1
gosub dessiner_note_1
gosub dessiner_point
case 2
gosub dessiner_note_2
case 3
gosub dessiner_note_2
gosub dessiner_point
case 4
gosub dessiner_note_3
case 5
gosub dessiner_note_3
gosub dessiner_point
case 6
gosub dessiner_note_4
case 7
gosub dessiner_note_4
gosub dessiner_point
case 8
gosub dessiner_note_5
case 9
gosub dessiner_note_5
gosub dessiner_point
case 10
gosub dessiner_note_6
case 11
gosub dessiner_note_6
gosub dessiner_point
end_select
if lignes_audessus%>0 then gosub dessiner_lignes_audessus
if lignes_endessous%>0 then gosub dessiner_lignes_endessous
x% = x% + lig_delta% + lig_delta%
end_if
return
dessiner_modificateur:
if notes_origine%(i%,2)>0 then gosub dessiner_dieze
if notes_origine%(i%,2)<0 then gosub dessiner_bmol
return
dessiner_dieze:
2d_pen_width 2
2d_line x%+4,y%-lig_delta%*0.8,x%,y%+lig_delta%*0.8
2d_line x%+9,y%-lig_delta%*0.8,x%+5,y%+lig_delta%*0.8
2d_line x%,y%-2,x%+lig_delta%-1,y%-2
2d_line x%,y%+2,x%+lig_delta%-1,y%+2
2d_pen_width 1
x% = x% + lig_delta%
return
dessiner_bmol:
2d_fill_color 241,246,136
print_locate x%-3,y%-10
print "b"
2d_fill_color 0,0,0
x% = x% + lig_delta%+4
return
dessiner_lignes_audessus:
for j%=1 to lignes_audessus%
2d_line x%-2,lig_start%-j%*lig_delta%,x%+lig_delta%+2,lig_start%-j%*lig_delta%
next j%
return
dessiner_lignes_endessous:
for j%=1 to lignes_endessous%
2d_line x%-2,lig_start%+(j%+4)*lig_delta%,x%+lig_delta%+2,lig_start%+(j%+4)*lig_delta%
next j%
return
dessiner_pause:
gosub localiser_note
select durees%(i%)
case 0
gosub dessiner_pause_1
case 1
gosub dessiner_pause_1
gosub dessiner_point_1
case 2
gosub dessiner_pause_2
case 3
gosub dessiner_pause_2
gosub dessiner_point_1
case 4
gosub dessiner_pause_3
case 5
gosub dessiner_pause_3
gosub dessiner_point_1
case 6
gosub dessiner_pause_4
case 7
gosub dessiner_pause_4
gosub dessiner_point_1
case 8
gosub dessiner_pause_5
case 9
gosub dessiner_pause_5
gosub dessiner_point_1
case 10
gosub dessiner_pause_6
case 11
gosub dessiner_pause_6
gosub dessiner_point_1
end_select
x% = x% + lig_delta% + lig_delta%
return
' dessiner note 4 temps (1 entier)
dessiner_note_1:
2d_fill_color 255,255,255
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
2d_fill_color 0,0,0
return
' dessiner note 2 temps (1/2)
dessiner_note_2:
2d_fill_color 255,255,255
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
2d_fill_color 0,0,0
if notes%(i%)<72
2d_line x%+lig_delta%-1,y%,x%+lig_delta%-1,y%-3*lig_delta%
else
2d_line x%+1,y%,x%+1,y%+3*lig_delta%
end_if
return
' dessiner note 1 temps (1/4)
dessiner_note_3:
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
if notes%(i%)<72
2d_line x%+lig_delta%-1,y%,x%+lig_delta%-1,y%-3*lig_delta%
else
2d_line x%+1,y%,x%+1,y%+3*lig_delta%
end_if
return
' dessiner note 1/2 temps (1/8)
dessiner_note_4:
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
if notes%(i%)<72
2d_line x%+lig_delta%-1,y%,x%+lig_delta%-1,y%-3*lig_delta%
2d_pen_width 2
2d_line x%+lig_delta%-1,y%-3*lig_delta%,x%+2,y%-5*lig_delta%/2
2d_pen_width 1
else
2d_line x%+1,y%,x%+1,y%+3*lig_delta%
2d_pen_width 2
2d_line x%+1,y%+3*lig_delta%,x%+lig_delta%-2,y%+5*lig_delta%/2
2d_pen_width 1
end_if
return
' dessiner note 1/4 temps (1/16)
dessiner_note_5:
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
if notes%(i%)<72
2d_line x%+lig_delta%-1,y%,x%+lig_delta%-1,y%-3*lig_delta%
2d_pen_width 2
2d_line x%+lig_delta%-1,y%-3*lig_delta%,x%+2,y%-5*lig_delta%/2
2d_line x%+lig_delta%-1,y%-5*lig_delta%/2,x%+2,y%-2*lig_delta%
2d_pen_width 1
else
2d_line x%+1,y%,x%+1,y%+3*lig_delta%
2d_pen_width 2
2d_line x%+1,y%+3*lig_delta%,x%+lig_delta%-2,y%+5*lig_delta%/2
2d_line x%+1,y%+5*lig_delta%/2,x%+lig_delta%-2,y%+2*lig_delta%
2d_pen_width 1
end_if
return
' dessiner note 1/8 temps (1/32)
dessiner_note_6:
2d_circle x%+lig_delta%/2+1,y%,lig_delta%/2
if notes%(i%)<72
2d_line x%+lig_delta%-1,y%,x%+lig_delta%-1,y%-3*lig_delta%
2d_pen_width 2
2d_line x%+lig_delta%-1,y%-3*lig_delta%,x%+2,y%-5*lig_delta%/2
2d_line x%+lig_delta%-1,y%-5*lig_delta%/2,x%+2,y%-2*lig_delta%
2d_line x%+lig_delta%-1,y%-2*lig_delta%,x%+2,y%-3*lig_delta%/2
2d_pen_width 1
else
2d_line x%+1,y%,x%+1,y%+3*lig_delta%
2d_pen_width 2
2d_line x%+1,y%+3*lig_delta%,x%+lig_delta%-2,y%+5*lig_delta%/2
2d_line x%+1,y%+5*lig_delta%/2,x%+lig_delta%-2,y%+2*lig_delta%
2d_line x%+1,y%+2*lig_delta%,x%+lig_delta%-2,y%+3*lig_delta%/2
2d_pen_width 1
end_if
return
' dessiner pause 4 temps (1 entier)
dessiner_pause_1:
2d_fill_color 255,255,255
2d_rectangle x%+1,y%-lig_delta%/2,x%+lig_delta%,y%
2d_fill_color 0,0,0
return
' dessiner pause 2 temps (1/2)
dessiner_pause_2:
2d_fill_color 255,255,255
2d_rectangle x%+1,y%,x%+lig_delta%,y%+lig_delta%/2
2d_fill_color 0,0,0
return
' dessiner pause 1 temps (1/4)
dessiner_pause_3:
2d_line x%+1,y%-lig_delta%/2,x%+lig_delta%/2,y%+5*lig_delta%/2
2d_line x%+1,y%-lig_delta%/2,x%+lig_delta%/2+2,y%+lig_delta%/2-1
2d_circle x%+lig_delta%-2,y%,lig_delta%/3
return
' dessiner pause 1/2 temps (1/8)
dessiner_pause_4:
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+lig_delta%/2,y%+5*lig_delta%/2
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+1,y%+lig_delta%/2-1
2d_circle x%+2,y%,lig_delta%/3
return
' dessiner pause 1/4 temps (1/16)
dessiner_pause_5:
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+lig_delta%/2,y%+5*lig_delta%/2
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+1,y%+lig_delta%/2-1
2d_circle x%+2,y%,lig_delta%/3
2d_line x%+lig_delta%-1,y%+lig_delta%/2,x%+1,y%+3*lig_delta%/2-1
2d_circle x%+2,y%+lig_delta%,lig_delta%/3
return
' dessiner pause 1/8 temps (1/32)
dessiner_pause_6:
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+lig_delta%/2,y%+5*lig_delta%/2
2d_line x%+lig_delta%-1,y%-lig_delta%/2,x%+1,y%+lig_delta%/2-1
2d_circle x%+2,y%,lig_delta%/3
2d_line x%+lig_delta%-2,y%+lig_delta%/2,x%+1,y%+3*lig_delta%/2-1
2d_circle x%+2,y%+lig_delta%,lig_delta%/3
2d_line x%+lig_delta%-3,y%+3*lig_delta%/2,x%,y%+5*lig_delta%/2-1
2d_circle x%+2,y%+2*lig_delta%,lig_delta%/3
return
' dessiner un point
dessiner_point:
if frac(abs(y%-lig_start%)/lig_delta%)=0
gosub dessiner_point_2
else
gosub dessiner_point_1
end_if
return
' dessiner un point juste à droite
dessiner_point_1:
2d_circle x%+lig_delta%+2,y%,2
return
' dessiner un point à droite décalé vers le bas
dessiner_point_2:
2d_circle x%+lig_delta%+3,y%+4,2
return
localiser_note:
index_ligne% = table_vertical%(notes_origine%(i%,1),notes_origine%(i%,0))
y% = lig_start% + index_ligne%*lig_delta%/2
if index_ligne%<0
lignes_audessus% = int((0-index_ligne%)/2)
else
lignes_audessus% = 0
end_if
if index_ligne%>8
lignes_endessous% = int((index_ligne%-8)/2)
else
lignes_endessous% = 0
end_if
return
sel_instrument:
s$ = text$(no_instruments%)
if len(s$)>3
s$ = left$(s$,3)
if numeric(s$)=1
text no_ligne%,trim$(text$(no_ligne%)) + " i"+trim$(s$)
return
end_if
end_if
message "il faut choisir un instrument valide"
return
sel_volume:
s$ = str$(position(no_volume%))
text no_ligne%,trim$(text$(no_ligne%)) + " v"+trim$(s$)
return
clic_piano:
off_click no_piano%
2d_target_is no_piano%
x% = mouse_x_left_down(no_piano%)
y% = mouse_y_left_down(no_piano%)
if y%<20
on_click no_piano%, clic_piano
return : ' partie inactive
end_if
for i%=1 to 9 : ' identifier l'octave
if x%>piano_octaves%(i%,0)
if x%<piano_octaves%(i%,1)
octave% = i%
exit_for
end_if
end_if
next i%
if color_pixel_red(no_piano%,x%,y%)=0 : ' clic entre les touches
on_click no_piano%, clic_piano
return
end_if
if color_pixel_red(no_piano%,x%,y%)=1 : ' identifier touche blanche/noire
flag_noire% = 1
else
flag_noire% = 0
end_if
2d_flood x%,y%,255,0,0
j% = x% - piano_octaves%(octave%,0)
touche_blanche% = int((j%+largeur_blanche%-1)/largeur_blanche%)
if octave%=1 then touche_blanche% = touche_blanche% + 4
touche_noire%=0
if flag_noire%=1
if (touche_blanche%-1)*largeur_blanche%+largeur_blanche%*0.6<j%
touche_noire% = 1
else
touche_noire% = M1%
end_if
end_if
mark_on no_octaves%+octave%
mark_on no_notes%+touche_blanche%
if flag_noire%=1
if touche_noire%=1
mark_on no_modif%+2
else
mark_on no_modif%+3
end_if
else
mark_on no_modif%+1
end_if
gosub inserer
if flag_noire%=1
2d_flood x%,y%,1,0,0
else
2d_flood x%,y%,255,255,255
end_if
on_click no_piano%, clic_piano
return
inserer:
inactive no_inserer%
s1$ = ""
for i%=1 to 9
if checked(no_octaves%+i%)=1
s1$ = caption$(no_octaves%+i%)
exit_for
end_if
next i%
for i%=1 to 8
if checked(no_notes%+i%)=1
s1$ = s1$ + caption$(no_notes%+i%)
if i%=8 then s1$ = mid$(s1$,2,len(s1$))
exit_for
end_if
next i%
if right$(s1$,1)<>"p"
for i%=2 to 3
if checked(no_modif%+i%)=1
s1$ = s1$ + caption$(no_modif%+i%)
exit_for
end_if
next i%
end_if
s1$ = s1$ + left$(text$(no_duree%),1)
if checked(no_duree%+1)=1 then s1$ = s1$ + "."
if checked(no_ecoute_immediate%)=1
mode_immediat% = 1
s$ = s1$ + " "
n_notes% = 0
gosub compiler_immediat
gosub jouer
mode_immediat% = 0
end_if
text no_ligne%,trim$(trim$(text$(no_ligne%)) + " "+trim$(s1$))
active no_inserer%
return
transplus:
if count(no_partition%)=0
message "La partition est vide."
return
end_if
for i%=1 to count(no_partition%)
s$ = item_read$(no_partition%,i%) + " "
s2$ = ""
j% = instr(s$," ")
while j%>0
s1$ = left$(s$,j%-1)
s$ = mid$(s$,j%+1,len(s$))
if instr("ivp",left$(s1$,1))>0 : ' instrument, volume, pause
s2$ = s2$ + s1$ + " "
else : ' vraies notes
octave$ = left$(s1$,1)
octave% = instr(octaves$,octave$)
s1$ = mid$(s1$,2,len(s1$))
if left$(s1$,2)="do" then gosub tp1
if left$(s1$,2)="ré" then gosub tp1
if left$(s1$,2)="mi" then gosub tp2
if left$(s1$,2)="fa" then gosub tp1
if left$(s1$,3)="sol" then gosub tp1
if left$(s1$,2)="la" then gosub tp1
if left$(s1$,2)="si" then gosub tp3
end_if
j% = instr(s$," ")
end_while
item_delete no_partition%,i%
item_insert no_partition%,i%,trim$(s2$)
next i%
return
tp1: : ' note note suivi d'une noire
if instr(s1$,"b")>0 : ' en b-mol ? enlever le b-mol !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
if instr(s1$,"#")>0 : ' en # ? passer à la note supérieure sans modificateur !
j% = instr(liste_notes$,left$(s1$,2)) + 3
s2$ = s2$ + octave$+trim$(mid$(liste_notes$,j%,3))+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer en # !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-1)+"#"+right$(s1$,1)+" "
return
tp2: : ' note suivie d'une blanche
if instr(s1$,"b")>0 : ' en b-mol ? enlever le b-mol !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer à la note supérieure !
j% = instr(liste_notes$,left$(s1$,2)) + 3
s2$ = s2$ + octave$+trim$(mid$(liste_notes$,j%,3))+right$(s1$,1)+" "
return
tp3: : ' si: changement d'octave
if instr(s1$,"b")>0 : ' en b-mol ? enlever le b-mol !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer à do octave supérieure !
s2$ = s2$ + mid$(octaves$,octave%+1,1)+"do"+right$(s1$,1)+" "
return
transmoins:
if count(no_partition%)=0
message "La partition est vide."
return
end_if
for i%=1 to count(no_partition%)
s$ = item_read$(no_partition%,i%) + " "
s2$ = ""
j% = instr(s$," ")
while j%>0
s1$ = left$(s$,j%-1)
s$ = mid$(s$,j%+1,len(s$))
if instr("ivp",left$(s1$,1))>0 : ' instrument, volume, pause
s2$ = s2$ + s1$ + " "
else : ' vraies notes
octave$ = left$(s1$,1)
octave% = instr(octaves$,octave$)
s1$ = mid$(s1$,2,len(s1$))
if left$(s1$,2)="do" then gosub tm3
if left$(s1$,2)="ré" then gosub tm1
if left$(s1$,2)="mi" then gosub tm1
if left$(s1$,2)="fa" then gosub tm2
if left$(s1$,3)="sol" then gosub tm1
if left$(s1$,2)="la" then gosub tm1
if left$(s1$,2)="si" then gosub tm1
end_if
j% = instr(s$," ")
end_while
item_delete no_partition%,i%
item_insert no_partition%,i%,trim$(s2$)
next i%
return
tm1: : ' note note précédée d'une noire
if instr(s1$,"#")>0 : ' en # ? enlever le # !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
if instr(s1$,"b")>0 : ' en b-mol ? passer à la note inférieure sans modificateur !
j% = instr(liste_notes$,left$(s1$,2)) - 3
s2$ = s2$ + octave$+trim$(mid$(liste_notes$,j%,3))+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer en b-mol !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-1)+"b"+right$(s1$,1)+" "
return
tm2: : ' note précédée d'une blanche
if instr(s1$,"#")>0 : ' en # ? enlever le # !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer à la note inférieure !
j% = instr(liste_notes$,left$(s1$,2)) - 3
s2$ = s2$ + octave$+trim$(mid$(liste_notes$,j%,3))+right$(s1$,1)+" "
return
tm3: : ' si: changement d'octave
if instr(s1$,"#")>0 : ' # ? enlever le #l !
s2$ = s2$ + octave$+left$(s1$,len(s1$)-2)+right$(s1$,1)+" "
return
end_if
: ' ici en note simple - passer à si octave inférieure !
s2$ = s2$ + mid$(octaves$,octave%-1,1)+"si"+right$(s1$,1)+" "
return
speedplus:
n% = 1
gosub speed
return
speedmoins:
n% = m1%
gosub speed
return
speed:
if count(no_partition%)=0
message "La partition est vide."
return
end_if
for i%=1 to count(no_partition%)
s$ = item_read$(no_partition%,i%) + " "
s2$ = ""
j% = instr(s$," ")
while j%>0
s1$ = left$(s$,j%-1)
s$ = mid$(s$,j%+1,len(s$))
if instr("iv",left$(s1$,1))>0 : ' instrument, volume, pause
s2$ = s2$ + s1$ + " "
else : ' vraies notes
if right$(s1$,1)="."
k% = val(mid$(s1$,len(s1$)-1,1)) + n%
if k%<1 or k%>6
s2$ = s2$ + s1$ + " "
else
s2$ = s2$ + left$(s1$,len(s1$)-2)+str$(k%) + ". "
end_if
else
k% = val(right$(s1$,1))+n%
if k%<1 or k%>6
s2$ = s2$ + s1$ + " "
else
s2$ = s2$ + left$(s1$,len(s1$)-1)+str$(k%) + " "
end_if
end_if
end_if
j% = instr(s$," ")
end_while
item_delete no_partition%,i%
item_insert no_partition%,i%,trim$(s2$)
next i%
return
Accueil 
Calendrier
Dommage que l'on ne puisse pas utiliser le midi sans ralentir les programmes sinon en jonglant avec un timer on pourrait faire des mélodies pendant les jeux en musique de fond .... 
