bouton roll-over

' test_mouse_over.bas

label changer_type
dim res%

' === définition de quelques objets dont le survol est contrôlé
alpha 1 : top 1,10 : left 1,10 : caption 1,"Votre nom:"
edit 2 : top 2,10 : left 2,70 : width 2,200
container 10 : top 10,40 : left 10,10 : caption 10,"Fiche personnelle"
  width 10,400 : height 10,300
alpha 11 : parent 11,10 : top 11,20 : left 11,10 : caption 11,"Adresse:"
memo 12 : parent 12,10 : top 12,20 : left 12,80
  width 12,200 : height 12,50
alpha 13 : parent 13,10 : top 13,80 : left 13,10 : caption 13,"Numéro SS:"
edit 14 : parent 14,10 : top 14,80 : left 14,80 : width 14,200
list 15 : top 15,10 : left 15,430 : height 15,400
item_add 15,"aaaaaa"
item_add 15,"bbbbbb"
item_add 15,"cccccc"
check 16 : top 16,340 : left 16,10 : caption 16,"Surveillance permanente"
  width 16,150 : mark_on 16 : on_click 16,changer_type
check 17 : top 17,360 : left 17,10 : caption 17,"Sélection dans liste par glissement"
  width 17,250 : mark_off 17

' objet pour la trace du programme
alpha 99 : top 99,400 : left 99,10 : caption 99,"Repos"
alpha 98 : top 98,420 : left 98,10 : caption 98,"Rien"

KGF_initialize("KGF.dll")

create_mouse_over(8,100,1)
add_mouse_over(1,0,0,0,0)
add_mouse_over(2,0,255,0,0)
add_mouse_over(11,10,0,0,0)
add_mouse_over(12,10,0,255,255)
add_mouse_over(13,10,0,0,0)
add_mouse_over(14,10,0,255,255)
add_mouse_over(10,0,0,0,0)
add_mouse_over(15,0,255,255,0)

end

changer_type:
  mouse_over_type(checked(16))
  return

' cette procédure est appelée chaque fois que le curseur entre
' dans un des objets surveillés, ou sur la form 0
' flag%=1 ==> on est dans la form
' flag%=0 ==> on est en-dehors de la form
sub on_mouse_over(flag%,obj%)
  if flag%=1
    caption 99,str$(mouse_over_x%)+","+str$(mouse_over_y%)+"  sur objet "+str$(obj%)+"  "+str$(mouse_over_n%)
' à titre d'exemple, on va interdire l'entrée dans le champ "adresse"
' (objet 12) si le nom est vide (objet 2)
    if obj%=12
      if trim$(text$(2))=""
        MousePosition(left(12)+width(12)+left(10)+10,top(12)+top(10)+10)
      end_if
    end_if
    if object_type(obj%)=8
      GetListBoxItemFromPoint(obj%,mouse_over_x%, mouse_over_y%)
      if GetListBoxItemFromPoint>0
        if checked(17)=1 then SelectListBoxItem(handle(obj%),GetListBoxItemFromPoint)
      end_if
      caption 99,str$(mouse_over_x%)+","+str$(mouse_over_y%)+"  sur objet "+str$(obj%)+"  "+str$(mouse_over_n%)+"  item "+str$(GetListBoxItemFromPoint)
    end_if
  else
    caption 99,"Sorti"
  end_if
  GetObjectHandleUnderCursor()
  caption 98,"Han dle: "+str$(GetObjectHandleUnderCursor)
end_sub

#INCLUDE "mouse_over_SUB.bas"
#INCLUDE "KGF_SUB.bas"

' constantes
Dim Dos$ : Dos$="C:\Users\Yannick\Desktop\Panoramic Essais\Essais O_Toll_Bar()\Icones\"

dim M_TB_deb%,M_TB_fin%
' varibles liées à la fonction verif_souris
Dim i0%,res%,res2%
' etiquettes d'évènements
Label Clic,Verif_souris,close

