Au secours !

' ==============================================================================
' DECLARATIONS DES VARIABLES
' ==============================================================================
  dim x%           : ' variable d'incrementation des boucles
  dim no%          : ' variable de numérotation des objets
  dim lib$         : ' variable de lecture des datas
  dim msg%         : ' variable de retour des boites de dialogue de message
  dim prt%         : ' variable de substitution du paramètre parent
  dim ret%         : ' variable de retour des fonctions de dll hors procédures
  dim secret%      : ' variable d'état de visio du mot de passe
  dim ActiveListe$ : ' variable contenant l'adresse du fichier de liste actif
  dim ActiveTList$ : ' variable contenant le nom à placer dans la barre de titre
  dim BddFile$     : ' variable d'adresse du fichier Bdd en cours d'utilisation
' ==============================================================================
' DECLARATIONS DES CONSTANTES
' ==============================================================================
' ! SYSTEME
  dim Path$
  dim PathImg$
  dim PathFic$
  dim PathBdd$  
' -
' ! FICHIERS SYSTEME  
  dim Kgf$
  dim AppIco$
' listes
  dim FListBenef$
  dim FListMarque$
  dim FListEtat$
  dim FListModUCT$
  dim FListModUCD$
  dim FListModUCL$
  dim FListModE$
  dim FListModC$
  dim FListModS$
  dim FListSource$
  dim FListSortie$
' -
' ! FICHIERS IMAGES
  dim FileImgBtnAdd$
  dim FileImgBtnSave$
  dim FileImgBtnVal$
  dim FileImgBtnCancel$
  dim FileImgBtnEchap$
  dim FileImgBtnUnLock$
  dim FileImgBtnSecretOn$
  dim FileImgBtnSecretOff$
' -
' ! SECURITE
  dim PWD1$
  dim PWD2$
' -
' ! OBJETS FRM0
  dim Mm%
  dim Sm%(50)
' -
' ! OBJETS FrmOpen
  dim FrmOpen%
' -  
' ! OBJETS FrmListes
  dim FrmListes%
  dim ListListe%
  dim BtnPListe%(2)
' -  
' ! OBJETS FrmAddItem
  dim FrmAddItem%
  dim AlphAddItem%
  dim EditAddItem%
  dim BtnPAddItem%(2)
' -  
' ! OBJETS non fenêtrés
  dim ODial%
  dim DLBase%
' -
' ==============================================================================
' DECLARATIONS DES SOUS PROGRAMMES
' ==============================================================================
' ! CLIC
  label CLICMenu
  label CLICFrm0
  label CLICFrmOpen
  label CLICFrmListes
  label CLICFrmAddItem
' -
' ! CHANGE
  label CHANGEFrm0
' -
' ! CLOSE
  label CLOSEFrm0
  label CLOSEFrmOpen
  label CLOSEFrmListes
' -
' ==============================================================================
' DECLARATIONS DES ETIQUETTES
' ==============================================================================
' ! MENU
  Label LibMenu
' -  
' ==============================================================================
' DECLARATION DES DATAS
' ==============================================================================
' ! MENU
  LibMenu:
  data "Bases","Listes","Edition","Paramètres","Affichage","A Propos","Aide","","Connection"
  data "Ouvrir","Fermer","-","Exporter *.csv","Exporter *.pdf","-","Quitter"
  data "Bénéficiaires","Etats","Marques","Modèles","Sources","Types de sortie"
  data "Créer","Voir","Modifier","-","Supprimer","-","Rechercher"
  data "Administrateur","Utilisateurs"
  data "Fiches","Table","Etats"
  data "Simple","Multiple"
' -  
' ==============================================================================
' AFFECTATIONS DE VALEURS
' ==============================================================================
' ! SYSTEME
  Path$    = file_extract_path$(Param_value$(0))
  PathImg$ = Path$+"img"
  PathFic$ = Path$+"fic"
  PathBdd$ = Path$+"bdd"
