PANORAMIC et informatique de gestion (les tableaux)

' Exécutable d'affichage d'un chrono rotatif sur l'écran
' Paramètre dans le clipboard: fichier texte contenant les coordonnées d'affichage.
' Arrêt quand le fichier donné en paramètre n'existe plus
DIM ft$,a$,x%,y%,i%
ft$ = CLIPBOARD_STRING_PASTE$
FILE_OPEN_READ 1,ft$
    FILE_READLN 1,a$: x% = VAL(a$)
    FILE_READLN 1,a$: y% = VAL(a$)
FILE_CLOSE 1
WIDTH 0,120: HEIGHT 0,80: TOP 0,y%: LEFT 0,x%: BORDER_HIDE 0
COLOR 0,255,255,0: TO_FOREGROUND 0
FONT_NAME 0,"Wingdings 2": FONT_SIZE 0,64: FONT_BOLD 0: FONT_COLOR 0,128,0,0
i% = 135
WHILE FILE_EXISTS(ft$) = 1
    PRINT_LOCATE 28,0: PRINT CHR$(i%)
    i%=i%+1: IF i% > 146 THEN i% = 135
    WAIT 200
END_WHILE
TERMINATE

Nomcourt(Edp$): Edp$ = CLIPBOARD_STRING_PASTE$

' ------------------------------------------------------------------------------
'                    EXEMPLE D UTILISATION D UN OBJET
'                                LIST
'                          PAR : ygeronimi
' ------------------------------------------------------------------------------


' Je ne ferai pas dans le visuel dans cette exemple, les objets auront
' leurs attributs par defaut
' Le format des lignes du fichier de sauvegarde sera :
' N°d'enregistrement+;+Nom+;+Prénom+;
' ce qui correspond à un enregistrement dans un fichier *.csv

'  1/ je déclare mes variables pour les objets

  dim Obj_List%
  dim Obj_Alpha%(3)
  dim Obj_Edit%(3)
  dim Obj_Button%(3)
 
'  2/ je déclare mes variables d' incrémentation et systeme
'  -->incrementation
  dim i%
  dim no%
'  -->systeme
'  pour stocker une ligne récupérée dans l' objet LIST
  dim line$
'  pour recup de l'emplacement séparateur de données dans la ligne d' enregistrement
  dim sep%
'  numero de la ligne de l' enregistrement dans le fichier
  dim Nitem%
'  numero d' enregistrement attribué à l' enregistrement de la fiche affiché
  dim Nenrgt$
'  nom et prenom du contact
  dim Nom$
  dim Prenom$
 
'  3/ je déclare et initialise une variable pour retrouver mon dossier source
  dim Path$ : Path$=dir_current$
  if right$(path$,1)="\" : path$=left$(path$,len(path$)-1) : end_if
  Path$=path$+"\"
 
'  3/ je déclare le fichier de sauvegarde et j' initialise son adresse
  dim Dest$ : Dest$= Path$+"Carnet.txt"
 
'  4/ j' initialise mes variables objet en leur donnant un numéro
  no%=no%+1 : Obj_List%=no%
  for i%=1 to 3 : no%=no%+1 : Obj_Alpha%(i%)=no% : next i%
  for i%=1 to 3 : no%=no%+1 : Obj_Edit%(i%)=no%  : next i%
  for i%=1 to 3 : no%=no%+1 : Obj_Button%(i%)=no%  : next i%
 
'  5/ je déclare les labels
  label Selection
  label Nouveau
  label Supprimer
  label Enregistrer
  label AvantDeQuitter
 
'  6/ Je crée mon interface
'  --> définition des dimensions et de l' emplacement sur l' écran du formulaire 0
  height 0,300
  width 0,500
  top 0,(screen_y-height(0))/2
  left 0,(screen_x-width(0))/2
  caption 0,"Carnet d' adresse"