Dll_on "KGF.dll"

O_Form(0,0,1,0,0,400,(25*20)+16,"")
O_Tool_Bar(1,0,1)
O_Insert_Button_TB(10,Dos$+"PasteFromClipboard")

timer M_TB_fin%+1 :timer_interval M_TB_fin%+1,50 :on_Timer M_TB_fin%+1,Verif_souris

on_close 0,close

end


Sub O_Tool_Bar(No%,P%,V%)
  Dim_local i%,img$,L%,x%
  img$=Dos$+"Icone_vierge.bmp"
  L%=-25
  M_TB_deb%=No%
  M_TB_fin%=(width(P%)-16)/25
  Dim Tab$(M_TB_fin%,2)
  for i%=M_TB_deb% to M_TB_fin%
      L%=L%+25
      Tab$(i%,1)=img$
      Tab$(i%,2)=img$
      O_scene2d(i%,0,1,0,L%,25,25):file_load i%,Tab$(i%,1):inactive i% :cursor_point i%
  next i%
End_Sub

Sub O_Insert_Button_TB(P%,Type$)
  dim_local x%
  active P%
  Tab$(P%,1)=Type$+".bmp"
  Tab$(P%,2)=Type$+"_Select.bmp"
  file_load P%,Tab$(P%,1)
  on_click P%,Clic
End_Sub

Clic:
message "Ok!"
return

Verif_souris:
  for i0%=1 to M_TB_fin%
      if active(i0%)=1
        caption 0,str$(handle(i0%))
        res%=dll_call2("ClickSetLink",handle(i0%),5)
        if res%=1 :file_load i0%,Tab$(i0%,2):end_if
        res2%=dll_call2("ClickSetLink",handle(i0%),6)
        if res2%=1 :file_load i0%,Tab$(i0%,1):end_if
      end_if
  next i0%
  return

Close:
  Timer_off (M_TB_fin%+1)
  Dll_off
  return

#include "Objet_Lib.bas"

' mouse_over_SUB.bas

' le programme principal doit contenir une procédure on_mouse_over().
' Cette procédure sera appelée chaque fois que le curseur entre dans
' un objet surveillé. Avant d'appeler cette procédure, le programme
' effectue un éventuel changement de couleur, mais cette procédure est
' appelée pour tout objet scruté dans lequel le curseur entre, même
' s'il n'y a pas de changement de couleur.
'
' sub on_mouse_over(flag%,obj%)
'  if flag%=1
'    traiter ici l'évènement "dans la form" pour objet obj%
'  else
'    traiter ici l'évènement "en-dehors de la form"
'  end_if
' end_sub

message "mouse_over: ce module ne peut pas être exécuté directement."
terminate

' ===== routine évènement pour le timer (usage internne)
mouse_over_scruter:
  timer_off mouse_over_ntimer%
  GetMousePosition(handle(0))
  mouse_over_x% = GetMousePositionX%
  mouse_over_y% = GetMousePositionY%
  if (mouse_over_x%>=0) and (mouse_over_y%>=0)
    mouse_over_kold% = mouse_over_k%
    mouse_over_kiold% = mouse_over_ki%
    mouse_over_k% = 0
    mouse_over_ki% = 0
    for mouse_over_i%=1 to mouse_over_nobj%
      if mouse_over_x%>=mouse_over_gauche%(mouse_over_i%)
        if mouse_over_x%<(mouse_over_gauche%(mouse_over_i%)+mouse_over_largeur%(mouse_over_i%))
          if mouse_over_y%>=mouse_over_haut%(mouse_over_i%)
            if mouse_over_y%<(mouse_over_haut%(mouse_over_i%)+mouse_over_hauteur%(mouse_over_i%))
              mouse_over_k% = mouse_over_objets%(mouse_over_i%)
              mouse_over_ki% = mouse_over_i%
              exit_for
            end_if
          end_if
        end_if
      end_if
    next mouse_over_i%
    if (mouse_over_k%<>mouse_over_kold%) or (mouse_over_type%=1)
      if mouse_over_kold%>0
        if mouse_over_colorer%(mouse_over_kiold%)=1 then color mouse_over_kold%,255,255,255
      end_if
      if mouse_over_k%>0
        if mouse_over_colorer%(mouse_over_ki%)=1
          color mouse_over_k%,mouse_over_RGB%(mouse_over_ki%,1),mouse_over_RGB%(mouse_over_ki%,2),mouse_over_RGB%(mouse_over_ki%,3)
        end_if
      end_if
      mouse_over_n% = mouse_over_n% + 1
      on_mouse_over(1,mouse_over_k%)
    end_if
  else
      on_mouse_over(0,0)
  end_if
  timer_on mouse_over_ntimer%
  return

