Mots-clés : Majuscules ou minuscules ?

' Mots-clés en majuscules ou minuscules
' Marc - mai 2021

dim motsCles$, source2$, mot$, nomFichier$, repertoire$
dim index%, modif%, reponse%

label redim0, ouvrir, minuscules, majuscules, enregistrer, quitter

data "#INCLUDE 2D_ARC 2D_CIRCLE 2D_CLEAR 2D_ELLIPSE 2D_FILL_COLOR 2D_FILL_CROSS 2D_FILL_DIAGONAL_CROSS 2D_FILL_DIAGONAL_DOWN 2D_FILL_DIAGONAL_UP "
data "2D_FILL_HORIZONTAL 2D_FILL_OFF 2D_FILL_ON 2D_FILL_SOLID 2D_FILL_VERTICAL 2D_FLOOD 2D_IMAGE_COPY 2D_IMAGE_PASTE 2D_LINE 2D_PEN_COLOR 2D_PEN_DASH "
data "2D_PEN_DASH_DOT 2D_PEN_DASH_DOT_DOT 2D_PEN_DOT 2D_PEN_SOLID 2D_PEN_WIDTH 2D_POINT 2D_POLY_FROM 2D_POLY_TO 2D_RECTANGLE 2D_TARGET_IS 3D_ACTOR 3D_BOX "
data "3D_CHAIN 3D_CHAIN_BREAK 3D_COLLISION_AS_CUBE 3D_COLLISION_AS_ELLIPSOID 3D_COLLISION_AS_FACES 3D_COLLISION_AS_POINT 3D_COLLISION_AS_SPHERE "
data "3D_COLOR 3D_CONE 3D_CUBE 3D_CYLINDER 3D_DELETE 3D_DELETE_ALL 3D_DODECAHEDRON 3D_HIDE 3D_IMAGE_TEXTURE 3D_LINE 3D_LINE_WIDTH 3D_LOAD_OBJECT 3D_LOAD_TEXTURE "
data "3D_LOAD_TEXTURE_BACK 3D_LOAD_TEXTURE_BOTTOM 3D_LOAD_TEXTURE_FRONT 3D_LOAD_TEXTURE_LEFT 3D_LOAD_TEXTURE_RIGHT 3D_LOAD_TEXTURE_TOP 3D_MESH 3D_MOVE "
data "3D_PLANE 3D_POINT_OBJECT 3D_POSITION 3D_ROTATE 3D_SCALE 3D_SHOW 3D_SKYBOX 3D_SPHERE 3D_TARGET_IS 3D_TEAPOT 3D_TEXT 3D_TEXT_CHANGE 3D_TORUS 3D_TRANSPARENT "
data "3D_U_TILE 3D_V_TILE 3D_X_POSITION 3D_X_ROTATE 3D_X_SCALE 3D_Y_POSITION 3D_Y_ROTATE 3D_Y_SCALE 3D_Z_POSITION 3D_Z_ROTATE 3D_Z_SCALE ABS( ACOS( "
data "ACTIVE ACTIVE( ADR( ALPHA AND APPLICATION_TITLE ARCHIVER_ADD ARCHIVER_EXTRACT ARCHIVER_OFF ARCHIVER_ON ASC( ASIN( ATN( AXES_HIDE AXES_SHOW "
data "BAR_BOTH BAR_HORIZONTAL BAR_NONE BAR_VERTICAL BEEP BEEP_ERROR BEEP_EXCLAMATION BEEP_INFORMATION BEEP_QUESTION BIN_AND( BIN_OR( BIN_XOR( BORDER_HIDE"
data "BORDER_NORMAL BORDER_SMALL BRIGHTNESS BUTTON BUTTON_PICTURE BUTTON_PICTURE_TARGET_IS_OBJECT BUTTON_PICTURE_TARGET_IS_PICTURE CAM_MOVE CAM_PITCH "
data "CAM_POSITION CAM_ROLL CAM_TURN CAM_X_POSITION CAM_Y_POSITION CAM_Z_POSITION CAPTION CAPTION$( CARET_POSITION CARET_POSITION( CASE CHAIN CHART "
data "CHART_BAR CHART_LINE CHART_POINT CHECK CHECKED( CHECKED_MENU CHECKED_OPTION( CHR$( CLEAR CLICKED( CLIPBOARD_COPY CLIPBOARD_CUT CLIPBOARD_PASTE "
data "CLIPBOARD_STRING_COPY CLIPBOARD_STRING_PASTE$ CLS COLOR COLOR_PIXEL_BLUE( COLOR_PIXEL_GREEN( COLOR_PIXEL_RED( COMBO COMMAND_TARGET_IS CONTAINER "
data "CONTAINER_OPTION CONTAINER_TAB CONTENT_COPY CONTRAST COS( COUNT( CREATE_HIDE CREATE_SHOW CURSOR_ARROW CURSOR_BEAM CURSOR_CROSS CURSOR_DEFAULT "
data "CURSOR_HELP CURSOR_HIDE CURSOR_HOURGLASS CURSOR_NOPARKING CURSOR_POINT DATA DATE$ DATE_DAY DATE_MONTH DATE_YEAR DEGREE_TO_RADIAN( DEGREES DELETE "
data "DELETE_ALL DIGIT1 DIM DIM_LOCAL DIR_CHANGE DIR_CURRENT$ DIR_DIALOG DIR_EXISTS( DIR_MAKE DIR_REMOVE DISK_EXISTS( DISK_KILO_FREE( DISK_KILO_SIZE( "
data "DISPLAY DLIST DLL_CALL0( DLL_CALL1( DLL_CALL2( DLL_CALL3( DLL_CALL4( DLL_CALL5( DLL_CALL6( DLL_OFF DLL_ON DOUBLE_CLICKED( EDIT ELSE END "
data "END_FNC END_IF END_SELECT END_SUB END_WHILE ENVIRONMENT$ ERROR_ENGLISH ERROR_FRENCH ERROR_LINE ERROR_NUMBER ERROR_TYPE$ EVEN( EXCEL_FILE_CLOSE "
data "EXCEL_FILE_NEW EXCEL_FILE_OPEN EXCEL_READ$( EXCEL_START EXCEL_STOP EXCEL_WRITE EXECUTE EXECUTE_WAIT EXIT_FNC EXIT_FOR EXIT_REPEAT EXIT_SUB "
data "EXIT_WHILE EXP( FILE_ADD FILE_ARCHIVE FILE_ARCHIVE_OFF FILE_CLOSE FILE_COPY FILE_DELETE FILE_DIALOG FILE_EOF( FILE_EXISTS( FILE_EXTRACT_DISK$( "
data "FILE_EXTRACT_EXTENSION$( FILE_EXTRACT_NAME$( FILE_EXTRACT_PATH$( FILE_FIND_CLOSE FILE_FIND_FIRST$ FILE_FIND_NEXT$ FILE_HIDE FILE_HIDE_OFF "
data "FILE_LOAD FILE_MOVE FILE_NAME$( FILE_OPEN_APPEND FILE_OPEN_READ FILE_OPEN_WRITE FILE_READ FILE_READ_ONLY FILE_READ_ONLY_OFF FILE_READBUF FILE_READLN "
data "FILE_READLN$( FILE_RENAME FILE_SAVE FILE_SYSTEM FILE_SYSTEM_OFF FILE_WRITE FILE_WRITEBUF FILE_WRITELN FILEBIN_BLOCK_READ FILEBIN_BLOCK_WRITE FILEBIN_CLOSE "
data "FILEBIN_HEXA_READ FILEBIN_HEXA_READ$( FILEBIN_HEXA_WRITE FILEBIN_OPEN_READ FILEBIN_OPEN_WRITE FILEBIN_POS( FILEBIN_POSITION FILEBIN_READ FILEBIN_READ( "
data "FILEBIN_SIZE( FILEBIN_WRITE FILTER FIND( FNC FOG_COLOR FOG_DISTANCE_MAX FOG_DISTANCE_MIN FOG_OFF FOG_ON FONT_BOLD FONT_BOLD_OFF FONT_COLOR FONT_ITALIC "
data "FONT_ITALIC_OFF FONT_NAME FONT_NAMES_ADD FONT_NAMES_LOAD FONT_SIZE FONT_STRIKE FONT_STRIKE_OFF FONT_UNDERLINE FONT_UNDERLINE_OFF FOR FORM FRAC( FREE "
data "FULL_SPACE GAMMA GOSUB GOTO GRID GRID_CLEAR GRID_COLUMN GRID_COLUMN( GRID_COLUMN_DELETE GRID_COLUMN_FIXED GRID_COLUMN_FIXED( GRID_COLUMN_INSERT "
data "GRID_COLUMN_SIZING_ON GRID_COLUMN_WIDTH GRID_COLUMN_WIDTH( GRID_FIXED_COLOR GRID_LOAD GRID_ONE_COLUMN_WIDTH GRID_ONE_COLUMN_WIDTH( GRID_ONE_ROW_HEIGHT "
data "GRID_ONE_ROW_HEIGHT( GRID_READ$( GRID_ROW GRID_ROW( GRID_ROW_DELETE GRID_ROW_FIXED GRID_ROW_FIXED( GRID_ROW_HEIGHT GRID_ROW_HEIGHT( GRID_ROW_INSERT "
data "GRID_ROW_SIZING_OFF GRID_ROW_SIZING_ON GRID_SAVE GRID_WRITE GRID_X_TO_COLUMN( GRID_Y_TO_ROW( HANDLE( HANDLE_APPLICATION HANDLE_CANVAS( HANDLE_FORM( "
data "HCOS( HEIGHT HEIGHT( HEIGHT_CLIENT( HEX$( HEX( HIDE HIDE( HIDE_ALL HINT HINT_HIDE HORIZONTAL HSIN( HTAN( HVIEWER IF IMAGE INACTIVE INACTIVE( "
data "INKEY$ INPUT INPUT_MARK_OFF INPUT_MARK_ON INPUT_REDO_OFF INPUT_REDO_ON INPUT_SOURCE_IS INPUT_VISIBLE_OFF INPUT_VISIBLE_ON INSERT$( INSTR( INSTR_LAST( "
data "INSTR_POS( INSTR_RIGHT( INT( ITEM_ADD ITEM_DELETE ITEM_INDEX$( ITEM_INDEX( ITEM_INSERT ITEM_READ$( ITEM_SELECT KEY_DOWN_CODE KEY_DOWN_SPECIAL "
data "KEY_UP_CODE KEY_UP_SPECIAL LABEL LABEL( LED1 LEFT LEFT$( LEFT( LEN( LIGHT_POSITION LIGHT_X_POSITION LIGHT_Y_POSITION LIGHT_Z_POSITION LIST LOG( "
data "LOG10( LOG2( LOWER$( LTRIM$( MAIL_SEND MAIN_MENU MAIN_MENU_POP MARK_OFF MARK_ON MAX MAX( MAXIMIZE MEMO MEMO_RICH MESSAGE MESSAGE_CONFIRMATION_OK( "
data "MESSAGE_CONFIRMATION_YES_NO( MESSAGE_ERROR_OK( MESSAGE_ERROR_YES_NO( MESSAGE_INFORMATION_OK( MESSAGE_INFORMATION_YES_NO( MESSAGE_INPUT$( MESSAGE_INPUT( "
data "MESSAGE_TEXT$ MESSAGE_WARNING_OK( MESSAGE_WARNING_YES_NO( MID$( MIDI_INSTRUMENT MIDI_OFF MIDI_ON MIDI_PLAY MIDI_VOLUME MIN MIN( MINIMIZE MOD( MOUSE_LEFT_DOWN( "
data "MOUSE_LEFT_UP( MOUSE_RIGHT_DOWN( MOUSE_RIGHT_UP( MOUSE_X_LEFT_DOWN( MOUSE_X_LEFT_UP( MOUSE_X_POSITION( MOUSE_X_RIGHT_DOWN( MOUSE_X_RIGHT_UP( MOUSE_Y_LEFT_DOWN( "
data "MOUSE_Y_LEFT_UP( MOUSE_Y_POSITION( MOUSE_Y_RIGHT_DOWN( MOUSE_Y_RIGHT_UP( MOVIE NEXT NORMAL NOT NUMBER_2D_TARGET NUMBER_3D_OBJECTS NUMBER_3D_TARGET "
data "NUMBER_ACTIVATE NUMBER_CHANGE NUMBER_CLICK NUMBER_COMMAND_TARGET NUMBER_CURRENT_LINE NUMBER_DOUBLE_CLICK NUMBER_EVENTS NUMBER_INPUT_SOURCE NUMBER_KEY_DOWN "
data "NUMBER_KEY_UP NUMBER_OBJECTS NUMBER_PRINT_TARGET NUMBER_SHOW NUMBER_SPRITE_TARGET NUMBER_SPRITES NUMBER_TICKS NUMBER_VARIABLES NUMERIC( O3D_COLLISION( "
data "O3D_OBJECT_EXISTS( O3D_OBJECT_TYPE( O3D_X_POSITION( O3D_X_ROTATE( O3D_X_SCALE( O3D_Y_POSITION( O3D_Y_ROTATE( O3D_Y_SCALE( O3D_Z_POSITION( "
data "O3D_Z_ROTATE( O3D_Z_SCALE( OBJECT_EXISTS( OBJECT_INTERNAL( OBJECT_PARENT( OBJECT_TYPE( ODD( OFF_ACTIVATE OFF_CHANGE OFF_CLICK OFF_CLOSE OFF_DOUBLE_CLICK "
data "OFF_ERROR_GOTO OFF_KEY_DOWN OFF_KEY_UP OFF_MOUSE_DOWN OFF_MOUSE_MOVE OFF_MOUSE_UP OFF_MOVE OFF_RESIZE OFF_SHOW OFF_USER_EVENT ON_ACTIVATE ON_CHANGE ON_CLICK "
data "ON_CLOSE ON_DOUBLE_CLICK ON_ERROR_GOTO ON_KEY_DOWN ON_KEY_UP ON_MOUSE_DOWN ON_MOUSE_MOVE ON_MOUSE_UP ON_MOVE ON_RECEIVE ON_RESIZE ON_SHOW ON_TIMER ON_USER_EVENT "
data "OPEN_DIALOG_PIC OPTION OR PANEL PARALLEL_INP( PARALLEL_OFF PARALLEL_ON PARALLEL_OUT PARAM_NUMBER PARAM_VALUE$( PARENT PAUSE PEEK( PEEK_NORMAL PEEK_REVERSE "
data "PEEK16( PEEK32( PI PICTURE PICTURE_BOTTOM PICTURE_LEFT PICTURE_RIGHT PICTURE_TOP PLAY PLAY_WAIT POINT_OBJECT POINT_POSITION POINT_X_POSITION POINT_Y_POSITION "
data "POINT_Z_POSITION POKE POKE_NORMAL POKE_REVERSE POKE16 POKE32 POSITION POSITION( POWER( PRINT PRINT_LOCATE PRINT_TARGET_IS PRINT_X_LOCATE PRINT_Y_LOCATE "
data "PROGRESS_BAR RADIAN_TO_DEGREE( RADIANS READ REM REPEAT REPLACE( RESTORE RESTORE_LABEL RESULT RETURN REVERSE$( RIGHT$( RIGHT_POS$( RMDIR RND( "
data "RTRIM$( SAVE_DIALOG SAVE_DIALOG_PIC SCANCODE SCENE2D SCENE3D SCREEN_X SCREEN_Y SCROLL_BAR SECRET_OFF SECRET_ON SELECT SELECT_DELETE SELECT_READ$( "
data "SELECT_TEXT SEPARATOR_IS_COMMA SEPARATOR_IS_POINT SERIAL SERIAL_BAUDRATE SERIAL_CLOSE SERIAL_DATABITS SERIAL_OPEN SERIAL_PARITY SERIAL_PORT SERIAL_PORT_EXISTS( "
data "SERIAL_READ$( SERIAL_STOPBITS SERIAL_WRITE SET_FOCUS SGN( SHAPE SHAPE_CIRCLE SHAPE_ELLIPSE SHAPE_RECTANGLE SHAPE_RECTANGLE_ROUNDED SHAPE_SQUARE "
data "SHAPE_SQUARE_ROUNDED SHOW SHOW( SHOW_ALL SHOW_MODAL SIN( SNAPSHOT SORT SORT_OFF SORT_ON SOUND SPIN SPRITE SPRITE_BRIGHTNESS SPRITE_CONTRAST SPRITE_CREATE_HIDE "
data "SPRITE_CREATE_SHOW SPRITE_DELETE SPRITE_DELETE_ALL SPRITE_EXISTS( SPRITE_FILE_LOAD SPRITE_GAMMA SPRITE_HIDE SPRITE_HIDE_ALL SPRITE_IMAGE_LOAD SPRITE_POSITION "
data "SPRITE_SCALE SPRITE_SHOW SPRITE_SHOW_ALL SPRITE_TARGET_IS SPRITE_TEXT SPRITE_X_POSITION SPRITE_X_POSITION( SPRITE_X_SCALE SPRITE_Y_POSITION SPRITE_Y_POSITION( "
data "SPRITE_Y_SCALE SQR( STEP STOP STR$( STRETCH_OFF STRETCH_ON STRING$( SUB SUB_MENU SWITCH1 SYNEDIT SYNEDIT_TARGET_IS_COMMENT SYNEDIT_TARGET_IS_GUTTER "
data "SYNEDIT_TARGET_IS_KEYWORD SYNEDIT_TARGET_IS_OBJECT SYNEDIT_TARGET_IS_STRING SYSTEM$ TAB TAN( TERMINATE TEXT TEXT$( TEXT_DELETE TEXT_HEIGHT( TEXT_INSERT "
data "TEXT_WIDTH( THEN TIME$ TIME_HOUR TIME_MINUTE TIME_SECOND TIMER TIMER_INTERVAL TIMER_OFF TIMER_OFF_ALL TIMER_ON TO TO_BACKGROUND TO_FOREGROUND TOP TOP( TRACE_OFF "
data "TRACE_ON TRACK_BAR TRIGGER_CLICK TRIGGER_KEY_DOWN TRIGGER_KEY_UP TRIM$( UNTIL UPPER$( USER_EVENT_LPARAM USER_EVENT_WPARAM VAL( VARIABLE( VERSION$ VERTICAL "
data "WAIT WHILE WIDTH WIDTH( WIDTH_CLIENT( WRAP_VALUE( "
data "PANORAMIC"

