Toolbar en Panoramic

' ==============================================================================
'                          Créer une Toolbar
'                            par ygeronimi
' ==============================================================================

' ------------------------------------------------------------------------------
'  VARIABLES
' ------------------------------------------------------------------------------

   dim i%,x%,no%,l%
   dim xmenu%,ymenu%
   dim p1%,p2%
   dim activebtn%
   dim etatbtn%(4)

' ------------------------------------------------------------------------------
'  CONSTANTES
' ------------------------------------------------------------------------------

'  >>> fichiers

   dim fdmenu$
   fdmenu$="FondMenu.bmp"
   dim imgbtn_over$(4)
   for i%=1 to 4 : imgbtn_over$(i%)="BtnPict_"+str$(i%)+"2.bmp"   : next i%
   dim imgbtn_click$(4)
   for i%=1 to 4 : imgbtn_click$(i%)="BtnPict_"+str$(i%)+"3.bmp"  : next i%
   dim imgbtn_inactive$(4)
   for i%=1 to 4 : imgbtn_inactive$(i%)="BtnPict_"+str$(i%)+"4.bmp" : next i%

'  >>> objets

   dim pictmenu%     : no%=no%+1 : pictmenu%=no%
   dim btn1%(4)      : for i%=1 to 4 : no%=no%+1 : btn1%(i%)=no% : next i%
   dim btn2%(4)      : for i%=1 to 4 : no%=no%+1 : btn2%(i%)=no% : next i%
   dim mem%          : no%=no%+1 : mem%=no%
   dim ActifInactif% : no%=no%+1 : ActifInactif%=no%
' ------------------------------------------------------------------------------
'  LABELS
' ------------------------------------------------------------------------------

   label SelectButton
   label ShowImgClic
   label Clic
  
' ------------------------------------------------------------------------------
'  INTERFACE
' ------------------------------------------------------------------------------

   height 0,480
   width 0,640
   top 0,(screen_y-height(0))/2
   left 0,(screen_x-width(0))/2
   color 0,240,205,152
   caption 0,"Créer une Toolbar Panoramic"
  
   picture pictmenu%
   top pictmenu%,0
   left pictmenu%,0
   height pictmenu%,36
   width pictmenu%,132
   file_load pictmenu%,fdmenu$
   on_mouse_move pictmenu%,SelectButton
  
   create_hide

   l%=2
   for i%=1 to 4
      picture btn1%(i%)
      height btn1%(i%),32
      width btn1%(i%),32
      top btn1%(i%),2
      left btn1%(i%),l%
      l%=l%+32
      file_load btn1%(i%),imgbtn_Over$(i%)
      cursor_point btn1%(i%)
      on_mouse_down btn1%(i%),ShowImgClic
      on_click btn1%(i%),Clic
   next i%

   l%=2
   for i%=1 to 4
      picture btn2%(i%)
      height btn2%(i%),32
      width btn2%(i%),32
      top btn2%(i%),2
      left btn2%(i%),l%
      l%=l%+32
      file_load btn2%(i%),imgbtn_inactive$(i%)
   next i%

   create_show
  
   memo mem%
   height mem%,height_client(0)-height(pictmenu%)-10
   width mem%,width_client(0)-10
   top mem%,height(pictmenu%)+5
   left mem%,5
   bar_both mem%
   text mem%,"Le monde merveilleux de Panoramic"
  
   check ActifInactif%
   top ActifInactif%,10
   left ActifInactif%,left(pictmenu%)+width(pictmenu%)+10
   width ActifInactif%,250
   mark_on ActifInactif%
   caption ActifInactif%,"Toolbar Active"
   font_bold ActifInactif%
   on_click ActifInactif%,Clic
end

' ------------------------------------------------------------------------------
'  MENUS LABELS
' ------------------------------------------------------------------------------

SelectButton:
   off_mouse_move pictmenu%
   xmenu% = mouse_x_position(pictmenu%)
   ymenu% = mouse_y_position(pictmenu%)
   for x%=1 to 4 : hide Btn1%(x%) : next x%
   p1%=2
   p2%=33
   for i%=1 to 4
      if Xmenu%>p1% and Xmenu%<p2%
         if ymenu%>2 and ymenu%<34
            activebtn%=i%
            show btn1%(i%)
            exit_for
         else
            for x%=1 to 4 : hide Btn1%(x%) : next x%
         end_if
      end_if
      p1%=p2%-1
      p2%=p2%+32
   next i%
   on_mouse_move pictmenu%,SelectButton
return

' ------------------------------------------------------------------------------

ShowImgClic:
   off_mouse_down btn1%(activebtn%)
   file_load btn1%(activebtn%),imgbtn_click$(activebtn%)
return

' ------------------------------------------------------------------------------

Clic:
   if number_click = btn1%(1)
      file_load btn1%(1),imgbtn_Over$(1)
      on_mouse_down btn1%(1),ShowImgClic
      if etatbtn%(1)=0
         font_bold mem%
         etatbtn%(1)=1
      else
         font_bold_off mem%
         etatbtn%(1)=0
      end_if
      return
   end_if

   if number_click = btn1%(2)
      file_load btn1%(2),imgbtn_Over$(2)
      on_mouse_down btn1%(2),ShowImgClic
      if etatbtn%(2)=0
         font_italic mem%
         etatbtn%(2)=1
      else
         font_italic_off mem%
         etatbtn%(2)=0
      end_if
      return
   end_if

   if number_click = btn1%(3)
      file_load btn1%(3),imgbtn_Over$(3)
      on_mouse_down btn1%(3),ShowImgClic
      if etatbtn%(3)=0
         font_underline mem%
         etatbtn%(3)=1
      else
         font_underline_off mem%
         etatbtn%(3)=0
      end_if
      return
   end_if

   if number_click = btn1%(4)
      file_load btn1%(4),imgbtn_Over$(4)
      on_mouse_down btn1%(4),ShowImgClic
      if etatbtn%(4)=0
         font_strike mem%
         etatbtn%(4)=1
      else
         font_strike_off mem%
         etatbtn%(4)=0
      end_if
      return
   end_if
  
   if number_click = ActifInactif%
      if checked(ActifInactif%)=0
         for x%=1 to 4 : show Btn2%(x%) : next x%
         caption ActifInactif%,"Toolbar Inactive"
      else
         for x%=1 to 4 : hide Btn2%(x%) : next x%
         caption ActifInactif%,"Toolbar Active"
      end_if
      return
   end_if
return

' ------------------------------------------------------------------------------
'  PROCEDURES
' ------------------------------------------------------------------------------

sub ActiveInactiveMenu(but%,etat%)
   if etat%=1
      show btn2%(but%)
   else
      hide btn2%(but%)
   end_if
end_sub