Outils de récupération et gestion des mots clés Panoramic

 ' -------------------------------------
 ' Programme  : Création_Aide_Panoramic.bas
 ' Créateur  : MiNiBuG
 ' Date      : 02/10/2021
 ' -------------------------------------
 '
 ' PRECEDURE POUR LA CREATION DES FICHIERS MOTS CLES
 '
 '  1) Ouvrir le programme 'ResourceHacker'
 '  2) Ouvrir le fichier de l'editeur panoramic (ex : PANORAMIC_EDITOR_0.9.29i9.exe)
 '  3) Doucle-cliquez sur la ligne 'RCData' dans la liste pour la développer
 '  4) Sélectionnez le fichier 'KEYWORDS ...'
 '  5) Cliquez ensuite avec le bouton de droite sur la même ligne 'KEYWORDS ...'
 '  5) Sélectionnez 'Save resource to a BIN file...'
 '  6) Choisir ensuite le répertoire correspondant ou est installé le programme 'Aide_Panoramic.exe'
 '  7) Refermer le programme 'ResourceHacker'
 '  8) Lancer l'exécution de 'Aide_Panoramic.exe'
 '  ATTENTION : Le fichier doit se trouver au même endroit que 'KEYWORDS.bin'
 '  9) Un dossier 'Aide_Panoramic.exe' est créé
 ' 10) Tous les mots clés sont repertoriés sous forme de fichiers
 '
 ' Voici la structure le chaque fichier correspondant à un mot clé :
 '
 ' 1 - Mot clé
 ' 2 - Titre résumé du mot clé en majuscule en francais
 ' B - Titre résumé du mot clé en majuscule en anglais
 ' a - Titre résumé du mot clé en minuscule en francais
 ' C - Titre résumé du mot clé en minuscule en anglais
 ' 3 - Classement du mot clé en francais
 ' D - Classement du mot clé en anglais
 ' 4 - Explication détaillées du mot clé en francais
 ' E - Explication détaillées du mot clé en anglais
 ' 5 - Syntaxe  du mot clé en francais
 ' G - Syntaxe  du mot clé en anglais
 ' 6 - Utilisation du mot clé en francais
 ' H - Utilisation du mot clé en anglais
 ' 7 - Erreur concernant le mot clé en francais
 ' I - Erreur concernant le mot clé en anglais
 ' 8 - Exemple du mot clé en francais
 ' J - Exemple du mot clé en anglais
 ' 9 - Mots clés en rapport
 '
 ' Pour la gestion et l'affichage relatif aux mots clés, reportez vous au programme 'Gestion_Aide_Panoramic.exe'
 '
 ' -------------------------------------

  DIM a% , n$ , f$

  WIDTH 0,600 : HEIGHT 0,100 : CAPTION 0,"Création des fichiers d'aide"

  DLIST 1 : FILE_LOAD 1,"KEYWORDS.bin"
 
  IF DIR_EXISTS("Liste_Mots_Cles_Panoramic")=0 THEN DIR_MAKE "Liste_Mots_Cles_Panoramic"

  PRINT " Création des fichiers en cours..."
 
  a%=1
  REPEAT
      n$=ITEM_READ$(1,a%)
      IF n$="0"
        a%=a%+1 : f$=ITEM_READ$(1,a%)
        FILE_OPEN_WRITE 1,"Liste_Mots_Cles_Panoramic\"+f$+".txt" : FILE_CLOSE 1
        PRINT_LOCATE 1,20 : PRINT " Création du fichier "+f$+STRING$(50," ")
        a%=a%+1
      ELSE
        FILE_OPEN_APPEND 1,"Liste_Mots_cles_Panoramic\"+f$+".txt"
            REPEAT
              n$=ITEM_READ$(1,a%)
              IF n$<>"0"
                  FILE_WRITELN 1,ITEM_READ$(1,a%)
                  a%=a%+1
              END_IF
            UNTIL n$="0" OR a%=COUNT(1) 
        FILE_CLOSE 1
      END_IF
  UNTIL a%=COUNT(1)
 
  PRINT_LOCATE 1,20
  PRINT " Les fichiers sont tous créés dans le dossier "+DIR_CURRENT$+"\Liste_Mots_Cles_Panoramic\"
 
  FOR a%=5 TO 1 STEP -1
      PRINT_LOCATE 1,40 : PRINT " Fermeture dans "+STR$(a%)+" secondes"
      PAUSE 1000 
  NEXT a%
 
  TERMINATE
' ------------------------------------------------------------------------------
' ------------------------------------------------------------------------------

' ------------------------------------------------------------------------------
' Programme  : Gestion_Aide_Panoramic.bas
' Créateur  : MiNiBuG
' Date      : 02/10/2021
' ------------------------------------------------------------------------------
'
' PRECEDURE POUR LA GESTION ET L AFFICHAGE DES FICHIERS MOTS CLES
'
' Voici la structure de chaque fichier correspondant à un mot clé :
'
' 1 - Mot clé
' 2 - Titre résumé du mot clé en majuscule en francais
' B - Titre résumé du mot clé en majuscule en anglais
' a - Titre résumé du mot clé en minuscule en francais
' C - Titre résumé du mot clé en minuscule en anglais
' 3 - Classement du mot clé en francais
' D - Classement du mot clé en anglais
' 4 - Explication détaillées du mot clé en francais
' E - Explication détaillées du mot clé en anglais
' 5 - Syntaxe  du mot clé en francais
' G - Syntaxe  du mot clé en anglais
' 6 - Utilisation du mot clé en francais
' H - Utilisation du mot clé en anglais
' 7 - Erreur concernant le mot clé en francais
' I - Erreur concernant le mot clé en anglais
' 8 - Exemple du mot clé en francais
' J - Exemple du mot clé en anglais
' 9 - Mots clés en rapport
'
' Pour la création des fichiers relatif aux mots clés, reportez vous au programme 'Creation_Aide_Panoramic.bas'
'
' ------------------------------------------------------------------------------