repertoire$ = dir_current$ + ""

creerStringMotsCles()

interfaceUtilisateur()

end


sub convertir(choix%)
    source2$ = upper$(text$(1))
    source2$ = source2$ + chr$(13)+chr$(10)
    index% = 1

    while index% <= len(source2$)
        lectureMot()
        if instr(motsCles$,mot$) > 0 :' test si le mot trouvé est un mot-clé
            select_text 1,index%-len(mot$)-1,len(mot$)
            select_delete 1
            if choix% = 1
                text_insert 1,index%-len(mot$)-2,lower$(mot$)
            else
                text_insert 1,index%-len(mot$)-2,upper$(mot$)
            end_if
        end_if
    end_while    
end_sub


sub lectureMot()
    dim_local a$, r%

    ' recherche début d'un mot
    while index% < len(source2$)
        a$=MID$(Source2$,index%,1)
        r%=INSTR("ABCDEFGHIJKLMNOPQRSTUVWXYZ23",a$)
        index% = index% + 1
        if r% > 0
            mot$ = a$
            exit_while
        end_if
    end_while

    ' recherche fin du mot
    while index% <= len(source2$)
        a$=MID$(Source2$,index%,1)
        r%=INSTR(chr$(13)+" ,()+-*/:",a$)
        index% = index% + 1
        if r% = 0
            mot$ = mot$ + a$
        else
            exit_while
        end_if
    end_while
