tag mp3

LABEL Chf, Extrac, Dump
DIM rp$,f$,i%,k%,a$,xx%,fr$,w,h,fdum$
rp$ = "C:\MP3TEST"
fr$ = "Z:\Image.jpg": ' <<<<<<<<<<<<<<<<<<<<<<< IMAGE RÉSULTAT
fdum$ = "C:\UTIL\Frhed-1.6.0-exe\Frhed.exe ": ' dump, pour info
WIDTH 0,400: HEIGHT 0,620: font_bold 0: color 0,192,255,255: CAPTION 0,"Tags MP3"
ALPHA 9: TOP 9,3: CAPTION 9,"Fichier mp3:"
EDIT 10: LEFT 10,70: WIDTH 10,270: ON_CLICK 10,Chf: color 10,255,255,128
BUTTON 11: LEFT 11,LEFT(10)+WIDTH(10)+2: WIDTH 11,40: HEIGHT 11,20: CAPTION 11,"Dump"
ON_CLICK 11,Dump
OPEN_DIALOG 15
FILTER 15,"Fichiers mp3|*.mp3"
MEMO 1: TOP 1,20: WIDTH 1,WIDTH(0)-16: HEIGHT 1,280
FONT_NAME 1,"Lucida Console": FONT_SIZE 1,10
BUTTON 2: TOP 2,TOP(1)+HEIGHT(1): LEFT 2,100: WIDTH 2,150
CAPTION 2,"Extraire l'image": ON_CLICK 2, Extrac
ALPHA 3: TOP 3,TOP(2)+7: LEFT 3,LEFT(2)+WIDTH(2)+10
PICTURE 5: TOP 5,TOP(2)+30: WIDTH 5,WIDTH(0)-16: HEIGHT 5,250: STRETCH_ON 5
COLOR 5,192,192,255
END
' ==============================================================================
' ==============================================================================
Chf:
f$ = FILE_NAME$(15): TEXT 10,f$
Lis_Tag(f$): ' Liste des tags ID3 v1 et/ou v2 du fichier
CLIPBOARD_PASTE 1
RETURN
' ==============================================================================
Extrac:
' recherche du 1er tag APIC (picture)
xx% = 0
FOR i% = 1 TO COUNT(1)
    a$ = ITEM_READ$(1,i%)
    IF LEFT$(a$,5) = "APIC:"
        k% = INSTR(a$,",")
        IF k% > 0
            xx% = VAL(MID$(a$,7,k%-7))
        ELSE
            xx% = VAL(MID$(a$,7,20))
        END_IF
        EXIT_FOR
    END_IF
NEXT i%
IF xx% > 0
    Img_Tag(f$,xx%,fr$): ' extraction de l'image
    DimJpg(fr$)
    CAPTION 3,STR$(w)+" x " + STR$(h)
    WIDTH 5,HEIGHT(5)*w/h
    FILE_LOAD 5,fr$: ' affichage
END_IF
RETURN
' ==============================================================================
Dump:
EXECUTE fdum$ + f$
RETURN
' ==============================================================================
SUB Img_Tag(f$,xx%,fr$)
' Extraction de l'image de f$ du Tag APIC situé en xx%, résultat dans fr$
DIM_LOCAL n%,i%,a$,x%,lg%,nbc%,rst%
n% = 2000: dim v%(n%): ' nombre d'octets en lecture (maxi)
FILEBIN_OPEN_READ 9,f$: FILEBIN_OPEN_WRITE 8,fr$
    FILEBIN_POSITION 9,xx%: FILEBIN_BLOCK_READ 9,100,v%(0): ' début du tag 'APIC'
    lg% = v%(7)+256*v%(6) + 10: ' longueur totale du tag image
    FOR i% = 1 TO 100
        IF v%(i%)=255 AND v%(i%+1)=216: ' FF D8: début d'image jpg
            x% = xx%+i%: lg% = lg%-i%: exit_for
        END_IF
    NEXT i%
    nbc% = INT(lg%/n%): rst% = lg%-nbc%*n%: ' nombre de lectures, et reste
    FILEBIN_POSITION 9,x%
    FOR i% = 1 TO nbc%
        FILEBIN_BLOCK_READ 9,n%,v%(0): FILEBIN_BLOCK_WRITE 8,n%,v%(0)
    NEXT i%
    IF rst%>0 THEN FILEBIN_BLOCK_READ 9,rst%,v%(0): FILEBIN_BLOCK_WRITE 8,rst%,v%(0)
