Un jeu qui va vous énerver!

Sujet: Un jeu qui va vous énerver! Mer 3 Jan 2018 - 12:25

Bonjour à tous, Very Happy

Et tout d'abord, UNE BONNE ANNÉE ET UNE BONNE SANTÉ à tous les PANORAMICIENS et plus particulièrement à Papydall!
Voilà, je me suis amusé à faire un petit jeu en 3d de moins de 50 lignes de code.
Le principe est simple: Vous êtes enfermés dans un cube. A l'intérieur de celui-ci rebondit dans tous les sens une balle folle! Vous avez une épine (un cône) que vous faites aller de droite à gauche ou de haut en bas avec la souris et que vous déplacez vers vous ou vers le fond avec les flèches haut et bas. Vous devez crever la balle avec cette épine!
C'est simple, mais presque impossible à faire. J'y suis arrivé une seule fois lors de mes essais! Alors, j'ai rajouté la possibilité de stopper la balle en appuyant sur la touche espace. Et même là, vous aurez quand même du mal à éclater la balle, car il faut qu'elle soit bien positionnée et que vous ameniez votre épine au bon endroit! Mais c'est faisable!
Alors ne vous énervez pas trop avec ce jeu et ne cassez pas votre écran ou votre ordi!

Code:: dim i,x,y,z,dx,dy,dz:i=1
label bouge
midi_on:midi_instrument 127:midi_volume 127
init()
timer 99:timer_interval 99,1:on_timer 99,bouge
end

bouge:
   timer_off 99
   select scancode
   case 27:terminate
   case 32:i=i*-1:pause 50
   case 38:3d_z_position 9,o3d_z_position(9)+0.05
   case 40:3d_z_position 9,o3d_z_position(9)-0.05
   end_select
   if i=1
   3d_position 8,o3d_x_position(8)+dx,o3d_y_position(8)+dy,o3d_z_position(8)+dz
   if o3d_x_position(8)>2.5 or o3d_x_position(8)<-2.5 then 3d_x_position 8,o3d_x_position(8)-dx:dx=dx*-1
   if o3d_y_position(8)>2.5 or o3d_y_position(8)<-2.5 then 3d_y_position 8,o3d_y_position(8)-dy:dy=dy*-1
   if o3d_z_position(8)>2.5 or o3d_z_position(8)<-2.5 then 3d_z_position 8,o3d_z_position(8)-dz:dz=dz*-1
   end_if
   3d_x_position 9,-1*(mouse_x_position(1)/screen_x/5)+2.5:3d_y_position 9,-1*(mouse_y_position(1)/screen_y/5)+2.5
   if o3d_z_position(9)>2.55 then 3d_z_position 9,2.55
   if o3d_z_position(9)<-2 then 3d_z_position 9,-2
   if o3d_collision(8,9)=1
   3d_text 1,"BRAVO!":3d_y_rotate 1,180::3d_x_position 1,1.75:3d_y_position 1,1.25:midi_play 60,4:3d_hide 8
   if message_information_yes_no("Continuer?")<>1 then midi_off:terminate
   3d_delete_all:delete 1:init()
   end_if
   timer_on 99
return

sub init()
   full_space 0:' construction de la scene 3d et du cube
   scene3d 1:full_space 1:cam_z_position -2:light_position 0,0,-100000
   3d_cube 2,5:3d_position 2,0,0,-5:3d_color 2,96,96,96:' fond
   3d_cube 3,5:3d_position 3,5,0,0 :3d_color 3,0,0,192:' droit
   3d_cube 4,5:3d_position 4,-5,0,0:3d_color 4,192,0,0:' gauche
   3d_cube 5,5:3d_position 5,0,5,0 :3d_color 5,192,128,0:' haut
   3d_cube 6,5:3d_position 6,0,-5,0:3d_color 6,0,128,0:' bas
   3d_cube 7,5:3d_position 7,0,0,5 :3d_color 7,225,128,64:' avant
' LA BOULE
   3d_sphere 8,0.2:x=rnd(5)-2.5:y=rnd(5)-2.5:z=rnd(5)-2.5
   dx=0.05+rnd(10)/1000:dy=0.05+rnd(10)/1000:dz=0.05+rnd(10)/1000
   3d_position 8,x,y,z:3d_transparent 8,120:3d_collision_as_point 8
' Le CONE
   3d_cone 9,0.5,0.1:3d_scale 9,0.25,0.25,0.25
   3d_x_rotate 9,270:3d_z_position 9,-0.5:3d_collision_as_faces 9
end_sub