' -
' ! FICHIERS SYSTEME
  Kgf$         = Path$+"KGF.dll"
  AppIco$      = Path$+"tzcld.ico"
  FListBenef$  = PathFic$+"Beneficiaires.inf"
  FListMarque$ = PathFic$+"Marques.inf"
  FListEtat$   = PathFic$+"Etats.inf"
  FListSource$ = PathFic$+"Sources.inf"
  FListSortie$ = PathFic$+"Sorties.inf"
  FListModUCT$ = PathFic$+"ModUCT.inf"
  FListModUCD$ = PathFic$+"ModUCD.inf"
  FListModUCL$ = PathFic$+"ModUCL.inf"
  FListModE$   = PathFic$+"ModEcrans.inf"
  FListModC$   = PathFic$+"ModClaviers.inf"
  FListModS$   = PathFic$+"ModSouris.inf"
' -
' ! FICHIERS IMAGES
  FileImgBtnAdd$       = PathImg$+"BtnAdd.bmp"
  FileImgBtnSave$      = PathImg$+""
  FileImgBtnVal$       = PathImg$+""
  FileImgBtnCancel$    = PathImg$+""
  FileImgBtnEchap$     = PathImg$+"BtnEchap.bmp"
  FileImgBtnUnLock$    = PathImg$+"BtnUnlock.bmp"
  FileImgBtnSecretOn$  = PathImg$+"BtnSecretOn.bmp"
  FileImgBtnSecretOff$ = PathImg$+"BtnSecretOff.bmp"
' -
' ! SECURITE
  PWD1$ = "T..........................."
  PWD2$ = "Objectif_2024"
' -
' ! OBJETS Frm0
  no%=no%+1 : Mm%=no%
  for x%=1 to 50 : no%=no%+1 : Sm%(x%)=no% : next x%
' -
' ! OBJETS FrmOpen
  no%=no%+1 : FrmOpen%=no%
' -  
' ! OBJETS FrmListes
  no%=no%+1 : FrmListes%=no%
  no%=no%+1 : ListListe%=no%
  for x%=1 to 2 : no%=no%+1 : BtnPListe%(x%)=no% : next x%
' -
' ! OBJETS FrmAddItem
  no%=no%+1 : FrmAddItem%=no%
  no%=no%+1 : AlphAddItem% = no%
  no%=no%+1 : EditAddItem% = no%
  for x%=1 to 2 : no%=no%+1 :  BtnPAddItem%(x%)=no% : next x%
' -  
' ! OBJETS non fenêtrés
  no%=no%+1 : ODial%=no%
  no%=no%+1 : DLBase%=no%
' -
' ==============================================================================
' ACTIVATION DES DLLS
' ==============================================================================
' ! ACTIVATION KGF
  if file_exists(Kgf$)=1
     dll_on Kgf$
  else
     hide 0
     msg%=message_warning_ok("KGF.dll est introuvable !"+chr$(13)+"Télécharger la dll et placez là dans le dossier source")
     terminate
  end_if
' -  
' ==============================================================================
' INTERFACE UTILISATEUR
' ==============================================================================
  Application_title "GTAI - Vs 24.01.i2"
  
  BUILD_FORM0(600,1000,0,0)
  SET_TEXT_ATTRIBUT(0,"Arial",10,"1000",100,100,100)
  ret% = DLL_call2("FixedFormSize",handle(0),1)
  ret% = DLL_call2("SetMinimizeMaximize",handle(0),0)
  ret% = DLL_call2("SetFormIcon",handle(0),adr(AppIco$))
  caption 0,"Gestion Atelier Informatique - Vs 24.01.i1"
  
  BUILD_OBJECT("MAIN_MENU",Mm%,0,0,0,0,0)
  restore_label LibMenu
  for x%=1 to 36
     if x%<10 : prt%=Mm% : end_if
     if x%>9 and x%<17 : prt%=Sm%(1) : end_if
     if x%>16 and x%<23: prt%=Sm%(2) : end_if
     if x%>22 and x%<30: prt%=Sm%(3) : end_if
     if x%>29 and x%<32: prt%=Sm%(4) : end_if
     if x%>31 and x%<35: prt%=Sm%(5) : end_if
     if x%>34 and x%<37: prt%=Sm%(23): end_if
     BUILD_OBJECT("SUB_MENU",Sm%(x%),Prt%,0,0,0,0)
     read lib$ : caption Sm%(x%),lib$
     if x%=8 : caption Sm%(x%),string$(160,chr$(32)) : inactive Sm%(x%) : end_if
     if x%>5 and lib$<>"-"
        on_click Sm%(x%),CLICMenu
     end_if    
  next x%
  
  BUILD_OBJECT("DLIST",DLBase%,0,0,0,0,0)
  END