' ===== création du système mouse_over
'  maxobj% ==> nombre maxi d'objets à scruter
'  ntimer% ==> un numéro d'objet disponible pour créer le timer interne
'  typ%    ==> type de surveillance  0=changement d'objet  1=continuel
sub create_mouse_over(maxobj%,ntimer%,typ%)
  if label("mouse_over_scruter")=0 then label mouse_over_scruter
  if variable("mouse_over_nobj%")=0
    dim mouse_over_maxobj% : mouse_over_maxobj% = maxobj%
    dim mouse_over_ntimer% : mouse_over_ntimer% = ntimer%
    dim mouse_over_type% : mouse_over_type% = typ%
    dim mouse_over_nobj%
    dim mouse_over_k%
    dim mouse_over_ki%
    dim mouse_over_kold%
    dim mouse_over_kiold%
    dim mouse_over_i%
    dim mouse_over_n%
    dim mouse_over_x%
    dim mouse_over_y%
    dim mouse_over_objets%(mouse_over_maxobj%)
    dim mouse_over_gauche%(mouse_over_maxobj%)
    dim mouse_over_haut%(mouse_over_maxobj%)
    dim mouse_over_largeur%(mouse_over_maxobj%)
    dim mouse_over_hauteur%(mouse_over_maxobj%)
    dim mouse_over_colorer%(mouse_over_maxobj%)
    dim mouse_over_RGB%(mouse_over_maxobj%,3)
    timer mouse_over_ntimer% : timer_interval mouse_over_ntimer%,100
    on_timer mouse_over_ntimer%,mouse_over_scruter
  end_if
end_sub

' ===== supprimer le système mouse_over
sub delete_mouse_over()
  if variable("mouse_over_nobj%")=1
    timer_off mouse_over_ntimer%
    delete mouse_over_ntimer%
    free mouse_over_maxobj%
    free mouse_over_ntimer%
    free mouse_over_type%
    free mouse_over_nobj%
    free mouse_over_k%
    free mouse_over_ki%
    free mouse_over_kold%
    free mouse_over_kiold%
    free mouse_over_i%
    free mouse_over_n%
    free mouse_over_x%
    free mouse_over_y%
    free mouse_over_objets%
    free mouse_over_gauche%
    free mouse_over_haut%
    free mouse_over_large%
    free mouse_over_hauteur%
    free mouse_over_colorer%
    free mouse_over_RGB%
  end_if
end_sub

