Encore un lanceur de programmes

' program_launcher.bas

' Le programme construit un menu hiérarchisé à partir d'un fichier texte nommé program_launcher.ini.
' Ce fichier a la structure suivante:
'  sousmenu 1
'  sousmenu 2
'  *sousmenu 1
'  *sousmenu 2
'  **sousmenu 1
'  ** sousmenu 2
'  *sousmenu 3
'  sousmenu 3
'  *sousmenu 1
' 
' Les * repsésentent des espaces.
' Chaque ligne "terminale" peut être suivie de # suivi du chemin du programme à lancer
' ## signifie "Sortie"
'
' Exemple:
' Fichier
'  Sortie##
' Développement
'  Panoramic#"C:\Program Files (x86)\Panoramic Editor V 0.9.29\PANORAMIC_EDITOR V0 9 29i8 du 08 04 2019.exe"
'  KGF.chm#"C:\Users\klausgunther\Documents\Mes projets\Mes projets Panoramic\Help file\KGF_CHM\KGF.chm"

label click
dim ini$ : ini$ = "program_launcher.ini"

dim no%, table_no%(10),index_no%, s$, cnt%, p$, i%, progs$(300)

caption 0,"Program Launcher"
height 0,60 : width 0,300

if file_exists(ini$)=0
  file_open_write 1,ini$
  file_writeln 1,"Fichier"
  file_writeln 1," Sortie##"
  file_close 1
end_if

file_open_read 1,ini$
no% = 1
main_menu no%
index_no% = 0
table_no%(index_no%) = no%

while file_eof(1)=0

  file_readln 1,s$
  i% = instr(s$,"#")
  if i%>0
    p$ = mid$(s$,i%+1,len(s$))
    s$ = left$(s$,i%-1)
  else
    p$ = ""
  end_if
  cnt% = 0
  while left$(s$,1)=" "
    s$ = mid$(s$,2,len(s$))
    cnt% = cnt% + 1
  end_while
 
' message "["+s$+"]  ["+p$+"]  cnt%="+str$(cnt%) 
  if cnt%>index_no%
    index_no% = index_no% + 1
    table_no%(index_no%) = no%
  else
    if cnt%<index_no%
      index_no% = cnt%
    end_if
  end_if
 
 
  no% = no%+ 1
  sub_menu no% : parent no%,table_no%(index_no%) : caption no%,s$
  if p$<>""
    on_click no%,click
    progs$(no%) = p$
  end_if
 
end_while

file_close 1
end

click:
  p$ = progs$(number_click)
  if p$="#" then terminate
  execute p$
  return

Fichier
 Sortie##
Développement
 Panoramic#"C:\Program Files (x86)\Panoramic Editor V 0.9.29\PANORAMIC_EDITOR V0 9 29i8 du 08 04 2019.exe"
 KGF.chm#"C:\Users\klausgunther\Documents\Mes projets\Mes projets Panoramic\Help file\KGF_CHM\KGF.chm"