end_sub


sub creerStringMotsCles()
    dim_local i%, a$
    while a$ <> "PANORAMIC"
        read a$
        motsCles$ = motsCles$ + a$
    end_while
end_sub


sub interfaceUtilisateur()
    width 0,width(0) - width_client(0) + 1200
    height 0,height(0) - height(0) + 700
    top 0,(screen_y - height(0)) / 2
    left 0,(screen_x - width(0)) / 2
    color 0,20,20,20
    caption 0,"Mots-clés : Majuscules ou minuscules ?"
    on_resize 0,redim0
    on_close 0,quitter

    barreIcones()

    synedit 1
    width 1,width_client(0)
    height 1,height_client(0)-70
    color 1,30,30,30         :' Couleur de fond de l'éditeur
    font_name 1,"Courier New"
    font_size 1,12           :' Taile des caractères dans l'éditeur
    font_color 1,240,240,240 :' Couleur d'écriture dans l'éditeur
    synedit_target_is_gutter
    color 1,30,30,30         :' Couleur de fond de la marge
    font_name 1,"Courier New"
    font_size 1,12           :' Taille d'écriture dans la marge
    font_color 1,210,210,210 :' Couleur d'écriture dans la marge
    synedit_target_is_keyword
    font_color 1,0,255,0     :' Couleur des mots-clés
    synedit_target_is_comment
    font_color 1,250,36,114  :' Couleur des commentaires
    left 1,0
    top 1,44

    creerBarreEtat()
