Aide-mémoire des mots-clés Panoramic

' Manuel Panoramic: liste des mots-clés (Jack)
DIM mke$
LABEL Fiche
  mke$ = "C:\PANORAMIC\MAKE_EXE\Make_Exe.exe"
  WIDTH 0,1000: HEIGHT 0,SCREEN_Y-30: BORDER_SMALL 0
    CAPTION 0,"  Manuel de Référence PANORAMIC" 
  LIST 4: ' pour la liste des mots-clés
    TOP 4,1: WIDTH 4,240: HEIGHT 4,HEIGHT_CLIENT(0)-2: LEFT 4,0
    COLOR 4,255,255,190: ON_CLICK 4,Fiche
  HVIEWER 3:' pour visualiser une fiche d'un mot-clé 
    TOP 3,1: LEFT 3,WIDTH(4)+2: WIDTH 3,WIDTH_CLIENT(0)-WIDTH(4)-2
    HEIGHT 3,HEIGHT_CLIENT(0)-29
  EXECUTE_WAIT mke$+"|-l": CLIPBOARD_PASTE 4
  ITEM_SELECT 4,1: GOSUB Fiche
END
' ==============================================================================   
Fiche:
  EXECUTE_WAIT mke$+"|-k 1 "+ITEM_INDEX$(4)
  CLIPBOARD_PASTE 3
RETURN

LABEL Affgroup, Affgroup1, Affcom, Affcom1, Lisgroupes
  DIM f$, a$, c$, t$, dl%, tr%, i%, k%, g%, r%, groupes$(50), n%(50), tx$(50,200)
  DIM det$(50,200),u$
  DIM rm$,Edp$,Rhk$,Rpm$,fz$,q$,grp%

 WIDTH 0,600: HEIGHT 0,440: FONT_BOLD 0: COLOR 0,180,255,255: BORDER_SMALL 0
 CAPTION 0,"  -  MOTS - CLÉS  PANORAMIC  -
 ALPHA 1: LEFT 1,20: CAPTION 1," Groupes: "
 ALPHA 2
 ALPHA 3
 FOR i% = 1 TO 3: COLOR i%,255,255,0: NEXT i%
 LIST 10: TOP 10,15: WIDTH 10,135: HEIGHT 10,HEIGHT(0)-50: ON_CLICK 10,Affgroup
 COLOR 10,255,255,190
 LIST 20: TOP 20,TOP(10): LEFT 20,WIDTH(10)+2: WIDTH 20,200: HEIGHT 20,HEIGHT(10)
 ON_CLICK 20,Affcom: COLOR 20,255,255,190
 MEMO 30: TOP 30,TOP(20): LEFT 30,WIDTH(10)+WIDTH(20)+4: WIDTH 30,245
 HEIGHT 30,60: COLOR 30,255,255,190
 ALPHA 35: TOP 35,TOP(30)+HEIGHT(30)+2: LEFT 35,LEFT(30)+100: CAPTION 35,"Détails:"
 MEMO 40: TOP 40,TOP(30)+HEIGHT(30)+15: LEFT 40,LEFT(30): WIDTH 40,WIDTH(30)
 HEIGHT 40,315
 LEFT 2,LEFT(20)+20: LEFT 3,LEFT(30)+20
 FOR i% = 10 TO 30 STEP 10: FONT_NAME i%,"Arial": FONT_SIZE i%,9: NEXT i%
 FONT_NAME 40,"Arial": FONT_SIZE 40,8: FONT_BOLD_OFF 40

 q$ = CHR$(34)
 rm$ = "C:\TEMP": ' Répertoire de travail
 Edp$ = "C:\Program Files (x86)\Panoramic Editor\PANORAMIC_EDITOR.exe": ' Éditeur
 Rhk$ = "C:\UTIL\ResHacker.exe ": ' *** ResHacker
 fz$ = rm$ + "\ppp.res": ' fichier provisoire résultat de ResHacker
 Rpm$ = "-extract "+q$+Edp$+q$+", "+q$+fz$+q$+", RCData, KEYWORDS, 1036"
 EXECUTE_WAIT Rhk$+Rpm$: ' -> résultat dans fz$
 dl% = 10: GOSUB Lisgroupes
 FILE_DELETE fz$: ' fichier résultat de Reshacker, ou à garder, si on veut...
 g% = 1: GOSUB Affgroup1
 END
 ' ==============================================================================
 Affgroup:
 ' Liste des mots-clés du groupe cliqué
 g% = ITEM_INDEX(10)
 Affgroup1:
 CLEAR 20: CLEAR 30: CLEAR 40
 CAPTION 2," Groupe: " + ITEM_READ$(10,g%) + " ": CAPTION 3,""
 FOR r% = 1 TO n%(g%)
 a$ = tx$(g%,r%): k% = INSTR(a$,":"): a$ = LEFT$(a$,k%-1)
 ITEM_ADD 20,a$
 NEXT r%
 grp% = g%
 r% = 1: GOSUB Affcom1: ' 1er mot-clé du groupe
 grp% = g%
 RETURN
 ' ==============================================================================
 Affcom:
 r% = ITEM_INDEX(20)
 Affcom1:
 CLEAR 30: CLEAR 40
 g% = grp%
 a$ = tx$(g%,r%)
 k% = INSTR(a$,":"): a$ = MID$(a$,k%+2,500)
 ITEM_ADD 30, a$
 CAPTION 3, " "+LEFT$(tx$(g%,r%),k%-1)+" "
 a$ = det$(grp%,r%): ITEM_ADD 40,a$
 RETURN
 ' ==============================================================================
 Lisgroupes:
 ' Liste des groupes de mots-clés
 FILE_OPEN_READ 1, fz$
 WHILE FILE_EOF(1) = 0: FILE_READLN 1,a$
 IF left$(a$,7) = "Groupe:"
 tr% = 0: a$ = MID$(a$,9,50): ' groupe
 IF COUNT(dl%) > 0
 FOR i% = 1 TO COUNT(dl%)
 IF a$ = ITEM_READ$(dl%,i%) THEN tr% = 1: EXIT_FOR
 NEXT i%
 END_IF
 IF tr% = 0 THEN ITEM_ADD dl%, a$
 END_IF
 END_WHILE
 FILE_CLOSE 1
 SORT dl%
 FOR i% = 1 TO COUNT(dl%)
 groupes$(i%) = item_read$(dl%,i%)
 NEXT i%
 ' Extraction et classement des mots-clés par groupe
 FILE_OPEN_READ 1, fz$
 WHILE FILE_EOF(1) = 0
 FILE_READLN 1, a$
 IF a$ = "1"
 FILE_READLN 1, t$: FILE_READLN 1, a$
 WHILE a$ <> "a": FILE_READLN 1,a$: END_WHILE
 FILE_READLN 1, a$: t$ = t$ + ": " + a$
 FILE_READLN 1,a$
 WHILE LEFT$(a$,7)<>"Groupe:": FILE_READLN 1, a$: END_WHILE
 a$ = MID$(a$,9,50): ' groupe
 FILE_READLN 1,c$
 WHILE c$<>"4": FILE_READLN 1,c$: END_WHILE
 u$ = ""
 FILE_READLN 1,c$: ' descriptif détaillé
 WHILE c$<>"E": u$=u$+c$+CHR$(13)+CHR$(10): FILE_READLN 1,c$: END_WHILE
 u$ = LEFT$(u$,LEN(u$)-2)
 FOR g% = 1 TO COUNT(dl%)
 IF a$ = groupes$(g%) THEN EXIT_FOR
 NEXT g%
 n%(g%) = n%(g%)+1: tx$(g%,n%(g%)) = t$: det$(g%,n%(g%)) = u$
 END_IF
 END_WHILE
 FILE_CLOSE 1
 RETURN
