Bonne année avec DistriLib

rem ' Distributaur d'argent frais - par jjn4 - le 28/12/2019 ==================
   dim NDS% : rem Numéro Des Sprites
   label clic : rem Gestionnaire des on-click
   label non : rem Inactivation de la croix rouge
   NDS%=200

rem Form0 et autres préparations ==============================================
   width 0,1300
   height 0,600
   caption 0,"   Distributeur d'argent - servez-vous, c'est gratuit !"
   on_close 0,non
   close_inactive
   midi_on
   midi_volume 127

scene2d 100 : rem Fond du distributeur
   full_space 100
   color 100,0,130,0
   sprite_target_is 100
  
picture 105 : rem Fabrication des pièces
   left 105,100
   top 105,210
   2d_target_is 105
   print_target_is 105
   sous()

panel 110 : rem Distributeur
   left 110,20
   top 110,150
   width 110,220
   height 110,220
   color 110,250,150,0
   font_size 110,30
   font_bold 110
  
button 120 : rem Bouton 1€
   parent 120,110
   left 120,120
   top 120,20
   width 120,80
   height 120,80
   caption 120,"1 €"
   on_click 120,clic
  
button 130 : rem Bouton 2€
   parent 130,110
   left 130,120
   top 130,120
   width 130,80
   height 130,80
   caption 130,"2 €"
   on_click 130,clic
  
alpha 140 : rem Invitation
   parent 140,110
   left 140,10
   top 140,15
   font_color 140,0,0,255
   caption 140,"Distri"+chr$(13)+"Lib."
  
button 150 : rem Fin
   parent 150,110
   left 150,20
   top 150,120
   width 150,80
   height 150,80
   caption 150,"Fin"
   on_click 150,clic
  
panel 160 : rem Souhaits
   hide 160
   left 160,400
   top 160,400
   width 160,600
   font_bold 160
   font_size 160,40
   font_name 160,"Arial"
   color 160,255,255,0
   caption 160,"Amusez-vous bien !"
  
end : ' Début des routines ====================================================

clic: : rem Gestionnaire des on-click =========================================
   select number_click
      case 120 : sortie(1)
      case 130 : sortie(2)
      case 150 : fin()
   end_select
return

sub fin() : rem Fin du programme ==============================================
   dim_local v1fi% , v2fi% , v3fi%
   if NDS%>200
      message "Placez votre sac sous l'écran"
      inactive 110
      midi_instrument 10
      if NDS%>220
         v3fi%=20
      else
         v3fi%=10
      end_if
      for v1fi% = 201 to NDS%
         for v2fi% = sprite_y_position(v1fi%) to 600 step v3fi%
            sprite_position v1fi%,sprite_x_position(v1fi%),v2fi%
         next v2fi%
         midi_play int(rnd(2))*2+74,10
      next v1fi%
   end_if
   show 160
   display
   pause 900
   midi_off
   file_delete "Un-Euro.bmp"
   file_delete "Deux-Euros.bmp"
   terminate
end_sub

non: : rem Inactivation de la croix rouge =====================================
   caption 0,""
   beep
   pause 200
   caption 0,"   Utilisez plutôt le bouton FIN"
return

sub sortie(qp%) : rem Sortie d`une pièce ======================================
   dim_local v1st% , lst% , hst , cst% : rem Longueur , Hauteur , Côté
   inactive 110
   NDS%=NDS%+1
   lst%=int(rnd(800))+301
   hst=(int(rnd(100))+1)/300
   cst%=(int(rnd(2))+1)*2-3
   midi_instrument 108
   sprite_create_hide
   sprite NDS%
      sprite_hide NDS%
      select qp%
         case 1 : sprite_file_load NDS%,"Un-Euro.bmp" : midi_play 70,10
         case 2 : sprite_file_load NDS%,"Deux-Euros.bmp" : midi_play 60,10
      end_select
      sprite_position NDS%,120,200
      sprite_show NDS%
   for v1st% = 110 to lst% step 20
      sprite_position NDS%,v1st%,200+hst*v1st%*cst%
      pause 1
   next v1st%
   active 110
end_sub

sub sous() : rem Création magique des pièces ==================================
   dim_local v1so%
   width 105,105 : rem Dessin d`un Euro
   height 105,105
   color 105,0,0,0
   2d_fill_color 255,220,85
   2d_pen_color 150,150,150
   2d_pen_width 1
   2d_circle 52,52,52
   2d_circle 52,52,49
   2d_fill_color 230,230,230
   2d_circle 52,52,36
   font_size 105,38
   font_name 105,"Times New Roman"
   font_color 105,150,150,150
   print_locate 33,23
   print "1"
   font_size 105,8
   print_locate 57,46
   print "EURO"
   for v1so% = 1 to 6
      2d_line 62+v1so%*4,13+v1so%*3,62+v1so%*4,90-v1so%*3
   next v1so%
   file_save 105,"Un-Euro.bmp"
   width 105,115 : rem Dessin de deux Euros
   height 105,115
   color 105,0,0,0
   2d_fill_color 230,230,230
   2d_pen_color 150,150,150
   2d_circle 57,57,55
   2d_circle 57,57,52
   2d_fill_color 255,220,85
   2d_circle 57,57,37
   font_size 105,38
   font_color 105,120,170,170
   print_locate 37,27
   print "2"
   font_size 105,8
   print_locate 64,51
   print "EURO"
   2d_pen_color 120,170,170
   for v1so% = 1 to 6
      2d_line 68+v1so%*4,18+v1so%*3,68+v1so%*4,95-v1so%*3
   next v1so%
   file_save 105,"Deux-Euros.bmp"
end_sub