end_sub


sub barreIcones()
    creerIconeOuvrirProjet(8,8)
    creerIconeMajuscules(44,8)
    creerIconeMinuscules(80,8)
    creerIconeSauvegarderProjet(116,8)
end_sub


sub creerIconeOuvrirProjet(x%,y%)
    dim_local i%

    picture 3
    height 3,28
    width 3,28
    top 3,y%
    left 3,x%
    hint 3,"Ouvrir Projet"
    on_click 3,ouvrir

    2d_target_is 3

    dessinerFondIcone()

    2d_pen_color 0,0,0
    2d_line 16,4,20,4
    2d_point 15,5
    2d_point 20,5
    2d_point 21,6
    2d_line 20,7,23,7
    2d_line 22,5,22,8
    2d_line 5,9,11,9
    2d_line 10,11,21,11
    2d_line 11,16,25,16
    2d_line 5,22,19,22
    2d_line 5,9,5,23
    2d_line 10,9,10,12
    2d_line 20,11,20,17
    2d_line 5,22,12,15
    2d_line 18,22,25,15
    for i% = 10 to 20
        2d_flood 6,i%,255,255,255
    next i%
    for i% = 17 to 21
        2d_flood 11,i%,250,250,0
    next i%
end_sub


sub creerIconeMajuscules(x%,y%)
    dim_local i%

    picture 4
    height 4,28
    width 4,28
    top 4,y%
    left 4,x%
    hint 4,"Mots-clés en MAJUSCULES"
    on_click 4,majuscules

    2d_target_is 4

    dessinerFondIcone()

    2d_pen_color 0,0,200
    2d_fill_color 0,0,200
    2d_rectangle 6,7,9,22
    2d_line 9,7,9,11
    2d_line 10,9,10,13
    2d_line 11,10,11,15
    2d_line 12,12,12,17
    2d_rectangle 13,14,15,18
    2d_line 15,12,15,17
    2d_line 16,10,16,15
    2d_line 17,9,17,13
    2d_line 18,7,18,11
    2d_rectangle 19,7,22,22
