3.01 du 23/04/2014: LoopPlayer et players multiples

label ouvrir,playpause,raz,mute,loop,volume,fin
dim dll$,musiq$,res%,mode%,loop%:mode%=1:loop%=0
init():on_close 0,fin
end

ouvrir:
  musiq$=file_name$(10)
  if musiq$<>"_" then load_player(musiq$):caption 0,musiq$:' charger un son
return

playpause:
  if caption$(4)=chr$(52)
     caption 4,chr$(59):play_player(position(1)):' jouer
  else
     caption 4,chr$(52):pause_player():' mettre en pause
  end_if
return

raz:
  caption 4,chr$(52):StopPlayer():' Arrêter le player)
return

mute:
  if mode%=1:mode%=0:color 6,200,90,200:else:mode%=1:color 6,200,200,240:end_if
  mute_player(mode%):' couper/réactiver le son
return

loop:
  if loop%=1:loop%=0:color 7,200,200,240:else:loop%=1:color 7,200,90,200:end_if
  looplayer(loop%):' Lecture en boucle (0=désactiver 1=activer)
return

volume:
  volume_player(position(1)):caption 2,"VOLUME "+str$(position(1)):' volume
return

sub init()
  dll$="c:\PANORAMIC\KGF.dll":' <======== CHEMIN DU DOSSIER À ADAPTER !!!!
     if file_exists(dll$)=1
        dll_on dll$
     else
        message "Le fichier "+dll$+" est introuvable.":terminate
     end_if
  border_small 0:width 0,320:height 0,80:caption 0,"PANO-PLAYER"
  track_bar 1
     min 1,0:max 1,100:position 1,90:on_change 1,volume
  alpha 2
     font_name 2,"Consolas":font_bold 2:font_size 2,12
     left 2,width(1):caption 2,"VOLUME "+str$(position(1))
  alpha 3
     font_name 3,"Webdings":font_bold 3:font_size 3,12
     left 3,left(2):top 3,height(2)
     caption 3,chr$(204):hint 3,"Ouvrir un fichier son"
     on_click 3,ouvrir
  alpha 4
     font_name 4,"Webdings":font_bold 4:font_size 4,12
     left 4,left(3)+width(3)+5:top 4,top(3):caption 4,chr$(52)
     color 4,200,200,240:hint 4,"PLAY / PAUSE":on_click 4,playpause
  alpha 5
     font_name 5,"Webdings":font_bold 5:font_size 5,12
     left 5,left(4)+width(4)+5:top 5,top(4):caption 5,chr$(60)
     color 5,200,200,240:hint 5,"ARRÊT":on_click 5,raz
  alpha 6
     font_name 6,"Webdings":font_bold 6:font_size 6,12
     left 6,left(5)+width(5)+5:top 6,top(5):caption 6,chr$(79)
     color 6,200,200,240:hint 6,"MUTE":on_click 6,mute
  alpha 7
     font_name 7,"Webdings":font_bold 7:font_size 7,12
     left 7,left(6)+width(6)+5:top 7,top(6):caption 7,chr$(96)
     color 7,200,200,240:hint 7,"LECTURE EN BOUCLE":on_click 7,loop
  open_dialog 10
     filter 10,"fichiers .mp3 .wav|*.mp3;*.wav"
  creer_player(20)
end_sub

sub creer_player(cp%):' créer l'objet player dans un panel que l'on cache
 panel cp%:hide cp%
 res%=dll_call5("CreatePlayer",handle(cp%),0,0,100,100)
end_sub

sub load_player(musiq$):' charger un son dans le player (ne joue pas le son !)
 res%=dll_call1("LoadFileIntoPlayer",adr(musiq$))
end_sub

sub play_player(volum%):' jouer le son avec le volume indiqué (0=muet 100=max)
 res%=dll_call0("PlayPlayer"):res%=dll_call1("VolumePlayer",volum%)
end_sub

sub volume_player(volum%):' changer le volume du player
 res%=dll_call1("VolumePlayer",volum%)
end_sub

sub mute_player(mode%):' couper/réactiver le son du player (0=muet 1=audible)
 res%=dll_call1("MutePlayer",mode%)
end_sub

sub pause_player():' mettre le player en pause (relancer par play_player)
 res%=dll_call0("PausePlayer")
end_sub

sub StopPlayer():' Arrêter le player
 res%=dll_call0("StopPlayer")
end_sub

sub looplayer(loop%):' Lecture en boucle (0=désactiver 1=activer)
 res%=dll_call1("LoopPlayer",loop%)
end_sub

sub delete_player(cp%):' supprimer le player
 res%=dll_call0("DeletePlayer"):pause 300:delete cp%
end_sub

fin:
delete_player(20):dll_off:terminate