PanExpress : l'éditeur Panoramic avec création d'objet

rem ============================================================================
rem           Orbites de l’ensemble de Julia
rem ============================================================================

Init()
 Orbites(0.77777777777, 0.1133333333)
' Orbites(0.1          , 0.84)
' Orbites(0.77789456123, 0.123456789)
' Orbites(0.60123456789, 0.10123456789)
 
terminate
rem ============================================================================
SUB Init()

    dim LX,LY,XI,XM,YI,YM,IM,A,B,XO,YO,F,I,X,Y,XX ,xp,yp,k,a$,r1,g1,b1,f$
    LX = 1000 : LY = 700
    Xi = -1.5 : XM = 1.5 : YI = -1 : YM = 1 : IM = 800
    width 0,LX : height 0,LY
    picture 10 : full_space 10 : 2d_target_is 10 : color 10,170, 170, 255
    application_title "Orbites de l'ensemble de Mandelbrot"
    caption 0,"Orbites de l’ensemble de Mandelbrot ... Tracé en cours ... <ESC> pour arrêter ..."

END_SUB
rem ============================================================================
' les paramètres a et b représentent respectivement la partie réelle et
' la partie imaginaire de la constante complexe.
' Jouez avec ces deux paramètres pour obtenir des jolis tracés
SUB Orbites(a,b)
    while scancode <> 27
       XO = (XM-XI) * RND(1) + XI : YO = (YM-YI) * RND(1) + YI
       X = XO : Y = YO  : ' Point de départ aléatoire
       for i = 1 to im
           xx = (x*x - y*y) - a : y = 2*x*y - b : x = xx
           xp = lx*(x-xi)/(xm-xi) : yp = ly*(y-yi)/(ym-yi)
           if i < (im*6/8) then b1 = 0 : else : b1 = 255          
           if i < (im / 2) then g1 = 0 : else : g1 = 255          
           if i < (im / 4) then r1 = 0 : else : r1 = 255
           2d_pen_color r1,g1,b1 : 2d_point xp,yp : 2d_point lx-xp,ly-yp
           if (x*x+y*y) > 4 then exit_for
       next i
    end_while
    caption 0, "Programme arrêté par l'utilisateur !"
    If message_information_yes_no("Voulez-vous sauvegarder l'image ?") = 1
       if dir_exists("Images") = 0 then dir_make "Images"
       f$ = "Images/" + str$(a) + "_" + str$(b) + ".bmp"
       file_save 10,f$
       message "L'image a été enrégistrée sous " + f$
    end_if
    
END_SUB
rem ============================================================================