Capture d'une zone de l'écran total

' Capture d'une zone de l'écran total -> fichier ou clipboard
' NB: DLL de Nardo26: Pick.dll, à récupérer sur son site:
'    http://nardo26.lescigales.org/dll-diverses-fonctions-28.html
DIM x%,y%,w%,h%,et%,el%,a$,b$,fr$
fr$ = "C:\TEMP\Capture.bmp": ' ou fr$ = "" -> clipboard)

BORDER_SMALL 0: FONT_BOLD 0: WIDTH 0,260: HEIGHT 0,65: FONT_NAME 0,"Arial"
  CAPTION 0," CAPTURE  D'UNE  ZONE  DE  L'ÉCRAN": COLOR 0,200,255,255: FONT_SIZE 0,11
ALPHA 2: TOP 2,5: CAPTION 2,"1) Click le coin supérieur gauche"
b$ = "0"
WHILE b$ = "0"
    Pickmouse(): a$ = CLIPBOARD_STRING_PASTE$: b$ = MID$(a$,9,1)
    PAUSE 50
END_WHILE
x% = VAL(LEFT$(a$,4)): y% = VAL(MID$(a$,5,4))
et% = 3: el% = 20: ' épaisseur trait, 1/2 longueur trait
FORM 7: BORDER_HIDE 7: TOP 7,y%-el%: LEFT 7,x%-et%/2: WIDTH 7,et%: HEIGHT 7,2*el%
    COLOR 7,255,0,255
FORM 8: BORDER_HIDE 8: TOP 8,y%-et%: LEFT 8,x%-el%: WIDTH 8,2*el%: HEIGHT 8,et%
    COLOR 8,255,0,255
CAPTION 2,"2) Click le coin inférieur droit"
PAUSE 500
b$ = "0"
WHILE b$ = "0"
    Pickmouse(): a$ = CLIPBOARD_STRING_PASTE$: b$ = MID$(a$,9,1)
    PAUSE 50
END_WHILE
w% = VAL(LEFT$(a$,4))-x%: h% = VAL(MID$(a$,5,4))-y%
DELETE 7: DELETE 8
Capture_T(x%,y%,w%,h%,fr$)
CAPTION 2,"Image :  "+fr$

' Rect_Form(x%,y%,w%,h%,3,65536*255+256*255): ' pour voir
END
' ==============================================================================
SUB Pickmouse()
  ' Souris dans tout l'écran: position, boutons
  ' -> chaîne xxxxyyyyb -> clipboard
  DIM_LOCAL a$,bt%
  DLL_ON "C:\Panoramic\NARDO\pick.dll"
    a$ = STRING$(8," ")
    bt% = DLL_CALL1("GetMouseXY",ADR(a$))
  DLL_OFF
  CLIPBOARD_STRING_COPY a$+STR$(bt%): ' coordonnées et bouton
END_SUB
' ==============================================================================
SUB Capture_T(x,y,w,h,f$)
  ' Capture d'une zone de l'écran total, en x,y absolus, dimensions w x h,
  ' dans f$ (BMP), ou dans le presse-papier (clipboard) si f$ = ""
  ' ATTENTION: x et y absolus par rapport à la totalité de l'écran !
  DIM_LOCAL c2d%
  c2d% = NUMBER_2D_TARGET
  FORM 999: TOP 999,0: LEFT 999,0: WIDTH 999,SCREEN_X: HEIGHT 999,SCREEN_Y
    BORDER_HIDE 999: HIDE 999: 2D_TARGET_IS 999: WAIT 100: ' Tout l'écran
  IF w < 0 THEN x = x+w: w = ABS(w)
  IF h < 0 THEN y = y+h: h = ABS(h)
  IMAGE 1000: 2D_IMAGE_COPY 1000,x,y,x+w,y+h
  IF f$ = ""
      CLIPBOARD_COPY 1000
  ELSE
      FILE_SAVE 1000,f$
  END_IF
  2D_TARGET_IS c2d%: DELETE 999: DELETE 1000
END_SUB
' ==============================================================================
SUB Rect_Form(x%,y%,w%,h%,e%,rgb%)
  ' Tracé d'un rectangle sur tout l'écran
  DIM_LOCAL f%,r%,g%,b%
  r% = INT(rgb%/65536): g% = BIN_AND(rgb%,65280)/256: b% = BIN_AND(rgb%,255)
  f% = 890: FORM f%: COLOR f%,r%,g%,b%
  BORDER_HIDE f%: TOP f%,y%-e%/2: LEFT f%,x%-e%/2: WIDTH f%,w%+e%: HEIGHT f%,e%
  f%=f%+1: FORM f%: COLOR f%,r%,g%,b%
  BORDER_HIDE f%: TOP f%,y%+h%-e%/2: LEFT f%,x%-e%/2: WIDTH f%,w%+e%: HEIGHT f%,e%
  f%=f%+1: FORM f%: COLOR f%,r%,g%,b%
  BORDER_HIDE f%: TOP f%,y%-e%/2: LEFT f%,x%-e%/2: WIDTH f%,e%: HEIGHT f%,h%+e%
  f%=f%+1: FORM f%: COLOR f%,r%,g%,b%
  BORDER_HIDE f%: TOP f%,y%-e%/2: LEFT f%,x%+w%-e%/2: WIDTH f%,e%: HEIGHT f%,h%+e%
END_SUB
' ==============================================================================

picture 10 : full_space 10
execute_wait "SnippingTool.exe"
clipboard_paste 10

picture 10 : full_space 10
execute_wait "c:\ ....\SnippingTool.exe" :' Indiquer l'emplacement exact du fichier
clipboard_paste 10