Copier et coller des images

rem ' Démonstration de copier-coller des images - Démo-Copi-Coll-Img
dim a$ , id$ , a , b , c , k , x , y , w , z
label dessin , point , ligne, rond , carre , coul , eff1 , eff2 , copy , coll
width 0,1000 : height 0,550 : id$="p" : c=1
caption 0,"Utilisation du copier coller pour les images en panoramic"
picture 1 : left 1,10 : top 1,35 : width 1,480 : height 1,470
picture 2 : left 2,500 : top 2,35 : width 2,480 : height 2,470
button 3 : left 3,20 : top 3,3 : width 3,220 : on_click 3,copy
caption 3,"Copier l'image dans le presse papier"
button 4 : left 4,520 : top 4,3 : width 4,260 : on_click 4,coll
caption 4,"Coller l'image dans le picture 2 (cliquez 2 fois)"
button 5 : left 5,250 : top 5,3 : width 5,25 : caption 5,"*" : on_click 5,point
hint 5,"Dessiner des points"
button 6 : left 6,280 : top 6,3 : width 6,25 : caption 6,"/" : on_click 6,ligne
hint 6,"Dessiner des lignes"
button 7 : left 7,310 : top 7,3 : width 7,25 : caption 7,"o" : on_click 7,rond
hint 7,"Dessiner des cercles"
button 8 : left 8,340 : top 8,3 : width 8,25 : caption 8,"c" : on_click 8,carre
font_name 8,"Webdings" : hint 8,"Dessiner des rectangles"
button 9 : left 9,370 : top 9,3 : width 9,25 : caption 9,"C" : on_click 9,coul
hint 9,"Dessiner en blanc ou en couleurs"
button 10 : left 10,400 : top 10,3 : width 10,25 : caption 10,chr$(215)
hint 10,"Effacer l'image" : on_click 10,eff1
alpha 11 : left 11,370 : top 11,28 : width 11,25 : height 11,5
button 12 : left 12,790 : top 12,3 : width 12,25 : caption 12,chr$(215)
hint 12,"Effacer l'image" : on_click 12,eff2
2d_target_is 1 : print_target_is 1
print "Commencez d'abord par faire un dessin dans le picture 1 (celui-ci)"
on_click 1,dessin

end

copy:
a$="C:\Progra~1\IRFANVIEW\i_view32.exe /capture=3 "
a$=a$+"/crop=(10,35,480,480) /clipcopy /killmesoftly "
execute_wait a$
return

coll:
execute "C:\Progra~1\IRFANVIEW\i_view32.exe /clippaste /convert=c:\Prv.bmp"
file_load 2,"C:\Prv.bmp"
return

dessin:
x=mouse_x_position(1) : y=mouse_y_position(1)
if k=1
 a=rnd(255) : b=rnd(255) : c=rnd(255)
 2d_fill_color a,b,c
 2d_pen_color a,b,c
else
 2d_fill_color 255,255,255
 2d_pen_color 0,0,0
end_if
if id$="p" then 2d_point x,y
if id$="l" then 2d_line x,y,w,z
if id$="r" then 2d_circle x,y,w/10
if id$="c" then 2d_rectangle x,y,w,z
w=x : z=y
return

point:
id$="p"
return

ligne:
id$="l"
return

rond:
id$="r"
return

carre:
id$="c"
return

coul:
k=1-k
color 11,236,233*(1-k),216*(1-k)
return

eff1:
color 1,255,255,255
return

eff2:
color 2,255,255,255
return