end_sub


sub creerIconeMinuscules(x%,y%)
    dim_local i%

    picture 5
    height 5,28
    width 5,28
    top 5,y%
    left 5,x%
    hint 5,"Mots-clés en minuscules"
    on_click 5,minuscules

    2d_target_is 5

    dessinerFondIcone()

    2d_pen_color 0,0,200
    2d_rectangle 7,11,9,22
    2d_line 11,11,13,11
    2d_line 17,11,19,11
    2d_line 10,12,14,12
    2d_line 16,12,20,12
    2d_line 9,13,21,13
    2d_point 9,14
    2d_line 12,14,16,14
    2d_point 18,14
    2d_rectangle 13,15,15,22
    2d_rectangle 19,14,21,22
end_sub


sub creerIconeSauvegarderProjet(x%,y%)
    dim_local i%

    picture 6
    height 6,28
    width 6,28
    top 6,y%
    left 6,x%
    hint 6,"Enregistrer Projet"
    on_click 6,enregistrer

    2d_target_is 6
    
    dessinerFondIcone()
    
    2d_pen_color 0,0,0
    2d_line 7,5,20,5
    2d_line 19,6,21,6
    2d_line 20,7,22,7
    2d_line 7,22,21,22
    2d_line 6,6,6,22
    2d_line 21,7,21,22
    
    for i% = 6 to 21
         2d_flood 8,i%,0,255,0
    next i%
    
    2d_rectangle 8,14,20,21
    2d_line 10,16,18,16
    2d_line 10,18,18,18
    2d_rectangle 9,5,18,10
    2d_line 9,6,15,6
    2d_line 9,7,15,7
    2d_line 9,8,15,8