FILEBIN_CLOSE 9: FILEBIN_CLOSE 8
END_SUB
' ==============================================================================
SUB Lis_Tag(f$)
' Liste des tags ID3 d'un fichier mp3 -> clipboard
' Rendu: une ligne par tag:
'        ID3v1: Nom du tag + contenu
'        ID3v2: Nom du tag, Position, Longueur
DIM_LOCAL a$,sz%,v%(2000),i%,k%,v1$,v2$,rc$,lt%, xx%
rc$ = CHR$(13)+CHR$(10)

FILEBIN_OPEN_READ 9,f$: sz% = FILEBIN_SIZE(9)
FILEBIN_POSITION 9,sz%-128: FILEBIN_BLOCK_READ 9,128,v%(0)
IF v%(0)=84 AND v%(1)=65 AND v%(2)=71: ' 'TAG' (tags ID3v1)
    a$ = "--- Tags ID3v1 ---"
    a$ = a$+rc$+"Titre : ": i% = 3
    WHILE v%(i%)<>0: a$=a$+CHR$(v%(i%)): i%=i%+1: END_WHILE
    a$=a$+rc$+"Auteur: ": i% = 33
    WHILE v%(i%)<>0: a$=a$+CHR$(v%(i%)): i%=i%+1: END_WHILE
    a$=a$+rc$+"Album : ": i% = 63
    WHILE v%(i%)<>0: a$=a$+CHR$(v%(i%)): i%=i%+1: END_WHILE
    a$=a$+rc$+"Année : ": i% = 93
    WHILE v%(i%)<>0: a$=a$+CHR$(v%(i%)): i%=i%+1: END_WHILE
    a$=a$+rc$+"Comnt : ": i% = 97
    WHILE v%(i%)<>0: a$=a$+CHR$(v%(i%)): i%=i%+1: END_WHILE
    a$=a$+rc$+"Genre : "+STR$(v%(127))
    v1$ = a$
END_IF
FILEBIN_POSITION 9,0: FILEBIN_BLOCK_READ 9,9,v%(0)
IF v%(0)=73 AND v%(1)=68 AND v%(2)=51: ' 'ID3' (tags ID3v2)
    lt% = v%(8)+256*v%(7)+256*256*v%(6): ' taille totale
    a$ = "--- Tags ID3v2 ---"
    xx% = 10: ' 1er tag
    WHILE xx%<(lt%+20)
        FILEBIN_POSITION 9,xx%: FILEBIN_BLOCK_READ 9,100,v%(0)
        a$ = a$+rc$+CHR$(v%(0))+CHR$(v%(1))+CHR$(v%(2))+CHR$(v%(3)): ' nom du tag
        k% = v%(7)+256*v%(6)+10: ' longueur totale du tag
        a$ = a$+": "+STR$(xx%)+","+STR$(k%): ' indice et longueur
        xx% = xx%+k%
    END_WHILE
    v2$ = a$
END_IF
FILEBIN_CLOSE 9
CLIPBOARD_STRING_COPY v1$+rc$+v2$
END_SUB
' ==============================================================================
SUB DimJpg(f$)
' dimensions d'un jpg -> w, h : frame FF C0
' (frames: FF tt 00 yy xx ...
'  tt = type de frame, xx+256*yy taille du contenu (+2 = taille totale)
DIM_LOCAL sz,t,x,v%(10)
FILEBIN_OPEN_READ 9,f$: sz = FILEBIN_SIZE(9): x = 2
WHILE x < sz
    FILEBIN_POSITION 9,x: FILEBIN_BLOCK_READ 9,10,v%(0)
    t = v%(1): ' type de frame (FF xx)
    IF t=192 OR t=193 OR t=194 OR t=195: ' C0, C1, C2, C3 frame dimensions
        h = v%(6)+256*v%(5): w = v%(8)+256*v%(7)
        EXIT_WHILE
    END_IF
    x = x+v%(3)+256*v%(2)+2: ' frame suivant