'  --> définition des dimensions et de l' emplacement des objets sur le form 0
  List Obj_List%
  height Obj_List%,260
  width Obj_List%,200
  top Obj_List%,5
  left Obj_List%,5
  on_click Obj_List%,Selection

  alpha  Obj_Alpha%(1)
  top Obj_Alpha%(1),5
  left Obj_Alpha%(1),210
  caption Obj_Alpha%(1),"N° Enregistrement"
 
  Edit Obj_Edit%(1)
  top Obj_Edit%(1),20
  left Obj_Edit%(1),210
  width Obj_Edit%(1),60
  inactive Obj_Edit%(1)
 
  alpha  Obj_Alpha%(2)
  top Obj_Alpha%(2),45
  left Obj_Alpha%(2),210
  caption Obj_Alpha%(2),"Nom"

  Edit Obj_Edit%(2)
  top Obj_Edit%(2),60
  left Obj_Edit%(2),210
  width Obj_Edit%(2),150
 
  alpha  Obj_Alpha%(3)
  top Obj_Alpha%(3),85
  left Obj_Alpha%(3),210
  caption Obj_Alpha%(3),"Prénom"

  Edit Obj_Edit%(3)
  top Obj_Edit%(3),100
  left Obj_Edit%(3),210
  width Obj_Edit%(3),200
 
  Button Obj_Button%(1)
  top Obj_Button%(1),height(0)-height(Obj_Button%(1))-35
  left Obj_Button%(1),250
  caption Obj_Button%(1),"Nouveau"
  cursor_point Obj_Button%(1)
  on_click Obj_Button%(1),Nouveau
 
  Button Obj_Button%(2)
  top Obj_Button%(2),height(0)-height(Obj_Button%(2))-35
  left Obj_Button%(2),250+width(Obj_Button%(2))+5
  caption Obj_Button%(2),"Supprimer"
  cursor_point Obj_Button%(2)
  on_click Obj_Button%(2),Supprimer
 
  Button Obj_Button%(3)
  top Obj_Button%(3),height(0)-height(Obj_Button%(2))-35
  left Obj_Button%(3),250+width(Obj_Button%(2))+10+width(Obj_Button%(3))
  caption Obj_Button%(3),"Enregistrer"
  cursor_point Obj_Button%(3)
  on_click Obj_Button%(3),Enregistrer

'  --> si le fichier de sauvegarde existe je le charge dans l' objet LIST
  if file_exists(Dest$)=1 : file_load Obj_List%,Dest$ : end_if
end

'  7/ je crée les fonctions liées aux objets
'  fonction de selection d' une fiche dans l' objet LIST par click
  Selection:
      if Count(Obj_List%)>0
        Nitem%=item_index(Obj_List%)
        Line$=item_index$(Obj_List%)

        sep%=instr(Line$,";")
        Nenrgt$=left$(Line$,sep%-1)
        Line$=right$(Line$,len(Line$)-sep%)
       
        sep%=instr(Line$,";")
        Nom$=left$(Line$,sep%-1)
        Line$=right$(Line$,len(Line$)-sep%)
       
        sep%=instr(Line$,";")
        Prenom$=left$(Line$,sep%-1)
       
        text Obj_Edit%(1),Nenrgt$
        text Obj_Edit%(2),Nom$
        text Obj_Edit%(3),Prenom$
      end_if
  return

'  fonction de création d' une nouvelle fiche, formulaire vierge avec attribution
'  du numéro d' enregistrement
  Nouveau:
      text Obj_Edit%(1),""
      text Obj_Edit%(2),""
      text Obj_Edit%(3),""

      Nitem%=0
      Line$=""
      Nom$=""
      Prenom$=""
     
      if Count(Obj_List%)>0
        Line$=item_read$(Obj_List%,Count(Obj_List%))
        sep%=instr(Line$,";")
        Nenrgt$=left$(Line$,sep%-1)
      else
        Nenrgt$="0"
      end_if
      Nenrgt$=str$(val(Nenrgt$)+1)
      text Obj_Edit%(1),Nenrgt$
  return

'  fonction de suppression d' une fiche enregistrement
  Supprimer:
      if Nitem%>0
        item_delete Obj_List%,Nitem%

        text Obj_Edit%(1),""
        text Obj_Edit%(2),""
        text Obj_Edit%(3),""

        Line$=""
        Nitem%=0
        Nenrgt$=""
        Nom$=""
        Prenom$=""
       
        file_save Obj_List%,Dest$
      end_if
  return

'  enregistrer une nouvelle fiche ou les modifs d' une fiche
  Enregistrer:
      if text$(Obj_Edit%(1))="" or text$(Obj_Edit%(2))="" or text$(Obj_Edit%(3))=""
        Message "Tous les champs doivent être remplis !"
        return
      else
        Line$=text$(Obj_Edit%(1))+";"+text$(Obj_Edit%(2))+";"+text$(Obj_Edit%(3))+";"
        if Nitem%=0
            Item_add Obj_List%,Line$
        else
            item_delete Obj_List%,Nitem%
            item_insert Obj_List%,Nitem%,Line$
        end_if
      end_if
 
      text Obj_Edit%(1),""
      text Obj_Edit%(2),""
      text Obj_Edit%(3),""

      Line$=""
      Nitem%=0
      Nenrgt$=""
      Nom$=""
      Prenom$=""
 
      file_save Obj_List%,Dest$
  return