' ==============================================================================

DIM Edp$,fl$,fa$,fc$
Edp$ = "C:\PANORAMIC\PANORAMIC_EDITOR.exe": ' à adapter
fl$ = "Z:\Liste.txt": ' fichiers résultat, à adapter
fa$ = "Z:\Docmc.txt": ' "
fc$ = "Z:\Fonct.txt": ' "
MotsClesPano(Edp$,fl$,fa$,fc$)
PRINT "Terminé !"
END
' ============================
SUB MotsClesPano(Edp$,fl$,fa$,fc$)
' Extraction depuis Edp$ (Panoramic_Editor.exe) de la documentation des mots-clés
' Panoramic.
' Résultats dans (définis dans l'appelant):
'      - fl$: liste brute des mots-clés
'      - fa$: documentation complète, par mot-clé
'      - fc$: liste des fonctions par mot_clé (parallèle à fl$)
DIM_LOCAL rm$,sd$,sf$,q$,p%,fz$,a$,b$,sz%,k%,k1%,nmc%,dl%
rm$ = FILE_EXTRACT_PATH$(fl$): ' répertoire de travail provisoire
fz$ = rm$+"ppp.txt": ' fichier provisoire de travail (créé puis supprimé)
sd$ = "300D0A23494E434C554445": ' séquence début de recherche = 0<=#INCLUDE
sf$ = "0D0A460D0A46": ' séquence fin de recherche = <=F<=F
q$ = CHR$(34)
p% = 0: ' recherche à partir du début de l'Éditeur
' Nom court de Edp$ (Panoramic_Editor) -> a$
EXECUTE_WAIT "cmd.exe|/c for %A in ("+CHR$(34)+Edp$+CHR$(34)+") do @echo %~sA | clip"
a$ = LEFT$(CLIPBOARD_STRING_PASTE$,LEN(CLIPBOARD_STRING_PASTE$)-3)
FILEBIN_OPEN_READ 8,a$: FILEBIN_OPEN_WRITE 9,fz$: sz% = FILEBIN_SIZE(8)
FILEBIN_POSITION 8,p%
FILEBIN_HEXA_READ 8,2000,a$: k% = INSTR(a$,sd$)
WHILE k% < 1
    IF FILEBIN_POS(8) >= sz%
        CLIPBOARD_STRING_COPY STRING$(16,"0"): ' séquence début non trouvée
        FILEBIN_CLOSE 8: FILEBIN_CLOSE 9: EXIT_SUB
    END_IF
    p% = p%+2000-LEN(sd$): FILEBIN_POSITION 8,p%
    FILEBIN_HEXA_READ 8,2000,a$: k% = INSTR(a$,sd$)