END_WHILE
FILEBIN_CLOSE 9
END_SUB
' ==============================================================================

SUB DumpF(f$,x%,y%,h%)
' dump de f$, affiché en x%,y% de l'écran, de hauteur h% pixels
IF LABEL("Boutdum") = 0 THEN LABEL Boutdum
IF LABEL("Dumdum") = 0 THEN LABEL Dumdum
IF LABEL("Closdum") = 0 THEN LABEL Closdum
DIM_LOCAL ff%,fd%,xd%,tp%,ads%, di%, dj%, dk%, ba$, ca$, cc$, sz%, nl%, rda$
ff%=1000: FORM ff%: TOP ff%,y%: LEFT ff%,x%: WIDTH ff%,555: HEIGHT ff%,h%
BORDER_SMALL ff%: color ff%,200,255,255: ON_CLOSE ff%,Closdum
LIST ff%+1: PARENT ff%+1,ff%: TOP ff%+1,0: WIDTH ff%+1,WIDTH(ff%)-16
HEIGHT ff%+1,HEIGHT(ff%)-35: FONT_NAME ff%+1,"Lucida Console"
BUTTON ff%+2: PARENT ff%+2,ff%: TOP ff%+2,10: WIDTH ff%+2,20: LEFT ff%+2,WIDTH(ff%+1)-21
CAPTION ff%+2,CHR$(235)
BUTTON ff%+3: PARENT ff%+3,ff%: TOP ff%+3,35: WIDTH ff%+3,20: LEFT ff%+3,LEFT(ff%+2)
CAPTION ff%+3,CHR$(233)
BUTTON ff%+4: PARENT ff%+4,ff%: TOP ff%+4,60: WIDTH ff%+4,20: LEFT ff%+4,LEFT(ff%+2)
CAPTION ff%+4,CHR$(234)
BUTTON ff%+5: PARENT ff%+5,ff%: TOP ff%+5,85: WIDTH ff%+5,20: LEFT ff%+5,LEFT(ff%+2)
FONT_BOLD ff%+5: CAPTION ff%+5,"F"
FOR di%=ff%+2 TO ff%+4: FONT_NAME di%,"Wingdings": NEXT di%
FOR di%=ff%+2 TO ff%+5: ON_CLICK di%,Boutdum: NEXT di%

nl% = INT(h%/(TEXT_HEIGHT("AB",ff%+1)-1)): ' nb de lignes affichables
tp% = 16*nl%: ' nb d'octets affichés dans la page
FILEBIN_OPEN_READ 9,f$: sz% = FILEBIN_SIZE(9): FILEBIN_CLOSE 9
CAPTION ff%,f$+"  ("+STR$(sz%)+" octets = "+HEX$(sz%)+"h)"
fd% = 0: xd% = 0: GOSUB Dumdum
WHILE fd% = 0: WAIT 100: END_WHILE: DELETE ff%: EXIT_SUB: ' clic fin
' ------------------------------------------------------------------------------
Dumdum:
FILEBIN_OPEN_READ 9,f$: FILEBIN_POSITION 9,xd%: ba$ = FILEBIN_HEXA_READ$(9,tp%)
FILEBIN_CLOSE 9
CLEAR ff%+1
ads% = xd%: rda$ = ""
FOR di% = 1 TO LEN(ba$) STEP 32
    rda$ = RIGHT$("00000"+HEX$(ads%),6) + ": ": ca$ = " "
    FOR dj% = di% TO di%+30 STEP 2
        cc$ = MID$(ba$, dj%, 2)
        rda$ = rda$ + cc$ + " ": dk% = HEX(cc$)
        IF dk% > 31
            ca$ = ca$ + CHR$(dk%)
        ELSE
            ca$ = ca$ + "."
        END_IF
    NEXT dj%
    ITEM_ADD ff%+1,rda$+ca$
    ads% = ads% + 16
