V3.05 du 15/05/2014: ResizePlayer, ResizeMultiPlayer

label ouvrir,loop,agrandir
dim dll$,fch$,res%,loop%,mp%,k%,w%,h%,inf%
k%=-1
init()
end

ouvrir:
 fch$=file_name$(19)
 if fch$<>"_"
    load_player(fch$):' charger un son
     play_player(0):' lancer le player avec le volume minimum 0
     pause_player():' mettre en pause
  while inf%<1
     pause 500:' suspendre le programme
     PlayerInfo(3):' récupérer l'information dimensions dans inf%
'      caption 0,str$(inf%)
  end_while
     StopPlayer():' arrêter le player
     w%=int(inf%/32768):w%=w%/2
     h%=bin_and(inf%,32767):h%=h%/2
     move_player((height(0)/2)-h%,(width(0)/2)-w%)
     play_player(25):' lancer le player avec le volume à 25%
     inf%=0
 end_if
return

loop:
 if loop%=1:loop%=0:color 7,200,200,240:else:loop%=1:color 7,200,90,200:end_if
 looplayer(loop%):' Lecture en boucle (0=désactiver 1=activer)
return

agrandir:
  ResizePlayer()
return

sub init()
  dll$="c:\mesprog\KGF.dll":' <======== CHEMIN DU DOSSIER À ADAPTER !!!!
     if file_exists(dll$)=1
        dll_on dll$
     else
        message "Le fichier "+dll$+" est introuvable.":terminate
     end_if
  border_small 0:full_space 0
  alpha 3
    font_name 3,"Webdings":font_bold 3:font_size 3,12
    caption 3,chr$(204):hint 3,"Ouvrir un fichier son, une vidéo"
    on_click 3,ouvrir
  alpha 7
    font_name 7,"Webdings":font_bold 7:font_size 7,12
    left 7,width(3)+5:caption 7,chr$(96)
    color 7,200,200,240:hint 7,"LECTURE EN BOUCLE":on_click 7,loop
  alpha 8
    font_name 8,"Terminal":font_bold 8:font_size 8,12
    left 8,left(7)+width(7)+5:caption 8,chr$(91)+chr$(29)+chr$(93)
    color 8,200,200,240:hint 8,"Plein écran":on_click 8,agrandir
  open_dialog 19
     filter 19,"fichiers .mp3 .wav avi|*.mp3;*.wav;*.avi"
  creer_player(20)
end_sub

sub creer_player(cp%):' créer l'objet player dans un panel que l'on cache
' panel cp%:width cp%,1008:height cp%,640
mp%=dll_call5("CreateMultiPlayer",handle(0),20,0,width(0)-8,700)
end_sub

sub ResizePlayer()
 res%=dll_call5("ResizeMultiPlayer",mp%,k%,k%,k%,k%)
end_sub

sub move_player(t%,l%):' créer l'objet player dans un panel que l'on cache
res% = dll_call3("MoveMultiPlayer",mp%,t%,l%)
end_sub

sub load_player(musiq$):' charger un son dans le player (ne joue pas le son !)
res%=dll_call2("LoadFileIntoMultiPlayer",mp%,adr(musiq$))
end_sub

sub play_player(volum%):' jouer le son avec le volume indiqué (0=muet 100=max)
res%=dll_call1("PlayMultiPlayer",mp%):res%=dll_call2("VolumeMultiPlayer",mp%,volum%)
end_sub

sub volume_player(volum%):' changer le volume du player
res%=dll_call2("VolumeMultiPlayer",mp%,volum%)
end_sub

sub mute_player(mode%):' couper/réactiver le son du player (0=muet 1=audible)
res%=dll_call2("MuteMultiPlayer",mp%,mode%)
end_sub

sub pause_player():' mettre le player en pause (relancer par play_player)
res%=dll_call1("PauseMultiPlayer",mp%)
end_sub

sub StopPlayer():' Arrêter le player
res%=dll_call1("StopMultiPlayer",mp%)
end_sub

sub looplayer(loop%):' Lecture en boucle (0=désactiver 1=activer)
res%=dll_call2("LoopMultiPlayer",mp%,loop%)
end_sub

sub delete_player(cp%):' supprimer le player
res%=dll_call1("DeleteMultiPlayer",mp%):' pause 300:delete cp%
end_sub

sub PlayerInfo(p%)
  inf%=dll_call2("GetMultiPlayerInfo",mp%,p%)
end_sub