Hint et Objets désactivés

Bonjour à tous et en particulier à Jack,

Dans un de mes codes, j'utilise plusieurs fois le même COMBO avec un contenu différent à chaque fois.
Dans certains cas le texte sélectionné est pus long que le COMBO. J'y ai donc mis un HINT pour que l'utilisateur puisse voir le texte en entier.
Cela marche, mais çà pose un problème si je "INACTIVE" le COMBO, le HINT ne fonctionne plus.

Voici le code:

Code:: dim n%,a$,b$
label Premiere_Utilisation,Deuxieme_Utilisation,PU2,DU2,reset

button 1:top 1,10:caption 1,"Première":on_click 1,Premiere_Utilisation
button 2:top 2,10:left 2,100:caption 2,"Deuxième":on_click 2,Deuxieme_Utilisation
timer 3 : timer_off 3 : timer_interval 3,100 : on_timer 3,reset
edit 4:top 4,100:left 4,10:hint 4,"EDIT":' inactive 4
combo 5:top 5,50:left 5,10:inactive 5
END
' -------------------
Premiere_Utilisation:
clear 5
for n%=1 to 10:item_add 5,str$(n%):next n%
active 5:on_click 5,PU2
return

PU2:
a$=text$(5):timer_on 3
return

' -------------------
Deuxieme_Utilisation:
clear 5
item_add 5,"Texte volontairement plus long que combo 5"
active 5:on_click 5,DU2
return

DU2:
a$=text$(5):timer_on 3
return

' -------------------
reset:
hint 5," "+a$+" "
' inactive 4:inactive 5
timer_off 3
return

Ma question: est-il possible de laisser actif le HINT sur un objet désactivé ?

A+

PS: j'ai oublié, faite des essais en activant la ligne 35....

Bonjour Jean Claude,

Le problème c'est que la commande INACTIVE est sensée désactiver complètement un objet.
Donc normalement le HINT est également concerné...
study

Un attribut READ_ONLY serait peut être intéressant dans ton cas...

ou faire un Hide également et dessiner un objet (Alpha par exemple) sur lequel on laisse le Hint. Sur un clic sur l'Alpha, on masque l'alpha et on affiche le combo. Avec les procédures événementielles, ça marche plutôt bien.

Tu peux simuler un attribut read-only de la manière suivante:

1. mémorise le contenu de la zone dans une variable
2. place un évènement ON_CHANGE sur la zone
3. dans la routine ON_CHANGE, remplace systématiquement le contenu de la zone par la varable

Bien sûr, si tu veux changer le contenu de la zone par programme, il faut d'abord placer la nouvelle valeur dans la variable, et APRES seulement dans la zone.

Voici une petite démo:

Code:: label change_1, nouveau
dim contenu_1$
contenu_1$ = "Essaie de modifier..."
edit 1 : top 1,10 : left 1,10 : width 1,200
hint 1,"Zone non modifiable"
text 1,contenu_1$
on_change 1,change_1

button 2 : top 2,40 : left 2,10
caption 2,"Nouveau text" : on_click 2,nouveau
end

change_1:
off_change 1
text 1,contenu_1$
on_change 1,change_1
return

nouveau:
contenu_1$ = "Texte changé par programme"
text 1," "
return

Tout à fait Klaus,
mais un petite commande simplifierai bien les choses...
et en Delphi, je ne pense pas que cela soit bien compliqué à rajouter... Wink

Certes non. Les objets Delphi ont une propriété "Read-Only". Il faut juste définir un nouveau mot-clé dans Panoramic? Deux même, pour rester dans la logique: READ_ONLY N et READ_ONLY_OFF N. Pourquoi pas. En attendant, il y a ma solution pour simuler exactement cela.

Je ne comprend pas ton code Klaus,
Il rend l'EDIT complètement inactif, ce n'est pas ce que je cherche...
Si on garde ton exemple avec l'EDIT, ce que je voudrais c'est que à chaque nouveau texte enté dans l'EDIT le HINT soit le dernier texte entré (Et cela même si l'EDIT se trouve désactivé)

A+

PS: ce n'est pas un READ_ONLY que je cherche mais plutot HINT_ONLY N,text$(N)

C'est simple:

Code:: label change_1, nouveau
dim contenu_1$
contenu_1$ = "Essaie de modifier..."
edit 1 : top 1,10 : left 1,10 : width 1,200
hint 1,"Essaie de modifier..."
text 1,contenu_1$
on_change 1,change_1