NEXT di%
RETURN
' ------------------------------------------------------------------------------
Boutdum:
di% = NUMBER_CLICK
IF di% = ff%+2 THEN xd% = 0: GOTO Dumdum: ' début
IF di% = ff%+3: ' page précédente
    xd%=xd%-tp%: IF xd%<0 THEN xd%=0
    GOTO Dumdum
END_IF
IF di% = ff%+4: ' page suivante
    xd%=xd%+tp%: IF xd%>(sz%-tp%) THEN xd%=sz%-tp%
    GOTO Dumdum
END_IF
IF di% = ff%+5 THEN xd%=sz%-tp%: GOTO Dumdum: 'Fin
RETURN
' ------------------------------------------------------------------------------
Closdum:
fd% = 1
RETURN
END_SUB

dim f$,f2$
f2$="C:\Users\Yannick\Desktop\Song.mp3"

caption 0,"Mp3 Cleaner"
height 0,300 :width 0,336
font_name 0,"Courrier"
font_size 0,8

Progress_bar 3
top 3,height(0)-68 :left 3,10 : width 3,200
min 3,0 : max 3,7 : position 3,0

memo 4
top 4,5 : left 4,5 : height 4,height(0)-88 : width 4,width(0)-26

Open_dialog 5
dir_dialog 5,"C:\Users\Yannick\Music"
filter 5,"*.mp3|*.mp3"
f$=file_name$(5)
if f$<>"_"
   work()
else
   terminate
end_if

end

sub work()
   dim_local x%,tf%,v%,v1%,p%,dep%,ts%,id3v1%(128),id3v2%(3),num%

filebin_open_read 1,f$

' taille du fichier
tf%=filebin_size(1)
position 3,1
item_add 4,"Taille du fichier en octets : "+str$(tf%)

' recherche du début de la bande son
for x%=0 to tf%
   filebin_read 1,v%
   if hex$(v%)="FF" or hex$(v%)="ff"
      filebin_read 1,v1%
      if hex$(v1%)="FB" or hex$(v1%)="fb"
          p%=1
          dep%=x%
          position 3,2
          item_add 4,"Octet de début de la bande son : "+str$(dep%)
          exit_for
      end_if
   end_if
next x%
display

' recherche de la présence de id3v2
filebin_position 1,0
filebin_block_read 1,3,id3v2%(0)
pause 1000
position 3,3
if chr$(id3v2%(0))+chr$(id3v2%(1))+chr$(id3v2%(2))="ID3"
   item_add 4,"id3v2 : Oui"
else
   item_add 4,"id3v2 : Non"
end_if
display

' recherche de la présence de id3v1
filebin_position 1,tf%-128
filebin_block_read 1,128,id3v1%(0)
pause 1000
position 3,4
if chr$(id3v1%(0))+chr$(id3v1%(1))+chr$(id3v1%(2))="TAG"
   tf%=tf%-128
   item_add 4,"id3v1 : Oui"
else
   item_add 4,"id3v1 : Non"
end_if
display

' lecture/ecriture des fichiers
if p%=1
   ts%=tf%-(dep%-1)
   dim bloc%(ts%)
   position 3,5
   item_add 4,"Lecture bande son : "+file_extract_name$(f$)
   display
   filebin_position 1,dep%
   filebin_block_read 1,ts%,bloc%(0)
   filebin_close 1

   position 3,6
   item_add 4,"Ecriture : "+file_extract_name$(f2$)
   display
   if file_exists(f2$)=1
      while file_exists(f2$)=1
         num%=num%+1
         f2$=file_extract_path$(f2$)+"Song("+str$(num%)+").mp3"
      end_while
   end_if
   filebin_open_write 2,f2$
   filebin_block_write 2,ts%,bloc%(0)
   filebin_close 2
end_if

position 3,7
item_add 4,"Fin !!!..."
item_add 4,"Fichier "+f2$+" créé."
pause 3000
Terminate

end_sub

  if file_exists(f2$)=1
      while file_exists(f2$)=1
         num%=num%+1
         f2$=file_extract_path$(f2$)+"Song("+str$(num%)+").mp3"
      end_while
   end_if

if f$<>" " then work(): pause 3000
terminate