END_WHILE
k1% = INSTR_POS(a$,sf$,k%)
IF k1% > 0
    a$ = MID$(a$,k%,k1%+LEN(sf$)-k%)
    FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$)
ELSE
    a$ = RIGHT_POS$(a$,k%): k% = 0
    WHILE k% < 1
        FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$
        p% = p%+2000-LEN(sf$)
        FILEBIN_HEXA_READ 8,2000,a$: k%=INSTR(a$,sf$)
    END_WHILE
    a$ = LEFT$(a$,k%-1)+sf$
    FILEBIN_HEXA_WRITE 9,LEN(a$)/2,a$
END_IF
FILEBIN_CLOSE 8: FILEBIN_CLOSE 9
FILE_OPEN_READ 8, fz$: FILE_OPEN_WRITE 9,fa$: FILE_OPEN_WRITE 6,fl$
FILE_OPEN_WRITE 7,fc$
EXECUTE_WAIT "cmd.exe|/c FIND /N "+q$+"Utilise PANORAMIC Version"+q$+" "+Edp$+" | clip"
a$ = CLIPBOARD_STRING_PASTE$: k% = INSTR(a$,"]")
FILE_WRITELN 9,RIGHT_POS$(a$,k%+9): ' Version de l'Editeur
FILE_READLN 8,a$: nmc% = 0
WHILE FILE_EOF(8) = 0
    FILE_READLN 8,a$
    IF LEN(a$) = 1 AND NUMERIC(a$) = 1
        WHILE a$<>"1": FILE_READLN 8,a$: END_WHILE: FILE_WRITELN 9,"": ' saut de ligne
        FILE_READLN 8,a$: FILE_WRITELN 9,"1_ "+a$: nmc%=nmc%+1: ' MOT-CLÉ COMPLET
        IF LEFT$(a$,1) = "("
            IF INSTR(a$,"STEP") > 0
                a$ = "STEP"
            ELSE
                a$ = "TO"
            END_IF
        END_IF
        FILE_WRITELN 6,a$: b$ = a$
        WHILE a$<>"2": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"2_ "+a$: ' RÉSUMÉ
        IF LEN(b$)<24 THEN b$=b$+STRING$(24-LEN(b$)," ")
        FILE_WRITELN 7,b$+" :"+a$: ' fonction globale
        WHILE a$<>"3": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"3_ "+a$: ' DÉFINITION
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"4": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"4_ "+a$: ' FONCTION
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"5": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"5_ "+a$: ' SYNTAXE
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"6": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"6_ "+a$: ' USAGE
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"7": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"7_ "+a$: ' CAS D'ERREUR
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"8": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"8_ "+a$: ' EXEMPLES
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
        WHILE a$<>"9": FILE_READLN 8,a$: END_WHILE
        FILE_READLN 8,a$: FILE_WRITELN 9,"9_ "+a$: ' EN RAPPORT
        FILE_READLN 8,a$: WHILE LEN(a$)>1: FILE_WRITELN 9,a$: FILE_READLN 8,a$: END_WHILE
    END_IF
END_WHILE
FILE_CLOSE 8: FILE_CLOSE 9: FILE_CLOSE 6: FILE_CLOSE 7
FILE_DELETE fz$
dl%=1000: WHILE OBJECT_EXISTS(dl%)=1: dl%=dl%+1: END_WHILE
DLIST dl%: FILE_LOAD dl%,fl$: SORT dl%: FILE_SAVE dl%,fl$: DELETE dl%
END_SUB