' ==============================================================================
' SOUS PROGRAMMES CLIC
' ==============================================================================
' ! MENU
  CLICMenu:
   ' a propos
     if number_click = Sm%(6)
     end_if  
   ' aide
     if number_click = Sm%(7)
     end_if  
   ' connection
     if number_click = Sm%(9)
     end_if  
   ' ouvrir
     if number_click = Sm%(10)
        OpenBddFile()
     end_if
   ' fermer
     if number_click = Sm%(11)
    CloseBddFile()
     end_if
   ' exp *.csv
     if number_click = Sm%(13)
     end_if
   ' exp *.pdf
     if number_click = Sm%(14)
     end_if
   ' quitter
     if number_click = Sm%(16)
     end_if
  RETURN
' -
' ! Frm 0  
  CLICFrm0:
  RETURN
' -
' ! Frm Open  
  CLICFrmOpen:
  RETURN
' -
' ! Frm Listes  
  CLICFrmListes:
     if number_click = BtnPListe%(1)
        hide FrmListes%
        FenAddItemInList()  
     end_if
    
     if number_click = BtnPListe%(2)
        FreezeMainMenu(1,5,1)
        hide FrmListes%
        ActiveListe$=""
        ActiveTlist$=""
     end_if
  RETURN
' -
' ! Frm AddItem  
  CLICFrmAddItem:
     if number_click = BtnPAddItem%(1)
        hide FrmAddItem%
        FenListe(ActiveListe$,ActiveTList$)
        if text$(EditAddItem%)<>""
           item_add ListListe%,text$(EditAddItem%)
           file_save ListListe%,ActiveListe$
        end_if
        text EditAddItem%,""
     end_if
    
     if number_click = BtnPAddItem%(2)
        text EditAddItem%,""
        hide FrmAddItem%
        FenListe(ActiveListe$,ActiveTList$)
     end_if  
  RETURN
' -  
' ==============================================================================
' SOUS PROGRAMMES CHANGE
' ==============================================================================
' ! Frm 0
  CHANGEFrm0:
  RETURN
' -  
' ==============================================================================
' SOUS PROGRAMMES CLOSE
' ==============================================================================
' ! Frm 0
  CLOSEFrm0:
  RETURN
' -
' ! Frm Open
  CLOSEFrmOpen:
  RETURN
' -
' ! Frm Listes
  CLOSEFrmListes:
  RETURN
' -  
' ==============================================================================
' PROCEDURES D'INTERFACE UTILISATEUR
' ==============================================================================
' ! FENETRE D AFFICHAGE DES LISTES
  SUB FenListe(Src$,L$)
     if object_exists(FrmListes%)=1
        show FrmListes%        
     else
        BUILD_OBJECT("FORM",FrmListes%,0,400,250,(screen_y-400)/2,(screen_x-250)/2)
        SET_TEXT_ATTRIBUT(FrmListes%,"Arial",8,"1000",90,90,90)
        on_close FrmListes%,CLOSEFrmListes
                
        BUILD_OBJECT("LIST",ListListe%,FrmListes%,height_client(FrmListes%)-34,width_client(FrmListes%)-10,5,5)
        SET_TEXT_ATTRIBUT(ListListe%,"Arial",8,"1000",0,0,0)
        
        BUILD_OBJECT("BUTTON_PICTURE",BtnPListe%(1),FrmListes%,24,24,height_client(FrmListes%)-29,width_client(FrmListes%)-58)
        button_picture_target_is_picture
        height BtnPListe%(1),16 : width BtnPListe%(1),16
        if file_exists(FileImgBtnAdd$)=1 : file_load BtnPListe%(1),FileImgBtnAdd$ : end_if
        on_click BtnPListe%(1),CLICFrmListes
        cursor_point BtnPListe%(1)        
        
        BUILD_OBJECT("BUTTON_PICTURE",BtnPListe%(2),FrmListes%,24,24,height_client(FrmListes%)-29,width_client(FrmListes%)-29)
        button_picture_target_is_picture
        height BtnPListe%(2),16 : width BtnPListe%(2),16
        if file_exists(FileImgBtnEchap$)=1 : file_load BtnPListe%(2),FileImgBtnEchap$ : end_if
        on_click BtnPListe%(2),CLICFrmListes
        cursor_point BtnPListe%(2)
     end_if      
     Caption FrmListes%,L$
     Clear ListListe%
     if file_exists(Src$)=1 then file_load ListListe%,Src$
     FormatForm(handle(FrmListes%),adr(AppIco$),0,1,1)          
  END_SUB
