A propos de souris...

rem rem ' Essai Glisser-en-tactile
  dim x% , y% , x2% , y2%
  label go , spot

timer 10
  timer_interval 10,10
  on_timer 10,go
  timer_off 10

picture 20
  on_click 20,spot
 
end

go:
  x%=mouse_x_position(20)
  y%=mouse_y_position(20)
  caption 0,str$(x%)+" - "+str$(y%)
  left 20,x2%-left(20)
  top 20,y2%-top(20)
  x2%=x%
  y2%=y%
return

spot:
  if color_pixel_blue(20,5,5)=255
      color 20,255,0,0
      timer_on 10
  else
      color 20,255,255,255
      timer_off 10
  end_if
return

' ------ Déclaration des variables ------
  DIM x , y    : ' coordonnées de la souris
  DIM ap       : ' Flag d'appui du bouton gauche de la souris
  DIM cl        : ' Numéro de l'objet cliqué par la souris

' ------ Déclaration des labels ------
  LABEL menu , appel_timer

' ------ Création des objets ------
WIDTH 0,SCREEN_X : HEIGHT 0,SCREEN_Y
PICTURE 20 : ON_CLICK 20,menu
TIMER 30 : TIMER_INTERVAL 30,20 : ON_TIMER 30,appel_timer

END

' ------ Boucle principale ------
menu:
  cl=NUMBER_CLICK
  IF cl=20 THEN IF ap=1 : ap=0 : COLOR 20,255,255,255 : TIMER_OFF 30 : ELSE : ap=1 : COLOR 20,255,0,0 : TIMER_ON 30 : END_IF

RETURN

' ------ Boucle principale ------
appel_timer:
  x=MOUSE_X_POSITION(0) : y=MOUSE_Y_POSITION(0) : LEFT 20,x : TOP 20,y
RETURN

rem ============================================================================
dim px,py
width 0,600 : height 0,600
picture 10 : full_space 10 : 2d_target_is 10 : 2d_fill_on : 2d_fill_color 255,0,0
caption 0, "Deplacer la souris, le cercle vous suit.... <CLICK>  pour arrêter"
repeat
    px = mouse_x_position(10) : py = mouse_y_position(10)
    cls : 2d_circle px,py,30 : pause 1
until scancode <> 0
end
rem ============================================================================

rem ============================================================================
rem
rem        L   A T T R A C T E U R    D E   E D W A R D   L O R E N Z
rem
rem                      P A R   P A P Y D A L L
rem
rem ============================================================================
rem                 Attracteur de Lorenz
' Ces équations permettent de décrire les échanges thermiques entre l'atmosphère et l'océan.
rem     dx/dt = a * (y - x)
rem     dy/dt = b * x - y - x * z
rem     dz/dt = x * y - c * z

' a = le nombre de Prandtl. Indique la diffusivité thermique du milieu. On prend  10
' b = nombre de Rayleigh, indique la différence des températures des deux milieux.  On prend 28
' c  représente les déperditions d'énergie.  On prend 8/3
' x(t) représente l'intensité du mouvement de convection.
' y(t) représente la différence de température entre les courants ascendants et descendants.
' z(t) représente l'écart du profil de température vertical par rapport à un profil linéaire.
rem ============================================================================


dim a,b,c,dt,x,y,z,t,xe,ye,dx,dy,dz,xn,yn,zn
dim alfa,beta,offx,offy,zoom
dim MinMax(3,2)
dim u(3),v(3),w(3),xp(3)

init() : attracteur()
end
rem ============================================================================
SUB Init()
    width 0 ,700 : height 0 ,600
    caption 0," L'attracteur de Lorenz            <CLICK> pour arrêter"
    dt = .005
    a = 10   : b = 28   : c = 8 / 3   : ' Essayez ces différents paramètres
  ' a = 3    : b = 26.5 : c = 1
  ' a = 7    : b = 18   : c = 1
  ' a = 9.5  : b = 19   : c = 1
  ' a = 9.5  : b = 19   : c = 17/7

    Alfa = 135 * Pi / 180 : Beta = 20 * Pi / 180
    Offx = 0 : Offy = 24 : Zoom = 15 : x = 5 : y = 5 : z = 0
    MinMax(1, 1) = -30
    MinMax(1, 2) = 30
    MinMax(2, 1) = -30
    MinMax(2, 2) = 30
    MinMax(3, 1) = 0
    MinMax(3, 2) = 55
' matrice de projection
   u(1) = COS(Alfa) * COS(Beta) : u(2) = SIN(Alfa) * COS(Beta) : u(3) = SIN(Beta)
   v(1) = 0-SIN(Alfa) : v(2) = COS(Alfa) : v(3) = 0
   w(1) = 0-COS(Alfa) * SIN(Beta) : w(2) = 0-SIN(Alfa)* SIN(Beta):w(3)= COS(Beta)
   color 0,0,0,0 : 2d_pen_color 255,255,255
END_SUB
rem ============================================================================
SUB Tracer()
    xp(1) = u(1) * x + u(2) * y + u(3) * z
    xp(2) = v(1) * x + v(2) * y + v(3) * z
    xp(3) = w(1) * x + w(2) * y + w(3) * z

    xe = INT(320 * (xp(2) - Offx) * Zoom / 640 + 320 + .5)
    ye = INT(-240 * (xp(3) - Offy) * Zoom / 480 + 240 + .5)
END_SUB
rem ============================================================================
SUB Attracteur()
    t = t + dt : dx = a * (y - x) : dy = b * x - y - x * z : dz = x * y - c * z
    x = x + dx * dt : y = y + dy * dt : z = z + dz * dt
    tracer() : 2d_poly_from xe,ye

    WHILE scancode = 0
     t = t + dt : dx = a * (y - x) : dy = b * x - y - x * z : dz = x * y - c * z
     x = x + dx * dt : y = y + dy * dt : z = z + dz * dt

     IF x > 0 AND y < 0    THEN 2d_pen_color 0,0,255
     IF x > 0 AND y >= 0   THEN 2d_pen_color 0,255,0
     IF x <= 0 AND y < 0   THEN 2d_pen_color 255,0,0
     IF x <= 0 AND y >= 0  THEN 2d_pen_color 255,255,0
     tracer()
     2d_poly_to  xe,ye
   end_while
END_SUB
rem ============================================================================