multiple timers sans plantage : ruse de sioux!!!

' Panoramic 0.9.27i5

'   ==============================================================
'   =  Title  : Tickers
'   =
'   =  Author : Silverman
'   =
'   =  Date   : Février 2016
'   =
'   =  Version: 1.2
'   ==============================================================
'   Comments  : Créer une alternative aux timers
'   ==============================================================


' Le principe va être de créer un timer maitre, qui ne gèrera que les tickers.
' Contrairement à un timer, un ticker ne peut pas interrompre un event en cours,
' donc une boucle ne peut pas être stoppée inopinément. Ce système ne provoque pas
' de plantage, quelque soit le nombre de tickers utilisé(9999 maximum)!
' Un ticker n'est rien d'autre qu'un chronomètre(pseudo objet) associé à un
' objet invisible(un 'edit') qui déclenche l'événement via la commande 'text N,P'.
' Un ticker peut générer l'évènement ON_CHANGE.
' Dans tous les events, sans exception, il faudra stopper le timer maitre, ainsi
' il n'y a besoin que d'une seule commande pour bloquer temporairement tous les tickers.
'
'
'
' Les tickers s'utilises à peu près de la même façon que les timers:
'
' TICKER(N%)
' crée un pseudo objet ticker N% associé à un OBJET(un 'edit') invisible.(L'edit a le même numéro que le ticker)
'
' TICKER_INTERVAL(N%,delai%)
' défini l'interval de temps 'delai%' en milliseconde, du ticker N%. Par défaut, delai%=1000 ms
'
' PERFORM_TICKER_EVENT(N%)   <--- Cette commande doit être géré par le timer maitre !!!
' déclenche l'évènement si le delai% de 'TICKER_INTERVAL' est dépassé.
' 'objet%'=0 ne retourne pas d'erreur(pratique en programmation séquentielle)
'
' TICKER_ON(N%)
' met en pause le ticker N%
'
' TICKER_OFF(N%)
' redémarre le ticker N%
'
' ON_CHANGE N%,label
' exécute le programme à partir du label 'label' quand l'objet système N% a "changé"
'
' en plus, on peut connaitre l'état d'un ticker:
' TICKER_STATE(N%,0) :  0=false  /  1=true (true=event en cours d'exécution)
' TICKER_STATE(N%,1) :  0=start  /  1=pause
' TICKER_STATE(N%,2) :  nb d'image/sec affiché entre 2 appels(si >1 alors on a perdu des images)
' TICKER_STATE(N%,3) :  ticker_exist
'
' TICKER_TIME_SCALE(scale) : permet de créer un effet d'accélération/ralenti pour les graphismes.
'
' Il n'y a pas besoin de déclarer quoi que ce soit, juste copier les subs dans
' votre source. C'est tout!!!




label TIMER_MAITRE
label mon_event1,mon_event2,mon_event3,sortir


dim i

'
caption 0,"3 timers émulés !!!"
on_close 0,sortir


' un memo que l'on va redimensionner en temps reel
memo 4 : top 4,50

' un affichage
alpha 5 : top 5,200 : caption 5,"Redimensionnez la fenetre horizontalement!"

' on declare les tickers, à peu près de la même maniere qu'un timer
TICKER(1) : TICKER_INTERVAL(1,90) : on_change 1,mon_event1   :' surveille un affichage quelconque
TICKER(2) : TICKER_INTERVAL(2,50) : on_change 2,mon_event2   :' surveille une procédure consommatrice de temps
TICKER(3) : TICKER_INTERVAL(3,20) : on_change 3,mon_event3   :' surveille le redimensionnement du memo


' le timer maitre déclaré en dernier, doit avoir le temps d'intervalle plus court possible !!!
timer 10
timer_interval 10,1
on_timer 10,TIMER_MAITRE

END
' ##############################################################################
' #                                                                            #
' #                                Les EVENTs                                  #
' #                                                                            #
' ##############################################################################

' ##############################################################################
' on ne place que les subs 'PERFORM_TICKER_EVENT()' ici, rien d'autre!!!
TIMER_MAITRE:
 timer_off 10  :' empêche le timer maitre de s'appeler lui même
   PERFORM_TICKER_EVENT(1) :' surveille et déclenche, chaque fois que le délai est écoulé, l'event associé au ticker n°1
   PERFORM_TICKER_EVENT(2) :' surveille et déclenche, chaque fois que le délai est écoulé, l'event associé au ticker n°2
   PERFORM_TICKER_EVENT(3) :' surveille et déclenche, chaque fois que le délai est écoulé, l'event associé au ticker n°3
 timer_on 10