end_sub


sub dessinerFondIcone()
    dim_local i%,r%,v%,b%
    for i% = 0 to 27
        r%=255-(5*i%)
        v%=255-(5*i%)
        b%=255-(5*i%)
        2d_pen_color r%,v%,b%
        2d_line 0,i%,28,i%
    next i%
end_sub


sub creerBarreEtat()
    alpha 30
    font_size 30,10
    font_color 30,240,240,240
    top 30,height_client(0)-20
    left 30,3
    caption 30," Réalisé en langage panoramic par Marc - https://panoramic.1fr1.net/"

    picture 31
    width 31,12
    height 31,12
    top 31,height_client(0)-12
    left 31,width_client(0)-12
    color 31,30,30,30
    2d_target_is 31
    2d_pen_color 240,240,240
    2d_line 8,2,10,2
    2d_line 8,3,10,3
    2d_line 5,5,10,5
    2d_line 5,6,10,6
    2d_line 2,8,10,8
    2d_line 2,9,10,9
    2d_pen_color 30,30,30
    2d_line 4,8,4,10
    2d_line 7,5,7,10
end_sub


ouvrir:
    ouvrirFichier()
return


sub ouvrirFichier()
    if modif% = 1
        reponse% = message_information_yes_no("Souhaitez-vous enregistrer votre projet en cours avant d'en ouvrir un  autre ?")
        if reponse% = 0
            exit_sub
        end_if
        if reponse% = 1
            subEnregistrer()
        end_if
    end_if
    if object_exists(10) = 0
        open_dialog 10
    end_if    
    filter 10,"Basic Files|*.bas"
    file_dialog 10,""
    nomFichier$ = file_name$(10)
    if nomFichier$ = "_" then return
    file_load 1,nomFichier$
    modif% = 0
    caption 30,nomFichier$
