Bouton-poussoir à double action

' Bouton-poussoir 3 états
' Marc - Mai 2022
' Ecrit en langage Panoramic

dim memoire%
label actionbouton

' creerBouton(numéro d'objet, coordonnée en x, coordonnée en y)
creerBouton(10,50,50)

' créer un track_bar pour vérifier le bon fonctionnement du programme
' creerTrackBar(numéro d'objet, coordonnée en x, coordonnée en y)
creerTrackBar(2,100,50)

end

sub creerBouton(n%,x%,y%)
    picture 1
    width 1,25
    height 1,25
    top 1,y%
    left 1,x%
    color 1,255,255,255
    on_mouse_down 1,actionBouton
end_sub

actionBouton:
    off_mouse_down 1
    appuiBouton()
    on_mouse_down 1,actionBouton
return

sub appuiBouton()
    dim_local null%, temps%, mr%
    ' inhiber bouton droit souris
    if mouse_right_down(1) = 1
        exit_sub
    end_if
    ' raffraichir de l'état des boutons de la souris
    null% = mouse_left_up(1)
    null% = mouse_left_down(1)

    temps% = number_ticks
    while mouse_left_up(1) = 0 :' Tant que le bouton gauche souris est appuyé            
        if temps% + 2000 < number_ticks
            memoire% = position(2)
            color 1,255,0,0
            pause 250
            color 1,255,255,255
            mr% = 1
            exit_while    
        end_if
    end_while
    if mr% = 0
        position 2,memoire%
        color 1,0,255,0
        pause 250
        color 1,255,255,255
    end_if
end_sub

sub creerTrackBar(n%,x%,y%)
    track_bar n%
    left n%,x%
    top n%,y%
    min n%,0
    max n%,100
end_sub

' Bouton-poussoir double action
' Démonstration
' Marc - Mai 2022
' Ecrit en langage Panoramic

dim memoire%
label actionbouton

interfaceUtilisateur()

end

sub interfaceUtilisateur()
    height 0,230
    width 0,400
    left 0,(screen_x - width(0))/2
    top 0,(screen_y - height(0))/2
    color 0,80,80,80

    ' Titre et commentaires
    creerTitre()

    ' Creer un bouton
    creerBouton()

    ' créer un track_bar témoin pour tester le fonctionnement du programme
    creerTrackBar()
end_sub

sub creerTitre()
    alpha 1
    top 1,15
    left 1,20
    font_size 1,14
    font_color 1,255,255,255
    caption 1,"Démonstration : Bouton à double action."
    
    alpha 2
    top 2,45
    left 2,30
    font_size 2,10
    font_color 2,255,255,255
    caption 2,"- Appui long : mémorisation de la position du track_bar"
    
    alpha 3
    top 3,65
    left 3,30
    font_size 3,10
    font_color 3,255,255,255
    caption 3,"- Appui court : rappel de la position mise en mémoire"
end_sub

sub creerBouton()
    button_picture 4
    width 4,30
    height 4,30
    top 4,120
    left 4,90
    button_picture_target_is_picture
    width 4,30
    height 4,30
    color 4,240,240,240
    on_mouse_down 4,actionBouton
end_sub

sub creerTrackBar()
    track_bar 5
    left 5,150
    top 5,125
    min 5,0
    max 5,100
end_sub

actionBouton:
    off_mouse_down 4
    appuiBouton()
    on_mouse_down 4,actionBouton
return

sub appuiBouton()
    dim_local null%, temps%, mr%

    ' inhiber l'action du bouton droit souris
    if mouse_right_down(4) = 1
        exit_sub
    end_if

    ' raffraichir l'état des boutons de la souris
    null% = mouse_left_up(4)
    null% = mouse_left_down(4)

    temps% = number_ticks
    while mouse_left_up(4) = 0 :' Tant que le bouton gauche souris n'est pas laché            
        if temps% + 1500 < number_ticks :' temps d'attente en ms pour valider l'appui long
            mr% = 1
            memoire% = position(5)
            color 4,255,0,0
            pause 100 :' délai du premier flash rouge
            color 4,240,240,240
            pause 100 :' delai entre les deux flashs
            color 4,255,0,0
            pause 100 :' délai du 2ème flash rouge
            color 4,240,240,240
            exit_while    
        end_if
    end_while
    if mr% = 0
        position 5,memoire%
        color 4,0,255,0
        pause 250 :' délai du flash vert
        color 4,255,255,255
    end_if
end_sub