jeu des 3 portes (statistiques)

' Il s'agit d'un jeu télévisé américain. Dans ce jeu le candidat a
' devant lui 3 portes fermées. Derrière l'une de ces portes il
' y a une voiture et derrière chacune des autres, une chèvre.
'
' Si le candidat désigne la porte derrière laquelle se trouve la
' voiture, il la gagne.
'
' Le jeu se passe ainsi. Le candidat désigne une porte. Le
' présentateur (qui sait où se trouve la voiture) n'ouvre pas
' cette porte, mais en ouvre une autre derrière laquelle se trouve une chèvre.
'
' Le candidat a droit à un autre essai dans lequel il peut
' maintenir son choix initial ou en changer. A votre avis, doit-il
' le maintenir, en changer, ou est-ce indifférent ?

dim k,solution_connu_du_presentateur,choix_candidat,gagne,perdu,porte_avec_chevre
dim nb_de_test

font_size 0,24
nb_de_test=100

for k=1 to nb_de_test
   solution_connu_du_presentateur=tirage()                    :' le presentateur connait le numéro de porte gagnante
   choix_candidat=aleatoire()                                 :' le candidat choisit au hasard
   porte_avec_chevre=presentateur_ouvre_porte()               :' cette porte n'est pas celle choisi par le candidat, ni celle où se trouve la voiture
   '
   ' Enlever le REM si le candidat doit changer
REM   choix_candidat=changer_choix_initial(porte_avec_chevre) :' le candidat doit-il changer son choix initial maintenant qu'il sait où est une "porte_avec_chevre" ?
   if choix_candidat=solution_connu_du_presentateur
      gagne=gagne+1
   else
      perdu=perdu+1
   end_if
next k

print_locate 0,0 : print "GAGNE = ",gagne
print_locate 0,48 : print "PERD = ",perdu

END
fnc tirage()
   result aleatoire()   :' numéro de la porte gagnante
end_fnc

fnc aleatoire()
   result int(rnd(3)+1)   :' un nombre au hasard compris entre 1 et 3
end_fnc

fnc presentateur_ouvre_porte()
 dim_local temp
 ' renvoie un numéro de porte qui n'est pas le "choix_candidat" et n'est pas la "solution_connu_du_presentateur"
   if solution_connu_du_presentateur=1
      select choix_candidat
         case 1: temp=2 :' ou 3
         case 2: temp=3
         case 3: temp=2
      end_select
   end_if
   if solution_connu_du_presentateur=2
      select choix_candidat
         case 1: temp=3
         case 2: temp=3 :' ou 1
         case 3: temp=1
      end_select
   end_if
   if solution_connu_du_presentateur=3
      select choix_candidat
         case 1: temp=2
         case 2: temp=1
         case 3: temp=1 :' ou 2
      end_select
   end_if
   result temp
end_fnc

fnc changer_choix_initial(porte_avec_chevre)
 dim_local temp
  ' renvoie un numéro de porte qui n'est plus le "choix_candidat" et n'est pas la "porte_avec_chevre"
   if porte_avec_chevre=1
      select choix_candidat
         case 2: temp=3
         case 3: temp=2
      end_select
   end_if
   if porte_avec_chevre=2
      select choix_candidat
         case 1: temp=3
         case 3: temp=1
      end_select
   end_if
   if porte_avec_chevre=3
      select choix_candidat
         case 1: temp=2
         case 2: temp=1
      end_select
   end_if
   result temp
end_fnc