GRID : Cellules en mode "édition"

dim colonneGrid%, ligneGrid%, contenuCellule$, n%

label edition, controleSaisie, annulSaisie, redim

width 0,width(0) - width_client(0) + 785
height 0,height(0) - height_client(0) + 305
top 0,(screen_y - height(0)) / 2
left 0,(screen_x - width(0)) / 2
on_click 0,annulSaisie
on_resize 0,redim

' creation du GRID et numerotation des lignes et colonnes
grid 1
width 1,785
height 1,305
grid_column 1,12
grid_row 1,12
grid_column_sizing_on 1
grid_row_sizing_on 1
for n% = 1 to 11
    grid_write 1,n%+1,1,n%
next n%
for n% = 1 to 11
    grid_write 1,1,n%+1,n%
next n%
on_click 1,edition

' creation du champ de saisie
memo 3
on_key_down 3,controleSaisie
hide 3

end


edition:
    saisie()
return


sub saisie()
    dim_local x%, y%, n%
    colonneGrid% = 0
    ligneGrid% = 0
    colonneGrid% = grid_x_to_column(1,mouse_x_position(1))
    ligneGrid% = grid_y_to_row(1,mouse_y_position(1))
    show 3
    
    ' On applique les dimensions de la cellule au MEMO de saisie (MEMO 3)
    width 3,grid_one_column_width(1,colonneGrid%)
    height 3,grid_one_row_height(1,ligneGrid%)
    top 3,mouse_y_position(1)
    
    ' Calcul des coordonnees x et y pour afficher le champ de saisie (MEMO 3)
    for n% = 1 to colonneGrid% - 1
         x% = x% + grid_one_column_width(1,n%)
    next n%
    left 3,x% +1
    
    for n% = 1 to ligneGrid% - 1
         y% = y% + grid_one_row_height(1,n%)
    next n%
    top 3,y% + 1

    contenuCellule$ = grid_read$(1,ligneGrid%,colonneGrid%)
    set_focus 3
    text 3,contenuCellule$
    caret_position 3,len(contenuCellule$)
end_sub


controleSaisie:
    if key_down_code = 13 :' touche ENTREE du clavier
        grid_write 1,ligneGrid%,colonneGrid%,text$(3)
        text 3,""
        hide 3
    end_if
    if key_down_code = 27 :' touche ECHAP du clavier
        text 3,""
        hide 3
    end_if    
return

annulSaisie:
    text 3,""
    hide 3
return

redim:
    width 0,width(0) - width_client(0) + 785
    height 0,height(0) - height_client(0) + 305
return