return


' event associé à l'objet n°1 :affichage quelconque
mon_event1:
 timer_off 10  :' bloque le timer maitre et les tickers
 '
 for i=1 to 40
    print " 000";
 next i
 wait 20 : cls   :' on ralenti un peu
 '
 timer_on 10  :' débloque le timer maitre et les tickers
return


' event associé à l'objet n°2 : émule une procédure consommatrice de temps
mon_event2:
 timer_off 10  :' bloque le timer maitre et les tickers
   wait 20
 timer_on 10  :' débloque le timer maitre et les tickers
return


' event associé à l'objet n°3 : redimensionne un memo en temps reel
mon_event3:
 timer_off 10  :' bloque le timer maitre et les tickers
   '
   width 4,width(0)-20
   '
 timer_on 10  :' débloque le timer maitre et les tickers
return


' sortir
sortir:
 timer_off 10 :' bloque le timer maitre et les tickers, pas utile ici mais bonne pratique de programmation
 terminate
return



' ##############################################################################
' #                                                                            #
' #                                Les SUBs  V1.4                              #
' #                                                                            #
' ##############################################################################

' ##############################################################################
'
sub TICKER(N%)
 if variable("memorise_tickers")=0
  dim memorise_tickers
  ' un tableau pour gérer le tickers
  dim TICKER_STATE(9999,5)
  TICKER_STATE(0,2)=1
 end_if
' erreur 1
   edit N% : hide N%
   if TICKER_STATE(0,0)=0
      TICKER_STATE(0,0)=NUMBER_TICKS
   end_if
   TICKER_STATE(N%,5)=1000
   TICKER_STATE(N%,1)=0
   TICKER_STATE(N%,4)=TICKER_STATE(0,0)+TICKER_STATE(N%,5)
   TICKER_STATE(N%,3)=1
   TICKER_STATE(N%,2)=1
end_sub


'
sub TICKER_INTERVAL(N%,delai%)
' erreur 2
   if TICKER_STATE(N%,3)=0 then message "(2)Le TICKER n°"+str$(N%)+" n'existe pas" : terminate
   if delai%<1 then message "(2)TICKER n°"+str$(N%)+": Délai nul ou négatif" : terminate
   TICKER_STATE(N%,4)=TICKER_STATE(N%,4)-TICKER_STATE(N%,5)+delai%
   TICKER_STATE(N%,5)=delai%
end_sub


'
sub PERFORM_TICKER_EVENT(N%)
' erreur 3
   if TICKER_STATE(N%,3)=0 then message "(3)Le TICKER n°"+str$(N%)+" n'existe pas" : terminate
   if TICKER_STATE(0,1)=0
      TICKER_STATE(0,0)=NUMBER_TICKS
      TICKER_STATE(0,1)=N%
   else
      if TICKER_STATE(0,1)=N% then TICKER_STATE(0,0)=NUMBER_TICKS
   end_if
   TICKER_STATE(N%,0)=0
   if TICKER_STATE(0,0)>=TICKER_STATE(N%,4)
      TICKER_STATE(N%,0)=1
      TICKER_STATE(N%,2)=TICKER_STATE(0,2)*int((TICKER_STATE(0,0)-TICKER_STATE(N%,4))/TICKER_STATE(N%,5))+1
      TICKER_STATE(N%,4)=TICKER_STATE(0,0)-mod(TICKER_STATE(0,0)-TICKER_STATE(N%,4),TICKER_STATE(N%,5))+TICKER_STATE(N%,5)
      if TICKER_STATE(N%,1)=0
         text N%,str$(NUMBER_TICKS)
      end_if
   end_if
end_sub


'
sub TICKER_ON(N%)
' erreur 4
   if TICKER_STATE(N%,3)=0 then message "(4)Le TICKER n°"+str$(N%)+" n'existe pas" : terminate
   TICKER_STATE(N%,1)=0
end_sub


'
sub TICKER_OFF(N%)
' erreur 5
   if TICKER_STATE(N%,3)=0 then message "(5)Le TICKER n°"+str$(N%)+" n'existe pas" : terminate
   TICKER_STATE(N%,1)=1
end_sub


'
sub TICKER_TIME_SCALE(scale)
' erreur 6
   if TICKER_STATE(N%,3)=0 then message "(6)Le TICKER n°"+str$(N%)+" n'existe pas" : terminate
   TICKER_STATE(0,2)=scale
end_sub