[color=blue][size=18]Salut a tous[/size][/color]
Voici mon premier [color=green]tutoriel[/color] qui sert à [color=green]apprendre[/color] à utiliser la [color=green]3D[/color] dans panoramic.
Tout le monde peut le lire car je vais partir de zero.
[size=18][b][u]I Comment faire la 3D?[/u][/b][/size]
Déjà il faut crée une scène 3D par la commande:
[code]scene3D 1[/code]
Il est preferable d'utiliser la commande full_space pour mettre tout l'espace disponible à la scène 3D
[code]scene3D 1
full_space 1
[/code]
Voir avec un plein écran:
[code]full_space 0
scene3D 1
full_space 1
[/code]
On peut changer la couleur de fond par la commande color.
[code]full_space 0
scene3D 1
full_space 1
color 1,0,0,255[/code]
Par défaut la couleur est blanche. (soit color 1,0,0,0)
On peut également activer les axes de couleurs
(X pour le rouge, Y pour le vert et bleu pour le Z:
[code]full_space 0
scene3D 1
full_space 1
color 1,0,0,255
axes_show [/code]
Toutes les commandes de 3D sont automatiquement transmise a la première scène3D crée. Si vous avez plus de une scène 3D, il faudra rajouter la commande [color=blue]3D_target_is n[/color]. Mais ne vous prenez pas la tête avec cela pour le moment ;)
[size=18][b][u]II La lumière[/u][/b][/size]
Une lumière est automatiquement crée a la création de la scène3D.
Elle est unique et on peut régler sa position par la commande light_position
[code]full_space 0
scene3D 1
full_space 1
color 1,0,0,255
light_position 0,1000,0 : ' La lumière est en haut
3d_teapot 1 : 3d_z_position 1,4 : ' (on vera ce qu'il y a à gauche plus tard.)[/code]
Si il n'y a pas de lumière, tout les objets (non texturer) seraient noire.
[color=red]Attention>[/color] Il [color=red]n'[/color]y a [color=red]PAS[/color] l'effet de: plus la lumière est loin et moins il y a de lumière. Vous me suivez?
[code]full_space 0
scene3D 1
full_space 1
color 1,0,0,255
light_position 0,10000000000,0 : ' La lumière est très haute mais il y a la même FORCE de lumière!
3d_teapot 1 : 3d_z_position 1,4 : ' (on vera ce qu'il y a à gauche plus tard.)[/code]
[size=18][u][b]III Les axes[/b][/u][/size]
Rappel: une scène2D a deux axes le X et le Y.
Plus le X est important, plus on va vers la droite.(Si le X est NUL alors on est a l’extrême gauche)
Plus le Y est important, plus on va vers le bas.(Si le Y est NUL alors on est a l’extrême haut)
Il n'y a donc pas de chiffre négatif ici.
Pour la scene3D, ce n'est pas le cas. On peut avoir des nombre négatif. En 3D les axes sont le X, Y, et Z.
:arrow: Le centre du monde 3D est la position ou les valeurs X,Y,Z sont égale a 0.
[url=http://www.servimg.com/image_preview.php?i=20&u=15821527][img]http://i22.servimg.com/u/f22/15/82/15/27/dsc00710.jpg[/img][/url]
[color=red]Attention [/color]certain vont être surprit:
[u]Le plus courent[/u] est le système de coordonnées [color=green]main gauche[/color]. Comme panoramic donc!
Mais blender n'est pas conventionnel, luis, il est en système main droite!
Donc le Y représente la hauteur dans panoramic quand c'est le z dans blender!
Ce problème se contourne facilement mais on fera cela plus tard.
[size=18][u][b]IV La caméra[/b][/u][/size]
Déjà, comment caractériser un point en 3D?
Il est caractériser par sa position X,Y et Z.
Imaginons un premier point dans la scène 3D.
[img]http://www.archive-host.com/files/1015616/bd7172de063197f3c62f696d7c6d6278409a0e82/11.jpg[/img]
Imaginons un second point
[img]http://www.archive-host.com/files/1015619/bd7172de063197f3c62f696d7c6d6278409a0e82/12.jpg[/img]
En créant en premier le[color=red] point 1[/color] et ensuite le [color=red]point 2[/color] on devine une [color=green]direction[/color]:
[img]http://www.archive-host.com/files/1015623/bd7172de063197f3c62f696d7c6d6278409a0e82/13.jpg[/img]
1>Maintenant il suffit juste de comprendre que le [color=red]point 1[/color] représente la camera. ;)
2>Et que le [color=red]point 2[/color] représente le point de viser.:lol:
1>Pour modifier la position de la camera (soit le [color=red]point 1[/color] sur mon schéma) , il y a la commande cam_position x,y,z
2>Pour modifier le point de viser (soit le [color=red]point 2[/color] sur mon schéma), il y a la commande point_position x,y,z
La camera regarde toujours le point de viser.
Je vous expliquerais comment se déplacer en 3D plus tard.
[size=18][u][b]V Les objets 3D[/b][/u][/size]
Quand on crée un objet dans panoramic, on luis attribut un numéro de suivi.
Exemple: [code]scene3D 1 : ' Le numéro est le 1 ici[/code]
On [color=red]ne [/color]peut [color=red]pas [/color]avoir 2 objet au même numéro.
Exemple: [code]scene3D 1
scene3D 1 : ' L'erreur est ici[/code]
En 3D, [u]c'est pareil[/u]. Il [color=red]ne[/color] peut [color=red]pas [/color]y avoir 2 objet 3D au même numéro.
En créant une scène 3D, on pourrait croire que si on est a:
[code]scene3D 1[/code]
Qu'il faut continuer par:
[code]scene3D 1
3d_teapot 2 [/code]
Mais c'est [color=red]faux [/color]car [color=green]les numeros de suivi des objets sont séparé des numeros de suivi des objets 3D![/color]
[code]full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3d_teapot 1 : ' le numero 1 marche
' Les numeros de suivi des objets sont séparé des numeros de suivi des objets 3D![/code]
Ce qui est [color=green]cool [/color]dans panoramic, c'est que l'on peut crée des objets 3D basic très facilement!
Il suffi juste de mettre les paramètres propre a l'objet3D que l'on veu crée. (comme la longueur d'un côté pour un cube ou le rayon pour une sphere ;))
[code]full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3d_torus 1,2,0.5
' regarder les exemples inclut dans panoramic dans aide/Manuel de référence
' Choisisser les bonnes commandes et appuyer sur charger l'exemple ;)[/code]
[u]Les objets de panoramic[/u]
[color=blue]3d_box
3d_cone
3d_cube
3d_cylinder
3d_dodecahedron
3d_line (3d_line_width)
3d_plane
3d_sphere
3d_teapot
3d_text (3d_text_change)
3d_torus[/color]
Pour importer des objet on verra les commandes plus tard
On peut également les [b]supprimer ces objet 3D[/b]!
Il y a 2 commandes, la première pour supprimer 1 objet3D en particulier ([color=blue]3d_delete n[/color]) l'autre pour supprimer tout les objets de la scene d'un coup ([color=blue]3d_delete_all[/color])
[u]Exemple:[/u]
[code]full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3d_torus 1,2,0.5
wait 3000
3d_delete 1 : ' le numero de suivie numero 1 est anssi libéré
3d_sphere 1,1 : ' le numero de suive peut donc être 1.
wait 3000
3d_sphere 2,1 : 3d_x_position 2,3 : ' création d'une autre sphere
wait 3000
3d_delete_all : ' tout les objet 3D sont maintenant supprimer[/code]
Ce qui est encore [b][color=green]plus cool[/color][/b], c'est que l'on peut importer des objets 3D que l'on a crée!
Mais [color=red]attention [/color]que cela soit au bon format. Les extensions qui fonctionne sont *.MD2 et *.3DS
Beaucoup de logiciel de 3D supporte ces format comme blender, 3D Studio Max...
L'erreur a ne pas commettre sur les formats, c'est de confondre [u]enregistrer sous[/u] et [u]exporter[/u]!
Par exemple Blender a comme format *.blend alors qu'en faite dans: Fichier/exporter ; il y a tout plein d’extension différente.
Si vous n'avez pas de logiciel de 3D je vous recommande très fortement Blender.
Pour [color=blue]apprendre [/color]a utiliser [color=blue]blender[/color] (Partie I et Partie II [color=green]suffise[/color].)
[url=http://www.siteduzero.com/tutoriel-3-11714-debutez-dans-la-3d-avec-blender.html]http://www.siteduzero.com/tutoriel-3-11714-debutez-dans-la-3d-avec-blender.html[/url]
[color=red]Attention:[/color]Les [color=green]numéro d'objet 3D[/color] est la lettre [color=green]n[/color] (ou [color=green]N[/color]) dans toute les commandes qui vienne.
[size=18][u][b]VI Position, rotation, dimension[/b][/u][/size]
Pour déplacer les objets dans l'espace, il y a la commande:
[code]3D_position n,x,y,z[/code]
Cette commande est utile pour initialiser la position de l'objet au début du code.
Pour déplacer que sur un axe en particulier il y a les 3 commandes:
[code]3D_x_position n,x
3D_y_position n,y
3D_z_position n,z[/code]
[u]Exemple:[/u]
[code]Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3d_teapot 1
message "Avant d'initialiser la position"
3d_position 1,3,0,1
' apres[/code]
Il est bien de pouvoir déplacer un objet, encore faut il connaître sa position. Les commandes sont:
[code]O3D_X_position(n)
O3D_Y_position(n)
O3D_Z_position(n)[/code]
[u]Exemple:[/u]
[code]Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3d_teapot 1
message O3d_x_position(1)
message O3d_y_position(1)
message O3d_z_position(1)
3d_position 1,3,-1,1
message O3d_x_position(1)
message O3d_y_position(1)
message O3d_z_position(1)[/code]
Il y a également une commande qui permet de déplacer les objets mais elle est un peu spécial.
Tout les objets ont un sens. Dans blender c'est l'axe Z positif ([color=blue]Z+[/color]) ce qui correspond au Y+ dans panoramic.
Par exemple, sur blender, l'avant de la voiture doit être positionner vers l'axe [color=blue]z+[/color] pour que la voiture avance normalement sur panoramic.
[img]http://www.archive-host.com/files/1022066/bd7172de063197f3c62f696d7c6d6278409a0e82/szfegtr.JPG[/img]
Cette commande est génial, on donne juste le numéro de l'objet et la vitesse et l'objet avance!
[u]Exemple:[/u]
[code]' Utiliser les touches fléchés
full_space 0
label prog , touche_enfoncer , touche_lacher : ' déclaration des sous-programme
dim touche_gauche , touche_haut , touche_droit , touche_bas : ' déclaration des variables
dim vitesse
vitesse=0.03 : ' la vitesse de déplacement
scene3D 1 : full_space 1 : color 1,0,0,255 : ' création de la scene 3D
3d_cube 1,1 : 3d_rotate 1,0,45,0 : ' création du cube
timer 2 : timer_interval 2,1 : on_timer 2,prog : ' création du timer (en dernier pour eviter les bugs)
on_key_down 0,touche_enfoncer : ' evenement si on enfonce une touche
on_key_up 0,touche_lacher : ' evenement si on lache une touche
end : ' fin du programme, place aux evenements
prog:
if key_down_code=27 : ' si on appui sur echap (quitter)
timer_off_all : ' destruction de tout les timers
terminate
end_if
if touche_haut=1
3d_move 1,vitesse : ' On donne la vitesse :)
end_if
if touche_bas=1
3d_move 1,0-vitesse : ' 0-la vitesse
end_if
if touche_gauche=1
3d_y_rotate 1,o3d_y_rotate(1)+2
end_if
if touche_droit=1
3d_y_rotate 1,o3d_y_rotate(1)-2
end_if
return
touche_enfoncer:
if key_down_code = 37 then touche_gauche=1
if key_down_code = 38 then touche_haut=1
if key_down_code = 39 then touche_droit=1
if key_down_code = 40 then touche_bas=1
return
touche_lacher:
if key_up_code = 37 then touche_gauche=0
if key_up_code = 38 then touche_haut=0
if key_up_code = 39 then touche_droit=0
if key_up_code = 40 then touche_bas=0
return[/code]
Si vous ne comprenez pas tout c'est pas grave. Vous devez simplement comprendre 3D_move et 3d_position ;)
[u]Les rotations[/u]
Pour mettre la rotation a un objet, il y a la commande [color=blue]3D_rotate N,x,y,z[/color]. Pour réglé les rotations sur l'un des 3 axes séparément, il y a les 3 commandes:
[code]3D_x_rotate n,x
3D_y_rotate n,y
3D_z_rotate n,z[/code]
Comme vous vous en douter, les [b]rotation [/b]vont de 0 à 360 oui mais:
Si on donne une rotation a (360+90=450) 450,c'est comme si on donner une rotation de 90.
[u]Exemple:[/u]
[code]Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255
3d_teapot 1 : 3d_position 1,-1,0,3 : ' une teapot a gauche
3d_teapot 2 : 3d_position 2,1,0,3 : ' l'autre a droite
3d_y_rotate 1,450 : ' la rotation fonctionne (même si c'est plus grand que 360)
3d_y_rotate 2,90 : ' il on la même rotation au final. (360+90=450)[/code]
Pour connaître la rotation d'un objet:
[code]O3D_x_rotate(n)
O3D_y_rotate(n)
O3D_z_rotate(n)[/code]
[size=18]Ce qui va suivre avec les rotations est très important à assimiler.[/size]
Les rotations dans panoramic sont local. [i]Et cela veux dire quoi?[/i] Je vais vous l'expliquez en 3 images:
Voila un cube dans panoramic disons.(même si l'on devine blender!)
[img]http://www.archive-host.com/files/1022299/bd7172de063197f3c62f696d7c6d6278409a0e82/111.JPG[/img]
Si on fait une rotation sur le côté vert cela donnera:
[img]http://www.archive-host.com/files/1022303/bd7172de063197f3c62f696d7c6d6278409a0e82/333.JPG[/img]
[color=red]Et non cela![/color]
[img]http://www.archive-host.com/files/1022304/bd7172de063197f3c62f696d7c6d6278409a0e82/222.JPG[/img]
Vous comprenez?
[u]Exemple:[/u]
[code]label changer_rotation_local , changer_rotation_globale
dim rotation_x_globale , rotation_y_globale , rotation_z_globale
Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
scroll_bar 2 : min 2,0 : max 2,360 : width 2,300 : top 2,20 : left 2,20 : hint 2,"X local"
scroll_bar 3 : min 3,0 : max 3,360 : width 3,300 : top 3,40 : left 3,20 : hint 3,"Y local"
scroll_bar 4 : min 4,0 : max 4,360 : width 4,300 : top 4,60 : left 4,20 : hint 4,"Z local"
scroll_bar 5 : min 5,0 : max 5,360 : width 5,300 : top 5,20 : left 5,screen_x/2 : hint 5,"X globale"
scroll_bar 6 : min 6,0 : max 6,360 : width 6,300 : top 6,40 : left 6,screen_x/2 : hint 6,"Y globale"
scroll_bar 7 : min 7,0 : max 7,360 : width 7,300 : top 7,60 : left 7,screen_x/2 : hint 7,"Z globale"
3d_teapot 1 : 3D_color 1,0,255,0 : 3d_scale 1,4,4,4 : 3d_x_position 1,-3
3d_teapot 2 : 3D_color 2,255,0,0 : 3d_scale 2,4,4,4 : 3d_x_position 2,3
on_change 2,changer_rotation_local
on_change 3,changer_rotation_local
on_change 4,changer_rotation_local
on_change 5,changer_rotation_globale
on_change 6,changer_rotation_globale
on_change 7,changer_rotation_globale
end
changer_rotation_local:
3D_rotate 1,position(2),position(3),position(4)
return
changer_rotation_globale:
rotation_x_globale=position(5)
rotation_y_globale=position(6)
rotation_z_globale=position(7)
3d_z_rotate 2,0
3d_y_rotate 2,0
3D_x_rotate 2,0
3d_rotate 2,rotation_x_globale,rotation_y_globale,rotation_z_globale
return[/code]
Changer les rotations des 2 teapots dans tout les sens, et remetter les a 0.
Celui de gauche est local, (parfait pour une voiture,avion,etc) il est dans n'importe quel sens.
Celui de droite est globale (il a reprit sa position d'origine) et vous voulez une globale, vous savez maintenant comment faire pour l'utiliser (regarder l'exemple)
Il y a également une autre commande pour donner la rotation a un objet: [color=blue]3d_point_object n1,n2[/color]
[u]Exemple:[/u]
[code]' utiliser les touches fléché
' regarder la ligne <aaaaaaaaaaaa plus bas
full_space 0
label prog , touche_enfoncer , touche_lacher : ' déclaration des sous-programme
dim touche_gauche , touche_haut , touche_droit , touche_bas : ' déclaration des variables
dim vitesse
vitesse=0.03 : ' la vitesse de déplacement
scene3D 1 : full_space 1 : color 1,0,0,255 : ' création de la scene 3D
3d_cube 1,1 : 3d_rotate 1,0,45,0 : 3d_color 1,0,255,0 : ' création du cube allier
3d_cube 2,1 : 3d_position 2,-2,0,1 : 3d_color 2,255,0,0 : ' création de l'ennemi :)
timer 2 : timer_interval 2,1 : on_timer 2,prog : ' création du timer (en dernier pour eviter les bugs)
on_key_down 0,touche_enfoncer : ' evenement si on enfonce une touche
on_key_up 0,touche_lacher : ' evenement si on lache une touche
end : ' fin du programme, place aux evenements
prog:
3D_point_object 2,1 : ' L'ennemi te regarde <aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa
if key_down_code=27 : ' si on appui sur echap (quitter)
timer_off_all : ' destruction de tout les timers
terminate
end_if
if touche_haut=1
3d_move 1,vitesse : ' On donne la vitesse :)
end_if
if touche_bas=1
3d_move 1,0-vitesse : ' 0-la vitesse
end_if
if touche_gauche=1
3d_y_rotate 1,o3d_y_rotate(1)+2
end_if
if touche_droit=1
3d_y_rotate 1,o3d_y_rotate(1)-2
end_if
return
touche_enfoncer:
if key_down_code = 37 then touche_gauche=1
if key_down_code = 38 then touche_haut=1
if key_down_code = 39 then touche_droit=1
if key_down_code = 40 then touche_bas=1
return
touche_lacher:
if key_up_code = 37 then touche_gauche=0
if key_up_code = 38 then touche_haut=0
if key_up_code = 39 then touche_droit=0
if key_up_code = 40 then touche_bas=0
return[/code]
Cette commande peut servir a pointé quelque chose sur quelqu'un.
[u]La dimension[/u]
[i]A quoi sa sert?[/i] très concrètement, c'est très utile pour mettre tout les objets a la même échelle. Dans l’extrême on aurais une voiture plus grand que le circuit ou un immeuble de la taille d'une chaussure! :D
Il y a la commande[color=blue] 3D_scale n,x,y,z[/color].Il y a également la possibilité de faire comme la rotation et la position, le changement par un axe en particulier:
[code]3d_x_scale n,x
3d_y_scale n,y
3d_z_scale n,z[/code]
La donné attendu est un coefficient multiplicateur, donc c'est comme pour les pourcentages:
50%=0.5 20%=0.2 1%=0.01 100%=1
Donc pour réduire un objet de 50% mettre 0.5 (soit 1/2)
On peut aussi l'augmenter ! > 150%=1.5 300%=3 1000%=10
[u]Exemple:[/u]
[code]Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255
3d_teapot 1
wait 2000
3D_color 1,255,0,0 : ' il devient rouge
3d_scale 1,1,1,1 : ' revient a modifier la taille de lobjet a 100% soit il ne change pas!
wait 2000
3D_color 1,0,255,0 : ' il devient vert
3d_scale 1,5,5,5 : ' 5=500% il grossis
wait 2000
3D_color 1,0,0,255 : ' il devient bleu
3d_scale 1,1,1,1 : ' il reprend sa taille d'origine[/code]
Conclusion:
si le coefficient multiplicateur < 1 il rétréci par rapport a sa taille d'origine
si le coefficient multiplicateur = 1 il est égale par rapport a sa taille d'origine
si le coefficient multiplicateur > 1 il se dilate par rapport a sa taille d'origine
Cette commande est également utile pour faire certaine animation: (une explosion). Notre objet explosion a une toute petite taille et plus le temps s'écoule, plus cette objet gonfle. :afro:
Pour connaître la dimension de notre objet:
[code]O3D_x_scale(n)
O3D_y_scale(n)
O3D_z_scale(n)[/code]
[size=18][b][u]VII Autres commandes 3D utiles:[/u][/b][/size]
Il y a la commande [color=blue]3D_color n,r,v,b[/color] pour changer la couleur de l'objet. Par default la couleur est noire. Si r=v=b alors la couleur est grise. (de 0 a 255 pour le rouge, le vert et le bleu)
On peut changer la transparence d'un objet par la commande [color=blue]3D_transparent N,intensité[/color] (de 0 a 255)
Cette commande est utile pour faire les vitres, l'eau, le feu, nuage ,etc...
On peut aussi cacher les objets directement par la commande [color=blue]3D_hide n[/color]
Cette commandes servira pour les collisions en particulier. On refait apparetre l'objet avec la commandes [color=blue]3D_show n[/color]
[u]Exemple:[/u]
[code]Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position 0,1000,0
3D_teapot 1 : 3d_scale 1,7,7,7
message "couleur rouge"
3D_color 1,255,0,0
message "Tranparence"
3d_transparent 1,80
message "cacher"
3D_hide 1
message "reafficher"
3D_show 1[/code]
[size=18][b][u]VIII Comment organiser son programme pour faire de la 3D :?:[/u][/b][/size]
Pour faire un programme en 3D, les commandes de 3D sont insuffisant:
1)Il faut géré les touches appuyer
2)Il faut une partie de code qui s’exécute tout le temps. (Pour qu'un ennemie se déplace, pour faire bouger l'eau... )
3)Crée les objet 3D et les autres objet.
[u]Voici la structure la mieux adapté pour le moment:[/u]
[code]error_french
label programme , touche_enfoncer , touche_lacher : ' (les label c'est là)
' dim (les déclarations de variable c'est ici)
' PROGRAMME PRINCIPALE##########################################################
' (Ici on crée la scene, on met les objets etc...)
' PROGRAMME PRINCIPALE#######################################################FIN
timer 1 : timer_interval 1,1 : on_timer 1,programme
on_key_down 0,touche_enfoncer : ' si on appui sur une touche alors on va a touche_enfoncer
on_key_up 0,touche_lacher : ' si on LACHE sur une touche alors on va a touche_lacher
end : ' LES SOUS PROGRAMMES#####################################################
touche_enfoncer:
' ici on vérifi si une touche est enfoncer
return
touche_lacher:
' ici on vérifi si une touche est lacher
return
programme:
' (ici c'est executer tout les 1/1000 de seconde. donc tout le temp,
' cela sert a effectuer une action si une touche est enfoncer)
return
' LES SOUS PROGRAMMES########################################################FIN
' A savoir> si on met le programme en pause, il faut desactiver le timer par timer_off 1
' et le réactivé par timer_on 1 à la fin de la pause.[/code]
[b][color=red]Voici un exemple concret:[/color][/b]
[code]error_french
label programme , touche_enfoncer , touche_lacher
dim touche_gauche , touche_haut , touche_droit , touche_bas
dim vitesse
' PROGRAMME PRINCIPALE##########################################################
vitesse=0.03 : ' la vitesse de déplacement
full_space 0
scene3D 2 : full_space 2 : color 2,0,0,255 : ' création de la scene 3D
3d_cube 1,1 : 3d_rotate 1,0,45,0 : ' création du cube
' PROGRAMME PRINCIPALE#######################################################FIN
timer 1 : timer_interval 1,1 : on_timer 1,programme
on_key_down 0,touche_enfoncer : ' si on appui sur une touche alors on va a touche_enfoncer
on_key_up 0,touche_lacher : ' si on LACHE sur une touche alors on va a touche_lacher
end : ' LES SOUS PROGRAMMES#####################################################
touche_enfoncer:
if key_down_code = 37 then touche_gauche=1
if key_down_code = 38 then touche_haut=1
if key_down_code = 39 then touche_droit=1
if key_down_code = 40 then touche_bas=1
return
touche_lacher:
if key_up_code = 37 then touche_gauche=0
if key_up_code = 38 then touche_haut=0
if key_up_code = 39 then touche_droit=0
if key_up_code = 40 then touche_bas=0
return
programme:
if key_down_code=27 : ' si on appui sur echap (quitter)
timer_off_all : ' destruction de tout les timers
terminate
end_if
if touche_haut=1
3d_move 1,vitesse : ' On donne la vitesse :)
end_if
if touche_bas=1
3d_move 1,0-vitesse : ' 0-la vitesse
end_if
if touche_gauche=1
3d_y_rotate 1,o3d_y_rotate(1)+2
end_if
if touche_droit=1
3d_y_rotate 1,o3d_y_rotate(1)-2
end_if
return
' LES SOUS PROGRAMMES########################################################FIN[/code]
[size=18][b][u]IX Comment se déplacer dans une scène 3D :?:[/u][/b][/size]
Pour ce déplacer en 1er personne, il y a une solution qui fonctionne sans formule mathématiques mais par de la logique.
[i]rappel: Pour utiliser la camera, il y a 2 point, la position x,y,z de la camera et la position x,y,z du point de visé.[/i]
Pour la soluce, nous allons utiliser 2 cubes:
La position du [color=green]cube numéro 1[/color] sera la position de la [color=green]camera[/color].
La position du [color=green]cube numéro 2[/color] sera la position du [color=green]point de viser[/color].
(Il serons cacher par [color=blue]3D_hide n[/color] pour que l'on ne les vois pas)
[img]http://www.archive-host.com/files/1034083/bd7172de063197f3c62f696d7c6d6278409a0e82/exemple_camera.jpg[/img]
Dans le programme, (celui qui s’exécute tout le temps par le timer)
nous allons luit faire effectuer les [color=green]4[/color] opérations suivantes:
[color=green]1)[/color] Le cube 2 va prendre la même [b]position[/b] et[b] rotation[/b] que le cube 1. (les deux cubes sont emboiter l'un dans l'autre)
[color=green]2)[/color] On avance le cube 2 par la commande [color=blue]3D_move 2,1[/color]
[color=green]3)[/color] On change la position du point de visé qui devient la position du cube 2,
[color=green]4)[/color] On change la position de la caméra qui devient la position du cube 1.
Si on veux déplacer la camera, il suffit de déplacer la position du cube 1 (par [color=blue]3D_move 1,vitesse[/color] par exemple)
Si on veux tourner la caméra, il suffit de mettre une rotation au cube 1.
[u]Exemple 1:[/u]
[code]
error_french
label actualiser_vue
' PROGRAMME PRINCIPALE##########################################################
Full_space 0
scene3D 1 : full_space 1 : color 1,0,0,255 : light_position -100,50,-200
cam_position 2,0,-2
3D_cube 1,1 : 3d_color 1,255,0,0 : 3d_transparent 1,50 : ' C'est la caméra
3d_cube 2,1 : 3d_color 2,0,255,0 : 3d_transparent 2,50 : ' C'est le point de visé
3d_position 1,-2,0,-1 : ' je met le cube 1 n'importe comment pour comprendre
3d_rotate 1,45,0,45 : ' je met le cube 1 n'importe comment pour comprendre
gosub actualiser_vue
' PROGRAMME PRINCIPALE#######################################################FIN
end : ' LES SOUS PROGRAMMES#####################################################
actualiser_vue:
' 1) etape 1
wait 2000
3d_position 2,o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
wait 2000
3d_rotate 2,o3d_x_rotate(1),o3d_y_rotate(1),o3d_z_rotate(1)
' 2) etape 2
wait 2000
3d_move 2,1.5
' 3)4) etape 3 et 4 (je l'ai est pas activer exprès):
' point_position o3d_x_position(2),o3d_y_position(2),o3d_z_position(2)
' cam_position o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
return
' LES SOUS PROGRAMMES########################################################FIN[/code]
[b]La camera est le cube [color=red]rouge[/color], le point de viser le [color=green]vert[/color].[/b]
[u]Exemple 2:[/u]
[code]
error_french
label programme , touche_enfoncer , touche_lacher , actualiser_vue
dim touche_gauche , touche_haut , touche_droit , touche_bas
dim vitesse_rotation , vitesse_deplacement
' PROGRAMME PRINCIPALE##########################################################
vitesse_rotation=2
vitesse_deplacement=0.02
Full_space 0
scene3D 2 : full_space 2 : color 2,0,0,255 : light_position 0,1000,0
3D_cube 1,1 : 3d_color 1,255,0,0 : 3d_transparent 1,50 : ' C'est la caméra
3d_cube 2,1 : 3d_color 2,0,255,0 : 3d_transparent 2,50 : ' C'est le point de visé
gosub actualiser_vue
' PROGRAMME PRINCIPALE#######################################################FIN
timer 1 : timer_interval 1,1 : on_timer 1,programme
on_key_down 0,touche_enfoncer
on_key_up 0,touche_lacher
end : ' LES SOUS PROGRAMMES#####################################################
touche_enfoncer:
if key_down_code = 37 then touche_gauche=1
if key_down_code = 38 then touche_haut=1
if key_down_code = 39 then touche_droit=1
if key_down_code = 40 then touche_bas=1
return
touche_lacher:
if key_up_code = 37 then touche_gauche=0
if key_up_code = 38 then touche_haut=0
if key_up_code = 39 then touche_droit=0
if key_up_code = 40 then touche_bas=0
return
actualiser_vue:
3d_position 2,o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
3d_rotate 2,o3d_x_rotate(1),o3d_y_rotate(1),o3d_z_rotate(1)
3d_move 2,1.5
' point_position o3d_x_position(2),o3d_y_position(2),o3d_z_position(2)
' cam_position o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
return
programme:
if key_down_code=27 : ' si on appui sur echap (quitter)
timer_off_all : ' destruction de tout les timers
terminate
end_if
if touche_haut=1
3d_move 1,vitesse_deplacement : ' On donne la vitesse_deplacement :)
end_if
if touche_bas=1
3d_move 1,0-vitesse_deplacement : ' 0-la vitesse_deplacement
end_if
if touche_gauche=1
3d_y_rotate 1,o3d_y_rotate(1)+vitesse_rotation
end_if
if touche_droit=1
3d_y_rotate 1,o3d_y_rotate(1)-vitesse_rotation
end_if
gosub actualiser_vue
return
' LES SOUS PROGRAMMES########################################################FIN[/code]
[u]Exemple 3:[/u]
[code]error_french
label programme , touche_enfoncer , touche_lacher , actualiser_vue
dim touche_gauche , touche_haut , touche_droit , touche_bas
dim vitesse_rotation , vitesse_deplacement
' PROGRAMME PRINCIPALE##########################################################
vitesse_rotation=2
vitesse_deplacement=0.01
Full_space 0
scene3D 2 : full_space 2 : color 2,0,0,255 : ' light_position 0,1000,0
3D_cube 1,1 : 3D_hide 1 : ' ON LES CACHES
3d_cube 2,1 : 3D_hide 2 : ' ON LES CACHES
3d_teapot 3 : 3d_position 3,0,0,1.5
gosub actualiser_vue
' PROGRAMME PRINCIPALE#######################################################FIN
timer 1 : timer_interval 1,1 : on_timer 1,programme
on_key_down 0,touche_enfoncer
on_key_up 0,touche_lacher
end : ' LES SOUS PROGRAMMES#####################################################
touche_enfoncer:
if key_down_code = 37 then touche_gauche=1
if key_down_code = 38 then touche_haut=1
if key_down_code = 39 then touche_droit=1
if key_down_code = 40 then touche_bas=1
return
touche_lacher:
if key_up_code = 37 then touche_gauche=0
if key_up_code = 38 then touche_haut=0
if key_up_code = 39 then touche_droit=0
if key_up_code = 40 then touche_bas=0
return
actualiser_vue:
3d_position 2,o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
3d_rotate 2,o3d_x_rotate(1),o3d_y_rotate(1),o3d_z_rotate(1)
3d_move 2,1
point_position o3d_x_position(2),o3d_y_position(2),o3d_z_position(2)
cam_position o3d_x_position(1),o3d_y_position(1),o3d_z_position(1)
return
programme:
if key_down_code=27 : ' si on appui sur echap (quitter)
timer_off_all : ' destruction de tout les timers
terminate
end_if
if touche_haut=1
3d_move 1,vitesse_deplacement
end_if
if touche_bas=1
3d_move 1,0-vitesse_deplacement
end_if
if touche_gauche=1
3d_y_rotate 1,o3d_y_rotate(1)+vitesse_rotation
end_if
if touche_droit=1
3d_y_rotate 1,o3d_y_rotate(1)-vitesse_rotation
end_if
gosub actualiser_vue
return
' LES SOUS PROGRAMMES########################################################FIN[/code]
Pour la 3ème personne nous verrons cela plus tard.
:study: Tutoriel en cours de réalisation...
A venir= texture , chaînage , collision ,brouillard, skybox et bien d'autre :!: :!: :!:
Accueil 
Calendrier
Le centre du monde 3D est la position ou les valeurs X,Y,Z sont égale a 0.
Tutoriel en cours de réalisation... 
! BOn travail
-