Capture des replay TV

' Captvty_lanc: Lancement de Captvty (capture de rattrapage TV)
' Tous les programmes et fichiers sont regroupés dans un même répertoire: C:\Captvty
LABEL Quit, Dirtv, Suptout, Exec, Voir
DIM dsk$,rp$,rv$,fd$,ec$,cptv$,ffm$,a$,b$,c$,d$,t$,r$,i%,j%,u,h%,m%,s%

dsk$ = LEFT$(DIR_CURRENT$,3): ' volume de travail
rp$ = dsk$+"Captvty\"
rv$ = rp$+"Vidéos\"
cptv$ = rp$+"Captvty.exe"
' Chemin éventuel de ffmpeg
ffm$ = "C:\UTIL\ffmpeg.exe": ' facultatif (durée vidéo, sinon elle sera estimée)
IF DIR_EXISTS(rp$)=0 THEN DIR_MAKE rp$
IF DIR_EXISTS(rv$)=0 THEN DIR_MAKE rv$
IF FILE_EXISTS(cptv$)=0 THEN MESSAGE "Exécutable Captvty.exe non trouvé !": TERMINATE
WIDTH 0,640: HEIGHT 0,520: BORDER_SMALL 0: ' COLOR 0,255,0,0
CAPTION 0,"                                            =  CAPTURE  DES  REPLAY  TV  ="
FONT_NAME 0,"Arial": FONT_SIZE 0,11: COLOR 0,200,255,255: ON_CLOSE 0,Quit
BUTTON 20: TOP 20,10: LEFT 20,20: WIDTH 20,240: CAPTION 20,"Supprimer tout le contenu actuel"
ON_CLICK 20,Suptout
BUTTON 25: TOP 25,TOP(20): LEFT 25,WIDTH(0)/2: WIDTH 25,240: CAPTION 25,"Lancer le programme de capture"
ON_CLICK 25,Exec
CHECK 26: TOP 26,TOP(25)+30: LEFT 26,LEFT(25)+20: WIDTH 26,250
CAPTION 26,"Arrêter le pc en fin de capture"
CONTAINER 1: TOP 1,0: LEFT 1,0: WIDTH 1,WIDTH(0)-16: HEIGHT 1,280: COLOR 1,255,0,0: HIDE 1
MEMO 2: PARENT 2,1: TOP 2,7: LEFT 2,50: WIDTH 2,WIDTH(1)-100: HEIGHT 2,HEIGHT(1)-20
COLOR 2,255,220,220: FONT_NAME 2,"Arial": FONT_SIZE 2,11
r$ = CHR$(13)+CHR$(10)
a$ = "    Dans la fenêtre de Captvty, cliquer l'icône de la chaîne, à gauche:"
a$=a$+r$+"                                        -> Chargement de la liste des émissions disponibles."
a$=a$+r$+"  - cliquer sur un élément pour afficher le résumé de l'émission"
a$=a$+r$+"  - double-clic sur l'élément pour lancer le téléchargement"
a$=a$+r$+"                                        ->  dans C:\Captvty\Vidéos (format MPEG-2 TS)"
a$=a$+r$+" On peut suivre la progression dans l'onglet 'Téléchargement'"
a$=a$+r$+" (NB: on peut lancer plusieurs téléchargements en même temps)."+r$
a$=a$+r$+" *********************** Conversion au format MPEG-4: ***********************"
a$=a$+r$+" Onglet Conversion, cliquer 'Vidéos' en bas. S'il n'y est pas, glisser/déposer"
a$=a$+r$+" le fichier capturé dans la fenêtre, puis cliquer la conversion désirée, en bas"
a$=a$+r$+" (MPEG-4)"
a$=a$+r$+" ********************* Conversion (externe) au format AVI: *********************"
a$=a$+r$+" avec FormatFactory."
ITEM_ADD 2,a$
ALPHA 9: TOP 9,TOP(1)+HEIGHT(1): LEFT 9,WIDTH(0)/2-100: CAPTION 9,"Contenu de "+rv$
FONT_BOLD 9
ALPHA 14: TOP 14,TOP(9)+18: LEFT 14,0: FONT_ITALIC 14: FONT_SIZE 14,10
CAPTION 14,"  Taille:      Durée:"
IF FILE_EXISTS(ffm$)= 0 THEN CAPTION 14,"Taille:      Durée(~):"
ALPHA 15: TOP 15,TOP(9)+18: LEFT 15,LEFT(9)+15
CAPTION 15,"(cliquer un article pour le voir)": FONT_ITALIC 15
LIST 30: TOP 30,TOP(15)+18: WIDTH 30,65: HEIGHT 30,HEIGHT(0)-HEIGHT(1)-70
LIST 31: TOP 31,TOP(30): LEFT 31,WIDTH(30): WIDTH 31,55: HEIGHT 31,HEIGHT(30)
FONT_SIZE 30,10: FONT_SIZE 31,10
LIST 10: TOP 10,TOP(30): LEFT 10,LEFT(31)+WIDTH(31): WIDTH 10,WIDTH(0)-WIDTH(30)-WIDTH(31)-16: HEIGHT 10,HEIGHT(30)
COLOR 10,255,255,190: FONT_SIZE 10,10: ON_CLICK 10,Voir
MEMO 11: LEFT 11,-1000: WIDTH 11,1200: HIDE 11
MEMO 12: WIDTH 12,600: HIDE 12
GOSUB Dirtv
END
' ==============================================================================
Quit:
TERMINATE
' ==============================================================================
Dirtv:
EXECUTE_WAIT "CMD.exe /C DIR /-C "+rv$+" | clip"
CLEAR 10: CLEAR 11: CLEAR 30: CLEAR 31: CLIPBOARD_PASTE 11
IF COUNT(11) > 0
    FOR i%=1 TO COUNT(11)
        a$ = ITEM_READ$(11,i%)
        IF a$<>"" AND LEFT$(a$,1)<>" " AND MID$(a$,22,5)<>"<REP>"
            t$ = LTRIM$(MID$(a$,18,18)): t$ = LEFT$(t$,LEN(t$)-5)
            t$=LEFT$(t$,LEN(t$)-1)+"."+RIGHT$(t$,1)
            a$ = RIGHT_POS$(a$,37)
            d$ = ""
            FileShort(rv$+a$): b$=CLIPBOARD_STRING_PASTE$
            IF FILE_EXISTS(ffm$)=1
                VideoDuree(b$): d$ = CLIPBOARD_STRING_PASTE$
            ELSE
                u=VAL(t$): j%=u/.190: ' très approximatif, en secondes
                h% = INT(j%/3600): m%=INT(j%-h%*3600)/60:s%=j%-h%*3600-m%*60
                d$ = STR$(h%)+":"+RIGHT$("0"+STR$(m%),2)+":"+RIGHT$("0"+STR$(s%),2)
            END_IF
            ITEM_ADD 10,a$: ITEM_ADD 30,t$+" M": ITEM_ADD 31,d$
        END_IF
    NEXT i%
