Boutons ronds et rotatifs

dim bouton_a,bouton_b
label c166c109a,c166c109b
alpha 1:caption 1,"CLIQUEZ SUR LES BOUTONS RONDS!"

alpha 2:left 2,80:top 2,80:font_name 2,"Wingdings":font_size 2,50:font_color 2,255,0,0:caption 2,chr$(109):on_click 2,c166c109a
alpha 3:left 3,90:top 3,140:font_name 3,"Consolas":font_size 3,10:font_color 3,255,0,0:caption 3," ARRÊT"

alpha 4:left 4,150:top 4,80:font_name 4,"Wingdings":font_size 4,50:font_color 4,255,0,0:caption 4,chr$(109):on_click 4,c166c109b
alpha 5:left 5,160:top 5,105:font_name 5,"Consolas":font_size 5,08:font_color 5,255,0,0:caption 5," ARRÊT":on_click 5,c166c109b

end

c166c109a:
if odd(bouton_a)=1  then font_color 2,255,0,0:font_color 3,200,0,0:caption 3," ARRÊT"
if even(bouton_a)=1 then font_color 2,0,155,0:font_color 3,0,130,0:caption 3,"MARCHE"
caption 2,chr$(166):wait 200:caption 2,chr$(109):bouton_a=bouton_a+1
return

c166c109b:
if odd(bouton_b)=1  then font_color 4,255,0,0:font_color 5,200,0,0:caption 5," ARRÊT"
if even(bouton_b)=1 then font_color 4,0,155,0:font_color 5,0,130,0:caption 5,"MARCHE"
caption 4,chr$(166):wait 200:caption 4,chr$(109):bouton_b=bouton_b+1
return

dim i,j
label saut
j=1
' Création des numéros
 for i=-4 to 1 step 0.5
  alpha j:font_name j,"Terminal":font_bold j
  left j,70+60*cos(i)
  top j,70+60*sin(i)
  caption j,str$(j-1)
  j=j+1
 next i
' Création des graduations correspondantes aux numéros
 2d_pen_width 2
 2d_pen_color 0,0,255
 for i=-4 to 1 step 0.5:2d_line 70+40*cos(i),70+40*sin(i),70+50*cos(i),70+50*sin(i):next i
 for i=-4 to 1 step 0.1:2d_line 70+40*cos(i),70+40*sin(i),70+45*cos(i),70+45*sin(i):next i
' Création du bouton et de son marqueur
j=-4
 2d_pen_width 3:2d_fill_color 200,0,0:2d_circle 70,70,30
 2d_line 70,70,70+27*cos(j),70+27*sin(j)
 alpha number_objects+1:left number_objects,60:top number_objects,110
 font_name number_objects,"Arial":font_size number_objects,12
 font_color number_objects,200,0,200:font_bold number_objects
 caption number_objects,str$((j+4)*2)
 scroll_bar number_objects+1:left number_objects,10:top number_objects,140
 width number_objects,130:min number_objects,-40:max number_objects,10
 position number_objects,-40

on_change number_objects,saut
end

saut:
      2d_pen_color 200,0,0
      2d_line 70,70,70+27*cos(j),70+27*sin(j)
      j=position(number_objects)/10
      caption number_objects-1,str$((j+4)*2)
      2d_pen_color 0,0,255
      2d_line 70,70,70+27*cos(j),70+27*sin(j)
return

dim i,j,x1%,y1%,x2%,y2%
label saut
j=1

2d_rectangle 30,30,170,170
' Création des numéros
 for i=-4 to 1 step 0.5
  alpha j:font_name j,"Terminal":font_bold j
  left j,100+60*cos(i)
  top j,100+60*sin(i)
  caption j,str$(j-1)
  j=j+1
 next i
 display:' mise à jour de l'affichage

' Création des graduations correspondantes aux numéros
 2d_pen_width 1
 2d_pen_color 0,0,255
 for i=-4 to 1 step 0.5
  2d_line 100+40*cos(i),100+40*sin(i),100+50*cos(i),100+50*sin(i)
 next i

' Création du bouton et de son marqueur
j=-4
 2d_pen_width 3:2d_fill_color 200,0,0:2d_circle 100,100,30
 2d_line 100,100,100+27*cos(j),100+27*sin(j)

saut:
repeat
  x1%=mouse_x_position(0):y1%=mouse_y_position(0)
until (mouse_left_down(0)=1 and mouse_left_up(0)=0)
if (x1%>30 and x1%<170 and y1%>30 and y1%<170)
  while mouse_left_up(0)=0
      2d_pen_color 200,0,0:2d_line 100,100,100+27*cos(j),100+27*sin(j)
      x2%=mouse_x_position(0):y2%=mouse_y_position(0)
      if x2%>x1%
        j=j+0.2:if j>1 then j=1
      end_if
      if x2%<x1%
        j=j-0.2:if j<-4 then j=-4
      end_if
      2d_pen_color 0,0,255:2d_line 100,100,100+27*cos(j),100+27*sin(j):pause 100
      x1%=x2%:y1%=y2%
  end_while
end_if
if scancode=27 then end
goto saut
end