' -
' ! FENETRE D AJOUT DANS UNE LISTE
  SUB FenAddItemInList()
     if object_exists(FrmAddItem%)=1
        show FrmAddItem%
     else
        BUILD_OBJECT("FORM",FrmAddItem%,0,130,250,(screen_y-130)/2,(screen_x-250)/2)
        SET_TEXT_ATTRIBUT(FrmAddItem%,"Arial",8,"1000",90,90,90)
        Caption FrmAddItem%,"Ajouter un élément"
        on_close FrmAddItem%,CLOSEFAItem
        
        BUILD_OBJECT("ALPHA",AlphAddItem%,FrmAddItem%,22,200,20,10)
        caption AlphAddItem%,"Nouvel élément :"
        
        BUILD_OBJECT("EDIT",EditAddItem%,FrmAddItem%,22,200,35,10)
        SET_TEXT_ATTRIBUT(EditAddItem%,"Arial",8,"1000",0,0,0)

        BUILD_OBJECT("BUTTON_PICTURE",BtnPAddItem%(1),FrmAddItem%,24,24,height_client(FrmAddItem%)-29,width_client(FrmAddItem%)-58)
        button_picture_target_is_picture
        height BtnPAddItem%(1),16 : width BtnPAddItem%(1),16
        if file_exists(FileImgBtnSave$)=1 : file_load BtnPAddItem%(2),FileImgBtnSave$ : end_if
        on_click BtnPAddItem%(1),CLICFrmAddItem
        cursor_point BtnPAddItem%(1)

        BUILD_OBJECT("BUTTON_PICTURE",BtnPAddItem%(2),FrmAddItem%,24,24,height_client(FrmAddItem%)-29,width_client(FrmAddItem%)-29)
        button_picture_target_is_picture
        height BtnPAddItem%(2),16 : width BtnPAddItem%(2),16
        if file_exists(FileImgBtnEchap$)=1 : file_load BtnPAddItem%(2),FileImgBtnEchap$ : end_if
        on_click BtnPAddItem%(2),CLICFrmAddItem
        cursor_point BtnPAddItem%(2)        
     end_if
     FormatForm(handle(FrmAddItem%),adr(AppIco$),0,1,1)
  END_SUB
' -
' ==============================================================================
' PROCEDURES DE FONCTIONS
' ==============================================================================
' ! Ouverture d'un fichier de base de données
  SUB OpenBddFile()
     dim_local txt$
     if BddFile$=""  
        BddFile$ = SelectedOpenBddFile$()
        if BddFile$<>"_"
           ret% = dll_call4("crypter",adr(PWD1$),adr(PWD2$),adr(BddFile$),1)
           file_load DLBase%,BddFile$
 else
   BddFile$=""
        end_if
     else
    txt$ = "Le fichier : "+file_extract_name$(BddFile$)+" est ouvert !"+chr$(13)
 txt$ = txt$+"Souhaitez vous fermer ce fichier ?"
        msg% = message_warning_yes_no(txt$)
 if msg%=1
   CloseBddFile()
 else
   EXIT_SUB
 end_if
     end_if
  END_SUB