END_IF
RETURN
' ==============================================================================
Suptout:
a$ = "Suppression définitive de tous les articles du répertoire Vidéos ?"
i% = MESSAGE_CONFIRMATION_YES_NO(a$)
IF i% = 1
    EXECUTE_WAIT "CMD.exe /C DEL /Q "+rv$+"\*.*"
    GOSUB Dirtv
END_IF
RETURN
' ==============================================================================
Exec:
HIDE 20: HIDE 25: SHOW 1
EXECUTE_WAIT cptv$
IF CHECKED(26) = 1
    EXECUTE "Cmd.exe /c %windir%\system32\Shutdown.exe -f -s -t 0": ' Arrêt du pc
ELSE
    GOSUB Dirtv
END_IF
RETURN
' ==============================================================================
Voir:
i% = ITEM_INDEX(10): ' Aperçu (ou visualisation complète...) de l'article choisi
IF i%>0 AND i%<=COUNT(10)
    a$ = rv$+ITEM_READ$(10,i%): FileShort(a$): a$ = CLIPBOARD_STRING_PASTE$
    EXECUTE_WAIT a$
END_IF
RETURN
' ==============================================================================
SUB FileShort(f$)
' Conversion chemin de f$ en chemin 'court' format Ms-Dos 8.3 -> clipboard
EXECUTE_WAIT "cmd /c for %A in ("+CHR$(34)+f$+CHR$(34)+") do @echo %~sA | clip"
CLIPBOARD_STRING_COPY LEFT$(CLIPBOARD_STRING_PASTE$, LEN(CLIPBOARD_STRING_PASTE$)-3)
END_SUB
' ==============================================================================
SUB VideoDuree(f$)
' Durée d'une vidéo, résultat dans le clipboard sous la forme hh:mm:ss
' (ffm$ = chemin de ffmpeg.exe)
DIM_LOCAL finf$, a$
finf$ = "Z:\Infos.txt"
EXECUTE_WAIT "CMD.exe /C "+ffm$ + " -i " + CHR$(34)+f$+CHR$(34) + " 2> "+ finf$
FILE_OPEN_READ 9,finf$
WHILE FILE_EOF(9)=0
    FILE_READLN 9,a$
    IF LEFT$(a$,10)="  Duration"
        a$ = MID$(a$,13,8): CLIPBOARD_STRING_COPY a$: EXIT_WHILE
    END_IF
END_WHILE
FILE_CLOSE 9: FILE_DELETE finf$
END_SUB
' ==============================================================================

 u=VAL(t$): j%=int(u/.190): ' approximatif, en secondes

 u=VAL(t$): j%=u/.190: ' approximatif, en secondes

 if numeric(t$) > 0 then u=VAL(t$): j%=u/.190: ' approximatif, en secondes

if numeric(t$) > 0 then u=VAL(t$): j%=u/.190: ' approximatif, en secondes

 quit:
 EXECUTE_WAIT "cmd /c taskkill /f /im Captvty.exe" : ' Tuer le pocessus
 TERMINATE
RETURN