changer vos icone panoramic

HIDE 0
DIM fichier$,i%,rhacker$
DIM TmpDir$:TmpDir$="C:\TempPano"
LABEL TraiteSelection, Modifier, FinProg

rhacker$="C:\Program Files\Resource Hacker\ResHacker.exe"

' Si le répertoire de travail n'existe pas
IF DIR_EXISTS(TmpDir$)=0
 DIR_MAKE TmpDir$
 ' on mémorise comme quoi il n'existait pas, pour pouvoir le supprimer lors de l'arrêt du programme
 ' et puis cela fera plaisir à ygeronimi ;-)
 DIM DirRemove%
END_IF

' Test pour éviter un message d'erreur
IF FILE_EXISTS("form.dll")=1
  DLL_ON "form.dll"
  i% = DLL_CALL2("SetSize",HANDLE(0),0)
  i% = DLL_CALL2("SetMinimize",HANDLE(0),0)
  i% = DLL_CALL2("SetMaximize",HANDLE(0),0)
  dll_off
END_IF

' Petite "soupe" pour mettre en place l'IHM
caption 0,"GetIcon"
height 0,300 : width 0,600

container 20: Caption 20,"  Cible  "
top 20,16 : Left 20,20 : height 20,88 : width 20,450

ALPHA  21: PARENT 21,20 : TOP 21,18 : LEFT 21,8  : CAPTION 21,"Executable"
EDIT   22: PARENT 22,20 : TOP 22,16 : LEFT 22,80 : WIDTH 22,300 : font_size 22,10 : i%=LEFT(22)+ WIDTH(22)+8
BUTTON 23: PARENT 23,20: TOP 23,16 : LEFT 23,i%: WIDTH 23,32  : CAPTION 23,"..."

ALPHA  31: PARENT 31,20 : TOP 31,50 : LEFT 31,8  : CAPTION 31,"Icône"
EDIT   32: parent 32,20 : TOP 32,48 : LEFT 32,80 : WIDTH 32, WIDTH(22) : font_size 32,10
BUTTON 33: PARENT 33,20: TOP 33,48 : LEFT 33,i%: WIDTH 33,32  : CAPTION 33,"..."

BUTTON 40: TOP 40, TOP(20)+HEIGHT(20)+16: LEFT 40,LEFT(20):CAPTION 40,"Modifier"

HEIGHT 0,TOP(40)+80 : LEFT 0,(SCREEN_X-WIDTH(0))/2 : TOP 0,(SCREEN_Y-HEIGHT(0))/2

open_dialog 50

' On déclare les évènements suivis
ON_CLICK 23,TraiteSelection
ON_CLICK 33,TraiteSelection
ON_CLICK 40,Modifier
ON_CLOSE 0,FinProg

SHOW 0

end

' Sélection d'un fichier (exec / icone)
TraiteSelection:
  SELECT NUMBER_CLICK
    CASE 23
      filter 50,"Executable | *.exe"
    CASE 33
      filter 50,"Icône | *.ico;*.png"
  END_SELECT
  fichier$=file_name$(50)
  if fichier$="_" then return
  TEXT NUMBER_CLICK-1,fichier$ : ' mise à jour du champ d'édition
RETURN

Modifier:
  IF FILE_EXISTS(TEXT$(22))=0 OR FILE_EXISTS(TEXT$(32))=0
    MESSAGE "Veuillez sélectionner l'exécutable et l’icône à associer"
    RETURN
  END_IF

  IF FILE_EXISTS(rhacker$)<>1
    MESSAGE "Selectionnez l'exécutable ResHacker"
    filter 50,"ResHacker.exe"
    rhacker$=file_name$(50)
    if rhacker$="_" then return
  END_IF

  fichier$=FILE_EXTRACT_NAME$(TEXT$(22)) : fichier$=LEFT$(fichier$,LEN(fichier$)-4)
  file_open_write 1,TmpDir$+"\script.scp"
    file_writeln 1,"[FILENAMES]"
    file_writeln 1,"Exe= "+CHR$(34)+TEXT$(22)+CHR$(34)
    file_writeln 1,"SaveAs= "+CHR$(34)+FILE_EXTRACT_PATH$(TEXT$(22))+Fichier$+".new.exe"+CHR$(34)
    file_writeln 1,"[COMMANDS]"
    file_writeln 1,"-addoverwrite "+CHR$(34)+TEXT$(32)+CHR$(34)+", ICONGROUP,MAINICON,0"
  file_close 1
  file_open_write 1,TmpDir$+"\script.bat"
    file_writeln 1,"  "+CHR$(34)+rhacker$+CHR$(34)+" -script "+CHR$(34)+TmpDir$+"\script.scp"+CHR$(34)
  file_close 1
  fichier$= TmpDir$+"\script.bat"
  IF FILE_EXISTS("utils.dll")=1
    DLL_ON "utils.dll"
    i% = DLL_CALL1("ExecuteAndWait", ADR(fichier$))
    DLL_OFF
  ELSE
    execute_wait fichier$
  END_IF
  MESSAGE "Ok : Icône modifiée"
RETURN

FinProg:
  IF VARIABLE("DirRemove%")=1
    IF FILE_EXISTS(TmpDir$+"\script.scp")=1 THEN FILE_DELETE TmpDir$+"\script.scp"
    IF FILE_EXISTS(TmpDir$+"\script.bat")=1 THEN FILE_DELETE TmpDir$+"\script.bat"
    DIR_REMOVE TmpDir$
  END_IF
RETURN