' -
' ! Fermeture d'un fichier de base de données
  SUB CloseBddFile()
     if BddFile$<>"" and file_extract_extension$(BddFile$)=".bdd"
        file_save DLBase%,BddFile$
        ret% = dll_call4("crypter",adr(PWD1$),adr(PWD2$),adr(BddFile$),1)
 BddFile$=""
 clear DLBase%
 else
    msg% = message_information_ok("Aucun fichier de données n'est ouvert !")
 end_if
  END_SUB
' -
' ! Blocage du MAIN_MENU
  SUB FreezeMainMenu(Dep%,Fin%,FUF%)
     dim_local i%
     for i%=Dep% to Fin%
        if FUF% = 0
           inactive Sm%(i%)
        else
           active Sm%(i%)
        end_if
     next i%
  END_SUB
' -
' ! Formatage des fenêtres annexes    
  SUB FormatForm(hnd%,adrico%,flagMM%,flagFFS%,flagWTM%)
     dim_local kgfres%
     kgfres% = DLL_call2("SetFormIcon",hnd%,adrico%)
     kgfres% = DLL_call2("SetMinimizeMaximize",hnd%,flagMM%)
     kgfres% = DLL_call2("FixedFormSize",hnd%,flagFFS%)
     kgfres% = DLL_call2("WindowTopMost",hnd%,flagWTM%)  
  END_SUB
' -
' ==============================================================================
' FONCTIONS
' ==============================================================================
  FNC SelectedOpenBddFile$()
     dim_local f$
 
     Open_dialog Odial%
 dir_dialog Odial%,PathBdd$
 filter Odial%,"*.bdd|*.bdd"
 f$ = file_name$(Odial%)
 delete Odial%
 result f$
  END_FNC