DIM no% , a% , n$ , f$ , x% , y% , fc$ , fr$ , tp$ , ch$ , lg% , v1$

lg%=1
' lg%=1 : Aide en Anglais / Sinon lg%=0 : Aide en francais

DIM ListInfo% , ListMc% , AlphaMc%

LABEL dimension , SelectionMotCle

WIDTH 0,1000 : HEIGHT 0,800 : CAPTION 0,"Gestion des mots clés Panoramic"
  x%=WIDTH_CLIENT(0) : y%=HEIGHT_CLIENT(0) : ON_RESIZE 0,dimension : no%=no%+1   

MEMO no% : LEFT no%,5 : TOP no%,5 : WIDTH no%,x%-260 : HEIGHT no%,y%-10
  BAR_VERTICAL no% : COLOR no%,255,255,200 : ListInfo%=no% : no%=no%+1 
 
LIST no% : LEFT no%,x%-250 : TOP no%,5 : WIDTH no%,245 : HEIGHT no%,y%-10
  HIDE no% : ON_CLICK no%,SelectionMotCle : COLOR no%,255,255,200
  ListMc%=no% : no%=no%+1   
 
  IF DIR_EXISTS(DIR_CURRENT$+"\Liste_Mots_Cles_Panoramic")=0
    MESSAGE "Le dossier contenant les mots clès n'a pas été trouvé !"
    TERMINATE
  END_IF

  DIR_CHANGE DIR_CURRENT$+"\Liste_Mots_Cles_Panoramic"
     
  f$=FILE_FIND_FIRST$
  REPEAT
      f$=FILE_FIND_NEXT$
      IF f$<>"_" AND f$<>".." THEN ITEM_ADD ListMc%,LEFT$(f$,LEN(f$)-4)
  UNTIL f$="_"
     
  SHOW ListMc%
 
ALPHA no% : LEFT no%,5 : TOP no%,5 : AlphaMc%=no% : no%=no%+1   

END

' ------------------------------------------------------------------------------

dimension:

  OFF_RESIZE 0
 
  IF WIDTH(0)<600 THEN WIDTH 0,600
  IF HEIGHT(0)<400 THEN HEIGHT 0,400
 
  x%=WIDTH_CLIENT(0) : y%=HEIGHT_CLIENT(0)
 
  WIDTH ListInfo%,x%-260 : HEIGHT ListInfo%,y%-10
 
  LEFT ListMc%,x%-250 : HEIGHT ListMc%,y%-10
 
  ON_RESIZE 0,dimension
 
RETURN

' ------------------------------------------------------------------------------
 
SelectionMotCle:

  OFF_CLICK ListMc%
 
  fc$=ITEM_INDEX$(ListMc%)+".txt"
     
  HIDE ListInfo% 
  CLEAR ListInfo%
     
  FILE_OPEN_READ 1,fc$
      REPEAT
        fr$=FILE_READLN$(1)
        IF LEN(fr$)=1
            v1$=fr$
            IF INSTR("a3456789",v1$)<>0 THEN ITEM_ADD ListInfo%,""
            AffichageMotCle(fr$)
        ELSE
            IF lg%=0 AND INSTR("1a3456789",v1$)<>0 THEN ITEM_ADD ListInfo%,fr$
            IF lg%=1 AND INSTR("1CDEGHIJ9",v1$)<>0 THEN ITEM_ADD ListInfo%,fr$
        END_IF
      UNTIL FILE_EOF(1)=1
  FILE_CLOSE 1
 
  ITEM_SELECT ListInfo%,1
  SHOW ListInfo%
 
  ON_CLICK ListMc%,SelectionMotCle
     
RETURN

' ------------------------------------------------------------------------------

SUB AffichageMotCle(v$)

  IF lg%=0
      IF v$="1" THEN ITEM_ADD ListInfo%,"MOT CLE : "+FILE_READLN$(1)
      ' IF v$="a" THEN ITEM_ADD ListInfo%,""
      ' IF v$="3" THEN ITEM_ADD ListInfo%,""
      IF v$="4" THEN ITEM_ADD ListInfo%,"ACTION :"
      IF v$="5" THEN ITEM_ADD ListInfo%,"SYNTAXE :"
      IF v$="6" THEN ITEM_ADD ListInfo%,"UTILISATION :"
      IF v$="7" THEN ITEM_ADD ListInfo%,"ERREUR :"
      IF v$="8" THEN ITEM_ADD ListInfo%,"EXEMPLE :"
      IF v$="9" THEN ITEM_ADD ListInfo%,"EN RAPPORT :"
  ELSE
      IF v$="1" THEN ITEM_ADD ListInfo%,"KEY WORD : "+FILE_READLN$(1)
      ' IF v$="C" THEN ITEM_ADD ListInfo%,""
      ' IF v$="D" THEN ITEM_ADD ListInfo%,""
      IF v$="E" THEN ITEM_ADD ListInfo%,"ACTION :"
      IF v$="G" THEN ITEM_ADD ListInfo%,"SYNTAX :"
      IF v$="H" THEN ITEM_ADD ListInfo%,"USE :"
      IF v$="I" THEN ITEM_ADD ListInfo%,"ERROR :"
      IF v$="J" THEN ITEM_ADD ListInfo%,"EXAMPLE :"
      IF v$="9" THEN ITEM_ADD ListInfo%,"SEE ALSO :"
  END_IF
 
END_SUB
 
' ------------------------------------------------------------------------------
' ------------------------------------------------------------------------------