' ===== ajouter un objet à surveiller au système mouse_over
' obj%        ==> numéro de l'objet
' parent%    ==> numéro de l'objet parent de obj%
' R%, G%, B%  ==> couleurs RGB pour changement de couleur de fond
'                R%=G%=B%=0  ==>  pas de changement de couleur
sub add_mouse_over(obj%,parent%,R%,G%,B%)
  if mouse_over_nobj%<mouse_over_maxobj%
    mouse_over_nobj% = mouse_over_nobj% + 1
    mouse_over_objets%(mouse_over_nobj%) = obj%
    if parent%=0
      mouse_over_gauche%(mouse_over_nobj%) = left(obj%)
      mouse_over_haut%(mouse_over_nobj%) = top(obj%)
    else
      mouse_over_gauche%(mouse_over_nobj%) = left(obj%)+left(parent%)
      mouse_over_haut%(mouse_over_nobj%) = top(obj%)+top(parent%)
    end_if
    mouse_over_largeur%(mouse_over_nobj%) = width(obj%)
    mouse_over_hauteur%(mouse_over_nobj%) = height(obj%)
    if (R%=0) and (G%=0) and (B%=0)
      mouse_over_colorer%(mouse_over_nobj%) = 0
    else
      mouse_over_colorer%(mouse_over_nobj%) = 1
      mouse_over_RGB%(mouse_over_nobj%,1) = R%
      mouse_over_RGB%(mouse_over_nobj%,2) = G%
      mouse_over_RGB%(mouse_over_nobj%,3) = B%
    end_if
  end_if
end_sub

' ===== changer le type de surveillance
'  typ%    ==> type de surveillance  0=changement d'objet  1=continuel
sub mouse_over_type(typ%)
  mouse_over_type% = typ%
end_sub

' constantes
Dim Dos$ : Dos$="C:\Users\Yannick\Desktop\Panoramic Essais\Essais O_Toll_Bar()\Icones\"

dim M_TB_deb%,M_TB_fin%
' variables liées à la fonction verif_souris
Dim i0%,res%,Ts%,Ls%,hnd%,bout%,cg%,cd%,j0%
hnd%=handle(0)
' etiquettes d'évènements
Label Clic,Verif_souris,close

Dll_on "KGF.dll"

O_Form(0,0,1,0,0,400,(25*20)+16,"")
O_Tool_Bar(1,0,1)
O_Insert_Button_TB(10,Dos$+"PasteFromClipboard")

timer M_TB_fin%+1 :timer_interval M_TB_fin%+1,500 :on_Timer M_TB_fin%+1,Verif_souris

on_close 0,close

end


Sub O_Tool_Bar(No%,P%,V%)
  Dim_local i%,img$,L%,x%
  img$=Dos$+"Icone_vierge.bmp"
  L%=-25
  M_TB_deb%=No%
  M_TB_fin%=(width(P%)-16)/25
  Dim Tab$(M_TB_fin%,2)
  for i%=M_TB_deb% to M_TB_fin%
      L%=L%+25
      Tab$(i%,1)=img$
      Tab$(i%,2)=img$
      O_scene2d(i%,0,1,0,L%,25,25):file_load i%,Tab$(i%,1):inactive i% :cursor_point i%
  next i%
End_Sub

Sub O_Insert_Button_TB(P%,Type$)
  dim_local x%
  active P%
  Tab$(P%,1)=Type$+".bmp"
  Tab$(P%,2)=Type$+"_Select.bmp"
  file_load P%,Tab$(P%,1)
  on_click P%,Clic
End_Sub

Clic:
message "Ok!"
return

Verif_souris:
  timer_on M_TB_fin%+1
  cg%=-26 : cd%=0
  res%=dll_call3("GetMousePosition",hnd%,adr(Ls%),adr(Ts%))
  if Ts%<25
      for i0%=1 to M_TB_fin%
      cg%=cg%+25 :cd%=cd%+25
        if Ls%>cg% and Ls%<cd%
            bout%=i0%
            for j0%=1 to M_TB_fin% :file_load j0%,Tab$(J0%,1):next j0%
            file_load bout%, Tab$(bout%,2)
        end_if
      next i0%
  else
      for j0%=1 to M_TB_fin% :file_load j0%,Tab$(J0%,1):next j0%
  end_if
return

Close:
  Timer_off (M_TB_fin%+1)
  Dll_off
  return

#include "Objet_Lib.bas"