end_sub


minuscules:
    inactive 0
    modif% = 1
    convertir(1)
    active 0
return


majuscules:
    inactive 0
    modif% = 1
    convertir(2)
    active 0
return


enregistrer:
    subEnregistrer()
return


sub subEnregistrer()
    dim_local nomDuProjet$, b$, longueurNomProjet%, pos%, n%

    if text$(1) = ""
        exit_sub
    end_if
    
    if object_exists(11) = 0
        save_dialog 11
    end_if
        
    filter 11,"Basic Files|*.bas"
    file_dialog 11,nomFichier$
    nomDuProjet$ = file_name$(11)

    if nomDuProjet$ = "_" or nomDuProjet$ = ""
        exit_sub
    end_if
        
    if file_exists(nomDuProjet$) = 1
         if message_confirmation_yes_no("ce nom de fichier existe déjà. le remplacer ?") <> 1
             exit_sub
         end_if    
    end_if

    b$=UPPER$(nomDuProjet$)
    
    if file_extract_extension$(b$) <> ".BAS"
        if file_extract_extension$(b$) <> ""
            longueurNomProjet% = len(nomNouveauProjet$)
            pos% = instr_right(nomDuProjet$,".")
            n% = longueurNomProjet% - pos%
            nomDuProjet$ = left$(nomDuProjet$,n%)
        end_if
        nomDuProjet$ = nomDuProjet$ + ".bas"
    end_if
    
    file_save 1,nomDuProjet$
    nomFichier$ = nomDuProjet$
    modif% = 0
    caption 30,nomFichier$
end_sub


redim0:
    width 1,width_client(0)
    height 1,height_client(0)-70
    top 30,height_client(0)-20
    top 31,height_client(0)-12
    left 31,width_client(0)-12
return


quitter:
    if modif% = 1
        close_inactive
            reponse% = message_information_yes_no("Souhaitez-vous enregistrer votre projet en cours avant de quitter ?")
            if reponse% = 0
                return
            end_if
            if reponse% = 1
                subEnregistrer()
            end_if
        close_active
    end_if    
    terminate    
return