KGF_dll - nouvelles versions

dim res%

picture 1 : width 1,64 : height 1,64

dll_on "KGF.dll"
' 32765 est la valeur du caractère Unicode
' 64 est la taille du carré récepteur, en pixels
res% = dll_call2("GetUnicodeGraphic",32765,64)
clipboard_paste 1

end

res% = dll_call2("SetIconPictureMode",act%,opt%)

act%=1: agit sur les dimensions
  opt%=0: dimensions par défaut des icônes du système
  opt%=1: dimensions de l'icône identique à celles de la bitmap
act%=2: agit sur la couleur de transparence
  opt%=-1: couleur de transparence par défaut (pixel en bas à gauche)
  opt%=RGB: couleur RGB est la couleur de transparence

' test_TrayIcon.bas

label exec, trayclick, menus, close100, complet
label popupmemo, popupalpha

dim res%, f$, s$, act%, hnd%, n%
dim PM1%, PM2%

dll_on "KGF.dll"

open_dialog 1 : filter 1,"Images|*.jpg;*.bmp;*.ico"

combo 10 : top 10,10 : left 10,10 : width 10,230
  item_add 10,"1 - Créer la liste des images"
  item_add 10,"2 - Ajouter une image à la liste"
  item_add 10,"3 - Sélectionner une image"
  item_add 10,"4 - Créer l'icône de notification"
  item_add 10,"5 - Retourner le nombre d'images"
  item_add 10,"6 - Retourner le numéro d'image actuelle"
  item_add 10,"7 - créer le menu contextuel"
  item_add 10,"8 - imposer un intervalle de 3 sec"
  item_add 10,"9 - activer l'animation"
edit 11 : top 11,10 : left 11,270
button 12 : top 12,10 : left 12,410 : caption 12,"Exécuter" : on_click 12,exec

button 13 : top 13,40 : left 13,410 : caption 13,"Test complet" : on_click 13,complet

edit 20 : top 20,40 : left 20,10 : on_change 20,trayclick :  hide 20
' memo 21 : hide 21 : bar_both 21
list 21 : hide 21
  item_add 21,"Option 1"
  item_add 21,"Option 2"
  item_add 21,"Option 3"
 
 
memo 101 : top 101,120 : left 101,10
button 102 : top 102,120 : left 102,200 : width 102,130
  caption 102,"Popup pour mémo" : on_click 102,popupmemo
memo 103 : top 103,220 : left 103,10
alpha 104 : top 104,320 : left 104,10 : caption 104,"Click droit ici..."
button 105 : top 105,320 : left 105,200 : width 105,130
  caption 105,"Popup pour alpha" : on_click 105,popupalpha
alpha 106 : top 106,350 : left 106,10 : caption 106,"Et ici..."


end

exec:
  act% = item_index(10)
  hnd% = handle(0)
  select act%
    case 1
      res% = dll_call2("TrayIcon",1,hnd%)
    case 2
      f$ = file_name$(1)
      if f$="_" then return
      res% = dll_call2("TrayIcon",2,adr(f$))
    case 3
      f$ = text$(11)
      if len(f$)=0 then f$ = 0
      if numeric(f$)=0
        message "Paramètre invalide"
        return
      end_if
      n% = val(f$)
      res% = dll_call2("TrayIcon",3,n%)
    case 4
      res% = dll_call2("TrayIcon",4,handle(20))
    case 5
      res% = dll_call2("TrayIcon",5,0)
    case 6
      res% = dll_call2("TrayIcon",6,0)
    case 7
      res% = dll_call2("TrayIcon",7,object_internal(21))
    case 8
      res% = dll_call2("TrayIcon",8,3000)
    case 9
      res% = dll_call2("TrayIcon",9,1)
  end_select
  message "Code retour: "+str$(res%)
  return
 
complet:
  res% = dll_call2("TrayIcon",1,hnd%)                  : ' créer la liste des images
  f$ = "crane_16x16.bmp"                                : ' choisir une image
  res% = dll_call2("TrayIcon",2,adr(f$))                : ' charger cette image dans la liste
  f$ = "crane_16x16_jaune.bmp"                          : ' choisir une autre image
  res% = dll_call2("TrayIcon",2,adr(f$))                : ' charger cette image dans la liste
  res% = dll_call2("TrayIcon",4,handle(20))            : ' créer l'icone de notification
  res% = dll_call2("TrayIcon",7,object_internal(21))    : ' créer le menu contextuel à partir du mémo
  res% = dll_call2("TrayIcon",8,3000)                  : ' définir un intervalle de 3 secondes
  res% = dll_call2("TrayIcon",9,1)                      : ' lancer l'animatioin
  message "C'est prêt..."
  return
 
trayclick:
  if text$(20)="Tray_Left"
    message "clic gauche"
  end_if
  if text$(20)="Tray_Right"
    message "clic droit"
    if object_exists(100)=0
      form 100 : on_close 100,close100
      border_small 100
      height 100,80 : width 100,400
      command_target_is 100
      main_menu 101
      sub_menu 102 : parent 102,101 : caption 102,"Option 1" : on_click 102,menus
      sub_menu 103 : parent 103,101 : caption 103,"Option 2" : on_click 103,menus
      sub_menu 104 : parent 104,101 : caption 104,"Option 3" : on_click 104,menus
      command_target_is 0
    end_if
    inactive 0
    show 100
  end_if
  if left$(text$(20),8)="Context_"
    message "Menu contextuel option "+mid$(text$(20),9,10)
  end_if
  return
 
menus:
  n% = number_click - 101
  message "Menu contextuel option "+str$(n%)
  gosub close100
  return
 
close100:
  hide 100
  active 0
  to_foreground 0
  return
 
popupmemo:
  PM1% = dll_call5("PopupMenu",1,PM1%,object_internal(101),object_internal(21),handle(20))
  message str$(PM1%)
  return
 
popupalpha:
  PM2% = dll_call5("PopupMenu",1,PM2%,object_internal(104),object_internal(21),handle(20))
  message str$(PM2%)
  return

dll_on "kgf"

dim no%, res%, heure%, minute%

label change_dtp, close, open

edit 1
hide 1
no%=dll_call6("DTP",1,handle(0),handle(1),100,100,2)
on_change 1,change_dtp
button 2 : on_click 2,close : caption 2,"Fermer"
button 3 : on_click 3,open : top 3,25 : caption 3,"Ouvrir"

end

change_dtp:
  res%=dll_call6("DTP",4,1,adr(heure%),adr(minute%),0,0)
return

open:
  res%=dll_call6("DTP",6,1,1,0,0,0)
  return

close:
  res%=dll_call6("DTP",6,1,0,0,0,0)
  return

' DTP_cacher_popup.bas

dll_on "kgf"

dim no%, res%, heure%, minute%

label change_dtp, close, open, auto

edit 1
hide 1
no%=dll_call6("DTP",1,handle(0),handle(1),100,100,2)
on_change 1,change_dtp
button 2 : on_click 2,close : caption 2,"Fermer"
button 3 : on_click 3,open : top 3,25 : caption 3,"Ouvrir"
check 4 : top 4,50 : caption 4,"AutoHide" : on_click 4,auto
end

change_dtp:
  res%=dll_call6("DTP",4,1,adr(heure%),adr(minute%),0,0)
return

open:
  res%=dll_call6("DTP",6,1,1,0,0,0)
  return

close:
  res%=dll_call6("DTP",6,1,0,0,0,0)
  return
 
auto:
  res%=dll_call6("DTP",7,1,checked(4),0,0,0)
  return