button 2 : top 2,40 : left 2,10
caption 2,"Nouveau text" : on_click 2,nouveau
end

change_1:
off_change 1
text 1,contenu_1$
on_change 1,change_1
return

nouveau:
contenu_1$ = "Texte changé par programme"
hint 1,contenu_1$
text 1," "
return

Décidément Klaus on ne se comprend pas. Mad

Je souhaite pouvoir a certain moment dans le programme réutiliser l'EDIT, pas par le programmeur mais par l'utilisateur et je veux que HINT me donne le texte de l'édit.
C'est le sens de mon exemple au début de cette page. Regarde le bien, il fait exatement ce que je souhaite à condition de ne pas employer INACTIVE

Néanmoins, tu m'as donné une piste en bloquant l'objet en lecture seul. Je dois pouvoir me débrouiller et je te retiens au courant. Wink

A+

Mais pourquois veut tu l'inactiver dans ce cas si l'utilisateur doit pouvoir l'utiliser ? Je ne comprends pas bien, mais peut être qu'il faudrait que je testes le programme, ce que je ne pourrais faire que ce soir...

@Jicehel Salut,
Je veux le désactivé une fois que la saisie par l'utilisateur est faite car s'il y a modif cela entraîne des problèmes dans la suite du programme.
Et pendant qu'il est désactivé je veux que Hint fonctionne car le texte est plus grand que l'objet (que je ne peux pas agrandir par manque de place).
Ensuite dans d'autres options du menu, j'ai besoin de me resservir de l'objet (en l’occurrence une COMBO)

Je pensais avoir la solution en remplaçant INACTIVE par OFF_CLICK (avec un bouton pour redonner le click) dans le code ci-dessous, mais à ma grande surprise OFF_CLICK n'est pas pris en compte.

J'en perd mon latin....

Code:: dim n%,a$
label Premiere_Utilisation,Deuxieme_Utilisation,PU2,DU2

button 1:top 1,10:caption 1,"Active Combo":on_click 1,Premiere_Utilisation
combo 5:top 5,50:left 5,10: inactive 5
END
' -------------------
Premiere_Utilisation:
clear 5
for n%=1 to 10:item_add 5,str$(n%):next n%
active 5:on_click 5,PU2
return

PU2:
off_click 5:set_focus 0:' SET_FOCUS FONCTIONNE MAIS PAS OFF_CLICK
a$=text$(5):hint 5,a$
on_click 1,Deuxieme_Utilisation
return

' -------------------
Deuxieme_Utilisation:
clear 5
item_add 5,"Texte volontairement plus long que combo 5"
active 5:on_click 5,DU2
return

DU2:
off_click 5:set_focus 0
a$=text$(5):hint 5,a$
on_click 1,Premiere_Utilisation
return

A+

Invité

Ecoutes Jean-Claude, j'ai pas le temps de tester ton programme. Mais tu peux aussi faire un sous programme bidon, et d'envoyer le on_click sur ce sous-programme. Le moment venu, tu le remets correctement.

Pour des phases pendant lesquelles tu veux laisser l'utilisateur modifier l'EDIT, regarde comment je fais ceci:

Code:: label change_1, change_1bis, nouveau, autoriser, interdire
dim contenu_1$
contenu_1$ = "Essaie de modifier..."
edit 1 : top 1,10 : left 1,10 : width 1,200
hint 1,"Essaie de modifier..."
text 1,contenu_1$
on_change 1,change_1

button 2 : top 2,40 : left 2,10
caption 2,"Nouveau text" : on_click 2,nouveau
button 3 : top 3,70 : left 3,10
caption 3,"Autoriser" : on_click 3,autoriser
button 4 : top 4,100 : left 4,10
caption 4,"Interdire" : on_click 4,interdire

end

change_1:
off_change 1
text 1,contenu_1$
on_change 1,change_1
return

change_1bis:
contenu_1$ = text$(1)
return

nouveau:
contenu_1$ = "Texte changé par programme"
hint 1,contenu_1$
text 1," "
return

autoriser:
on_change 1,change_1bis
return

interdire:
on_change 1,change_1
return

Je pense qu'avec ça, tu peux faire ce que tu veux:
- laisser saisir la zone par l'utilisateur
- lorsque la saisie est faite, interdire la saisie, mais laisser le HINT actif
- réactiver la saisie quand tu veux

En fait, c'est juste le coup de changer de routine de ON_CHANGE, c'est tout.