' ==============================================================================
'                                ObjLibrary.bas                                              
'                             BIBBLIOTHEQUE OBJETS                                            
'                                  Y.GERONIMI                                                  
'                                  25/05/2021                                                  
' ==============================================================================
' BUILD_OBJECT(Object$,Obj%,Par%,H%,W%,T%,L%)
' BUILD_FORM0(H%,W%,T%,L%)
' SET_TEXT_ATTRIBUT(Obj%,FtName$,FtSize%,FtStyle$,FtColR%,FtColG%,FtColB%)
' ------------------------------------------------------------------------------
' Construction d'objets                                                                                                    
  SUB BUILD_OBJECT(Object$,Obj%,Par%,H%,W%,T%,L%)
     dim_local i%,ListObject$,ObjName$,Type%,Fen%
 
     ListObject$ ="SCENE3D BUTTON EDIT MEMO COMBO ALPHA FORM LIST PICTURE CHECK OPTION"+chr$(32)
     ListObject$ = ListObject$ + "MAIN_MENU SUB_MENU SOUND MOVIE TRACK_BAR OPEN_DIALOG SAVE_DIALOG"+chr$(32)
     ListObject$ = ListObject$ + "SCROLL_BAR PROGRESS_BAR SPIN GRID CONTAINER MEMO_RICH BUTTON_PICTURE DLIST SCENE2D TIMER"+chr$(32)
     ListObject$ = ListObject$ + "PANEL - MAIN_MENU_POP CONTAINER_OPTION OPEN_DIALOG_PIC SAVE_DIALOG_PIC SHAPE HVIEWER SERIAL LED1 DIGIT1"+chr$(32)
     ListObject$ = ListObject$ + "SWITCH1 IMAGE CONTAINER_TAB TAB - - SYNEDIT CHART"+chr$(32)
     for i%=1 to 47
        ObjName$ = left$(ListObject$,instr(ListObject$,chr$(32))-1)
        ListObject$ = right$(ListObject$,len(ListObject$)-instr(ListObject$,chr$(32)))
        if ObjName$ = Object$
           Type% = i%
           exit_for
        end_if
     next i%
 
     select Type%
     case 1  : Fen% = 1 : SCENE3D Obj%
     case 2  : Fen% = 1 : BUTTON Obj%
     case 3  : Fen% = 1 : EDIT Obj%
     case 4  : Fen% = 1 : MEMO Obj%
     case 5  : Fen% = 1 : COMBO Obj%
     case 6  : Fen% = 1 : ALPHA Obj%
     case 7  : Fen% = 1 : FORM Obj%
     case 8  : Fen% = 1 : LIST Obj%
     case 9  : Fen% = 1 : PICTURE Obj%
     case 10 : Fen% = 1 : CHECK Obj%
     case 11 : Fen% = 1 : OPTION Obj%
     case 12 : Fen% = 0 : MAIN_MENU Obj%
     case 13 : Fen% = 0 : SUB_MENU Obj%
     case 14 : Fen% = 0 : SOUND Obj%
     case 15 : Fen% = 0 : MOVIE Obj%
     case 16 : Fen% = 1 : TRACK_BAR Obj%
     case 17 : Fen% = 0 : OPEN_DIALOG Obj%
     case 18 : Fen% = 0 : SAVE_DIALOG Obj%
     case 19 : Fen% = 1 : SCROLL_BAR Obj%
     case 20 : Fen% = 1 : PROGRESS_BAR Obj%
     case 21 : Fen% = 1 : SPIN Obj%
     case 22 : Fen% = 1 : GRID Obj%
     case 23 : Fen% = 1 : CONTAINER Obj%
     case 24 : Fen% = 1 : MEMO_RICH Obj%
     case 25 : Fen% = 1 : BUTTON_PICTURE Obj% : button_picture_target_is_object
     case 26 : Fen% = 0 : DLIST Obj%
     case 27 : Fen% = 1 : SCENE2D Obj%
     case 28 : Fen% = 0 : TIMER Obj%
     case 29 : Fen% = 1 : PANEL Obj%
     case 30
     case 31 : Fen% = 0 : MAIN_MENU_POP Obj%
     case 32 : Fen% = 1 : CONTAINER_OPTION Obj%
     case 33 : Fen% = 0 : OPEN_DIALOG_PIC Obj%
     case 34 : Fen% = 0 : SAVE_DIALOG_PIC Obj%
     case 35 : Fen% = 1 : SHAPE Obj%
     case 36 : Fen% = 1 : HVIEWER Obj%
     case 37 : Fen% = 0 : SERIAL Obj%
     case 38 : Fen% = 1 : LED1 Obj%
     case 39 : Fen% = 1 : DIGIT1 Obj%
     case 40 : Fen% = 1 : SWITCH1 Obj%
     case 41 : Fen% = 0 : IMAGE Obj%
     case 42 : Fen% = 1 : CONTAINER_TAB Obj%
     case 43 : Fen% = 0 : TAB Obj%
     case 44
     case 45
     case 46 : Fen% = 1 : SYNEDIT Obj%
     case 47 : Fen% = 1 : CHART Obj%
     end_select
 
     if Par%>0
        parent Obj%,Par%
     end_if
 
     if Fen% = 1
        height Obj%,H%
        width Obj%,W%
        top Obj%,T%
        left Obj%,L%
     end_if
  END_SUB
' ------------------------------------------------------------------------------
' paramètres graphiques du form 0
  SUB BUILD_FORM0(H%,W%,T%,L%)
     height 0,H%
     width 0,W%
     if T%=0 : top 0,(screen_y-height(0))/2 : else : top 0,T%  : end_if
     if L%=0 : left 0,(screen_x-width(0))/2 : else : left 0,L% : end_if
  END_SUB
' ------------------------------------------------------------------------------
' Attributs du texte d'un objet
  SUB SET_TEXT_ATTRIBUT(Obj%,FtName$,FtSize%,FtStyle$,FtColR%,FtColG%,FtColB%)
     font_name Obj%,FtName$
     font_size Obj%,FtSize%
     if mid$(FtStyle$,1,1)="1" : font_bold Obj% : else : font_bold_off Obj% : end_if
     if mid$(FtStyle$,2,1)="1" : font_italic Obj% : else : font_italic_off Obj% : end_if
     if mid$(FtStyle$,3,1)="1" : font_underline Obj% : else : font_underline_off Obj%: end_if
     if mid$(FtStyle$,4,1)="1" : font_strike Obj% : else : font_strike_off Obj% : end_if
     font_color Obj%,FtColR%,FtColG%,FtColB%
  END_SUB
' ------------------------------------------------------------------------------