tu peux dans ce cas utiliser la nouvelle fonction de la DLL de Klaus pour voir quand tu passes la souris sur l'objet. Auquel cas tu réactive l'objet pour afficher le Hint ?

Merci à vous tous

Avec ton dernier code, Klaus, on touche au but. Il manquait une ligne (voir ligne 26) pour que le HINT colle au contenu:

Code:: label change_1, change_1bis, nouveau, autoriser, interdire
dim contenu_1$
contenu_1$ = "Essaie de modifier..."
edit 1 : top 1,10 : left 1,10 : width 1,200
hint 1,"Essaie de modifier..."
text 1,contenu_1$
on_change 1,change_1

button 2 : top 2,40 : left 2,10
caption 2,"Nouveau text" : on_click 2,nouveau
button 3 : top 3,70 : left 3,10
caption 3,"Autoriser" : on_click 3,autoriser
button 4 : top 4,100 : left 4,10
caption 4,"Interdire" : on_click 4,interdire

end

change_1:
off_change 1
text 1,contenu_1$
on_change 1,change_1
return

change_1bis:
contenu_1$ = text$(1)
hint 1,contenu_1$: ' cette ligne manquait
return

nouveau:
contenu_1$ = "Texte changé par programme"
hint 1,contenu_1$
text 1," "
return

autoriser:
on_change 1,change_1bis
return

interdire:
on_change 1,change_1
return

Mais çà fait 3 boutons pour arriver à ce que l'on veut faire, c'est un peu lourds.
Je pense pouvoir garder un seul bouton pour activer ou désactiver l'objet...çà doit être faisable.

Par contre je suis surpris qu'il n'y ai pas de réaction, concernant le OFF_CLICK qui n'est pas pris en compte dans mon code précédent... J'ose pas parler de B.. mais j'ai un doute.

En tous cas Merci à vous tous.

A+

PS: le on_click bidon proposé par Cosmos, franchement c'est pas con... je dirais même que je vais le tester.

Suite à l'aide de Cosmos70 sur le problème de clipboard_copy, je peux te proposer une extension de mon code, aux mémos également:

Code:: label change_1, change_1bis, change_11, change_11bis
label nouveau, autoriser, interdire
dim contenu_1$
contenu_1$ = "Essaie de modifier..."
edit 1 : top 1,10 : left 1,10 : width 1,200
hint 1,"Essaie de modifier..."
text 1,contenu_1$
on_change 1,change_1

memo 11 : top 11,10 : left 11,300
item_add 11,"Mon mémo"
item_add 11,"est bien protégé"
item_add 11,"contre les modifs"
memo 21 : top 21,300 : left 21,300 : hide 21
select_text 11,1,32000
clipboard_copy 11 : clipboard_paste 21
hint 11,item_read$(11,1)
on_change 11,change_11

button 2 : top 2,40 : left 2,10
caption 2,"Nouveau text" : on_click 2,nouveau
button 3 : top 3,70 : left 3,10
caption 3,"Autoriser" : on_click 3,autoriser
button 4 : top 4,100 : left 4,10
caption 4,"Interdire" : on_click 4,interdire

end

change_1:
off_change 1
text 1,contenu_1$
on_change 1,change_1
return

change_1bis:
contenu_1$ = text$(1)
return

change_11:
off_change 11
select_text 11,1,32000
clipboard_copy 21
clear 11
clipboard_paste 11
on_change 11,change_11
return

change_11bis:
return

nouveau:
contenu_1$ = "Texte changé par programme"
hint 1,contenu_1$
text 1," "
item_add 21,"Nouvelle ligne"
item_add 11," "
hint 11,"Le mémo a "+str$(count(11))+" lignes"
return

autoriser:
on_change 1,change_1bis
on_change 11,change_11bis
return

interdire:
on_change 1,change_1
select_text 11,1,32000
clipboard_copy 11
select_text 11,32000,1
clear 21
clipboard_paste 21
clear 11
clipboard_paste 11
on_change 11,change_11
return

Salut Klaus,

Merci pour le tuyau.

Une remarque: ligne 60 => hint 11,"Le mémo a "+str$(count(11))+" lignes"

A+

Bien sûr ! Merci pour le réctificatif. LE HINT, il faut l'adapter bien sûr en fonction de l'application. C'est corrigé.

Le même principe est adaptable à d'autres types d'objets (combo, check, option, ...).

» Amélioration de la commande HINT
» Amélioration de la commande HINT
» Autre amélioration de la commande HINT
» Modification de la fonte pour HINT
» Nombre d'objets